83985_zh-CN

liliconcom

使用多个y数据和一个控制组使Y适合X.

你好

 

我有多个不同的组和一个控件。我想通过X analysi做一个Fit Y，其中我在不同的图上有不同的组，但在每个图上都有控制组比较器。例如，使用grps B，C，D控制grp A和使用grps E，F，G控制grp A.希望在不需要使用隐藏/排除和多次绘制的情况下完成所有操作。

 

谢谢

 

R.

Re：使用多个y数据和一个控制组使Y适合X.

可能不是你想要的，但你可以尝试使用本地数据过滤器的“收藏夹”（然后可能记录过滤后的结果以将它们放在一个地方）。

要查看此信息，请运行以下代码创建表，然后在表中运行已保存的脚本：

New Table( "Test",
 Add Rows( 100 ),
 New Script(
  "Oneway",
  Oneway(
   Y( :Response ),
   X( :Group ),
   Automatic Recalc( 1 ),
   Local Data Filter(
    Add Filter(
     columns( :Group ),
     Display( :Group, Size( 160, 105 ), List Display )
    ),
    Favorites(
     "Group = Control, B, C, D"(Match( columns( :Group ),
      Where( :Group == {1, 2, 3, 4} )
     )),
     "Group = Control, E, F, G"(Match( columns( :Group ),
      Where( :Group == {1, 5, 6, 7} )
     ))
    )
   )
  )
 ),
 New Column( "Group",
  Numeric,
  "Nominal",
  Format( "Best", 12 ),
  Formula( Random Integer( 1, 7 ) ),
  Value Labels(
   {1 = "Control", 2 = "B", 3 = "C", 4 = "D", 5 = "E", 6 = "F", 7 = "G"}
  ),
  Use Value Labels( 1 )
 ),
 New Column( "Response",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 12, 2 ),
  Formula( Random Normal() )
 )
)