106187_zh-CN

liliconcom

具有不同目标或规格限制的图形

喜

 

我有一个2产品（P和X）的图表，如下图所示。

 

我想使用图表的jsl为每个产品添加一个参考线和一个彩色区域。

 

可能吗？

 

最好的祝福

 

 

 

Re：具有不同目标或规格限制的图形

是。

 

如果隐藏“男性”（例如，通过使用本地数据过滤器），则会从显示中删除包含这些点的框架（在本例中为“FrameBox（2）”）以及相关的图形脚本。当“Males”被取消隐藏时，JMP将创建它所需的框架框，但它将继承“女性”中的图形脚本。有人可能会争辩说它不应该这样做，但当然你对“男性”没有任何界限。

 

我认为你可以通过使用行状态处理程序来获得你想要的行为，但是这需要一些工作来使这一般。

Re：具有不同目标或规格限制的图形

喜

 

有一个pb。

 

如果排除M然后重新包含M，则F和M的规格限制相同。

 

最好的祝福

Re：具有不同目标或规格限制的图形

认为您可能不得不求助于图形脚本。制作这种一般性需要一些工作，但完全可能。使用“帮助”>“脚本索引”了解更多详细信息。

 

NamesDefaultToHere(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// Using the axis gives common values for the groups
gb1 = dt << Graph Builder(
    Size( 534, 488 ),
    Show Control Panel( 0 ),
    Show Legend( 0 ),
    Variables( X( :weight ), Y( :height ), Group X( :sex ) ),
    Elements( Points( X, Y, Legend( 8 ) ), Smoother( X, Y, Legend( 9 ) ) ),
    SendToReport(
     Dispatch(
      {},
      "height",
      ScaleBox,
      {Add Ref Line( {60, 65}, "Solid", "Green", "Middle", 1, 0.25 ),
      Add Ref Line( {65, 70}, "Solid", "Medium Dark Cyan", "Top", 1, 0.25 ),
      Add Ref Line( 65, "Solid", "Orange", "", 1 )}
     )
    )
   );

// Different values for each group takes more work
gb2 = dt << Graph Builder(
    Size( 534, 488 ),
    Show Control Panel( 0 ),
    Show Legend( 0 ),
    Variables( X( :weight ), Y( :height ), Group X( :sex ) ),
    Elements( Points( X, Y, Legend( 8 ) ), Smoother( X, Y, Legend( 9 ) ) )
   );
gb2Rep = Report(gb2);
// Females . . .
gb2Rep[Framebox(1)] << addGraphicsScript(
       PenColor("Orange"); HLine(60);
       Transparency(0.25);
       FillColor("Green");
       Rect(50, 60, 180, 55, 1);
       FillColor("Blue");
       Rect(50, 65, 180, 60, 1);
      );
// Males . . .
gb2Rep[Framebox(2)] << addGraphicsScript(
       PenColor("Orange"); HLine(65);
       Transparency(0.25);
       FillColor("Green");
       Rect(50, 65, 180, 60, 1);
       FillColor("Blue");
       Rect(50, 70, 180, 65, 1);
      );