78984_es-ES

liliconcom

combinar ventanas gráficas a través de bucle

Hola,

 

Tengo una larga lista de variables de respuesta para graficar y me gustaría agruparlas en ventanas separadas donde cada ventana es una categoría predefinida. Luego quiero combinar todos los informes (ventanas de gráficos) y crear un Panel de control. Cuando voy a Ventana -> Combinar Windows (que había usado antes para diferentes propósitos) los informes no se muestran como opciones para combinar. ¿Alguien puede ayudar por favor?

 

A continuación se muestra el script JMP que utilicé para generar los gráficos con una tabla de datos de muestra. Para este ejemplo, supongamos que queremos una ventana gráfica separada para cada aerolínea.

 

Gracias.

Derchieh

 

 

 

 

Names Default to Here(1);

sourcedt = Open("$SAMPLE_DATA\Airline Delays.jmp");

dt = sourcedt << Stack(
 columns( :Elapsed Time, :Arrival Delay, :Distance ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Value" )
);

Summarize(dt, al = By(:Airline));
Summarize(dt, mon = By(:Month));
Summarize(dt, para = By(:Label));


For (j = 1, j <= NItems(al), j++,
 New Window( al[j],
  V List Box(
 
   For (i = 1, i <= NItems(para), i++,
  
    Graph Builder(
     Size(230, 300),
     Fit to Window( "Off" ),
     Show Control Panel(0),
     Variables( X( :Month ), Y( :Value ), Overlay( :Day of Week ) ),
     Elements( Points( X, Y, Legend( 1 ) ) ),
     Where( :Airline == al[j] & :Label == para[i] ),
     SendToReport(
     Dispatch(
      {},
      "Value",
      ScaleBox,
      {Min( -10 ),  Minor Ticks( 0 )}
     ),
     Dispatch( {}, "graph title", TextEditBox, {Set Text( "" )} ),
     Dispatch( {}, "Y title", TextEditBox, {Set Text( para[i] )} )
     )
    ) << report;
   )
  )
 )
);

 

Re: combinar ventanas gráficas a través de bucle

¡Muchas gracias por su respuesta! Ahora lo entiendo. ¡Gracias!

 

Re: combinar ventanas gráficas a través de bucle

El problema con el que se está ejecutando es que no ha guardado los punteros en las diferentes ventanas que ha creado.  He modificado su script (ver más abajo), para guardar las referencias a las 6 ventanas que crea, a una lista llamada "alWindowList".  Contiene los seis punteros a las ventanas.  Se puede utilizar en una ventana de combinación para unir las ventanas.

También noté en su script que la visualización de la aerolínea y la etiqueta no se muestra de manera significativa, por lo que también modifiqué el script para forzar al código a usar los valores reales, en lugar de al [j] y para [ i] mostrar.

Names Default To Here( 1 );

sourcedt = Open( "$SAMPLE_DATA\Airline Delays.jmp" );

dt = sourcedt << Stack(
 columns( :Elapsed Time, :Arrival Delay, :Distance ),
 Source Label Column( "Label" ),
 Stacked Data Column( "Value" )
);

Summarize( dt, al = By( :Airline ) );
Summarize( dt, mon = By( :Month ) );
Summarize( dt, para = By( :Label ) );
alWindowList = {};

For( j = 1, j <= N Items( al ), j++,
 nw = New Window( al[j],
  V List Box(
 
   For( i = 1, i <= N Items( para ), i++,
    Eval(
     Substitute(
       Expr(
        Graph Builder(
         Size( 230, 300 ),
         Fit to Window( "Off" ),
         Show Control Panel( 0 ),
         Variables( X( :Month ), Y( :Value ), Overlay( :Day of Week ) ),
         Elements( Points( X, Y, Legend( 1 ) ) ),
         Where( :Airline == __al__ & :Label == __para__ ),
         SendToReport(
          Dispatch( {}, "Value", ScaleBox, {Min( -10 ), Minor Ticks( 0 )} ),
          Dispatch( {}, "graph title", TextEditBox, {Set Text( "" )} ),
          Dispatch( {}, "Y title", TextEditBox, {Set Text( para[i] )} )
         )
        ) << report
       ),
      Expr( __al__ ), al[j],
      Expr( __para__ ), para[i]
     )
    )
   )
  )
 );
 Insert Into( alWindowList, nw );
);

Re: combinar ventanas gráficas a través de bucle

Hola txnelson

 

Tengo que reutilizar este código (similar) para un contexto diferente, pero parece que ya no funciona. Es decir, los títulos de la ventana no aparecen en la lista para la ventana de combinación o como informes disponibles para agregar a un panel. Vuelvo a ejecutar tu código a continuación, existe el mismo problema. Recientemente hemos actualizado a 14.2 ..... ¿podría ser ese el problema?

 

Muchas gracias.

Derchieh