35823_zh-CN

liliconcom

JSL：DT<

正常的“SelectWhere”用法如下：

dt<<SelectWhere(:ExampleColumnName > 5);

这很好用。 我遇到的困难是当我需要更灵活地选择“:ExampleColumnName”时。

 

例如，如果我在拟合模型中保存新的 Studentized Residuals 列，它将创建一个名为“Studentized Resid Log(CFU/mL) By Condition”的列。 假设我想选择高于 3 或低于 -3 的任何值。 由于该列的名称，我需要使用：

dt<<SelectWhere(:Name("Studentized Resid Log(CFU/mL) By Condition")<-3 | :Name("Studentized Resid Log(CFU/mL) By Condition")>3);

大多数时候这都很好，但并非总是如此。 必须在 :Name() 中完全写出字符串并不是很理想 - 例如，如果计划使一个函数可用于各种拟合模型，每个拟合模型将产生不同的 Studentized Residual 列名称，那么它是不理想的为每个可能的模型编写唯一的“SelectWhere”效率不高（特别是如果您不能总是预测用户将选择什么模型）。

 

我想要的工作是以下一项/两项：

//Option 1
colName = ""Studentized Resid Log(CFU/mL) By Condition";
dt<<SelectWhere(:Name(colName)<-3 | ::Name(colName)>3);

//Option 2
colRef = Column(dt, colName);
dt<<SelectWhere( colRef <-3 | colRef >3 );

当运行 SelectWhere 函数时，选项 1 返回“名称参数必须是带引号的字符串”错误。 似乎 :Name() 需要一个完全写出的字符串，并且对一个字符串的引用是不可接受的。

 

选项 2 不返回任何错误，但不会选择任何内容。 SelectWhere 似乎没有像显式键入“：XXXX”引用那样对待列引用变量。

 

我当前的解决方法不是很好：在 Fit Model 创建新列后，将表上的最后一列重命名为简单且唯一的名称（例如“StdResid”），可以直接在 SelectWhere 的“正常用法”中使用（例如，“ ：标准残留”）。

 

我是否错过了一些明显的东西，可以让我的生活更轻松？

 

另外，有什么方法可以让选项 1 和/或选项 2 发挥作用吗？

回复：JSL：DT<

我大部分时间都使用 As Column。 它适用于字符串名称或列引用：

 

dt = Open("$SAMPLE_DATA/Big Class.jmp");

// column name
col = "height"; 
dt << Select Where( AsColumn(col) <60 );

Wait(2);
dt  << Clear Row States;

// column reference
col = Column(dt,"height");
dt << Select Where( AsColumn(col) > 65 );

如果我觉得需要将实际的文本字符串嵌入到 :Name 中，那么我会使用所示的其他方法，尽管我使用其他我认为更容易处理的语法：

dt = Open("$SAMPLE_DATA/Big Class.jmp");
colName = "height";
Eval(Parse(EvalInsert("\[ 
 dt << Select Where( :Name("^colName^") > 65 );
]\")));

回复：JSL：DT<

你好，

我认为需要理解的重要部分是每个返回的内容：

• :Name() 语法是一种特殊的解析器，它只接受字符串参数，如您所见。 这使得脚本编写非常不灵活。
• Column() 函数返回对整个列的引用。 SelectWhere() 对每一行执行比较。 向 Column() 函数添加 Row() 下标（或只是 []）将指示 JMP 查看当前行上的列，无论 SelectWhere() 执行比较时是什么。

colName = "Studentized Resid Log(CFU/mL) By Condition";

dt << Select Where( Column( colName )[] < -3 | Column( colName )[] > 3 );

• As Column() 函数返回对当前行指定列中的值的引用。 在 SelectWhere() 的上下文中，当前行由 SelectWhere() 控制。 这就是为什么 Row() 下标不是必需的@pmroz的例子。  

希望有帮助！

回复：JSL：DT<

两个都是好主意，谢谢。 我之前一直尝试使用 Column(dt, colName) ，但不知道 AsColumn() 的存在。

 

我仍然希望有一天看到选项 1 和选项 2 的功能得以实现。 提出这个问题的最佳方式是什么？

回复：JSL：DT<

JSL 和列名称令人困惑，尤其是当您尝试使用 GET ROWS WHERE 或 SELECT WHERE 时。 我倾向于使用该构造作为column(dt,“column-name”)。

 

这将起作用：

dt = New Table( "Test Table", Add Rows( 9 ),
 New Column( "Studentized Resid Log(CFU/mL) By Condition",
  Numeric, Continuous, Format( "Best", 12 ),
  Set Values( [-4, -3, -2, -1, 0, 1, 2, 3, 4] ) )
);

colName = "Studentized Resid Log(CFU/mL) By Condition";

dt << Select Where(as column(dt, colName) < -3 | as column(dt, colName) > 3);

回复：JSL：DT<

当没有其他方法似乎无法获得我需要的结果时，我使用以下方法：

Eval(parse("dt << select where(" || ":Name(\!"" || Char( Column( dt, 1 ) << get name ) || 
"\!")< -3 | :Name(\!"" || Char( Column( dt, 1 ) << get name ) || "\!")  > 3);"));