46732_zh-CN

liliconcom

使用JMP脚本修复分析结果的图形大小

你好

 

我试图在分析结果中修复框架框的大小，以下代码为例：

 

dt = Open( "$SAMPLE_DATA/Flight Distances.jmp" );
dt << Multidimensional Scaling(
    Y(
        :Birmingham,
        :Boston,
        :Buffalo,
        :Chicago,
        :Cleveland,
        :Dallas,
        :Denver,
        :Detroit,
        :El Paso,
        :Houston,
        :Indianapolis,
        :Kansas City,
        :Los Angeles,
        :Louisville,
        :Memphis,
        :Miami,
        :Minneapolis,
        :New Orleans,
        :New York,
        :Omaha,
        :Philadelphia,
        :Phoenix,
        :Pittsburgh,
        :St. Louis,
        :Salt Lake City,
        :San Francisco,
        :Seattle,
        :Washington DC
    ),
    SendToReport(
        Dispatch(
            {"Multidimensional Scaling Plot"},
            "MDS Report Plot",
            FrameBox,
            {Frame Size( 750, 500 )}
        )
    )
);

 

帧大小（750,500）是所需的设置。但是，单击“水平翻转”按钮的“垂直翻转”后，它变为默认设置。

 

                                 之前

 

有没有办法使用JMP脚本自动修改框架框的大小而不是右键单击框框并手动设置框架大小？

 

 

 

Re：使用JMP脚本修复分析结果的图形大小

非常感谢，这正是我所需要的。

Re：使用JMP脚本修复分析结果的图形大小

一种方法是设置帧大小并使用JSL翻转图形。  来自'mds << Show Tree Structure;'的报告显示'FrameBox（1）'的来源。

mds = dt << Multidimensional Scaling( ... );
mds << Flip Horizontal( 1 );
(mds << Find( FrameBox(1) )) << Frame Size ( 750, 500 );

 

要进行此交互式，您可以使用自己的替换翻转按钮：

Names default to here( 1 );

dt = Open( "$SAMPLE_DATA/Flight Distances.jmp" );
mds = dt << Multidimensional Scaling(
    Y(  :Birmingham, :Boston, :Buffalo, :Chicago, :Cleveland, 
  :Dallas, :Denver, :Detroit, :El Paso, :Houston, :Indianapolis, 
  :Kansas City, :Los Angeles, :Louisville, :Memphis, :Miami, 
  :Minneapolis, :New Orleans, :New York, :Omaha, :Philadelphia, 
  :Phoenix, :Pittsburgh, :St. Louis, :Salt Lake City, 
  :San Francisco, :Seattle, :Washington DC
    ),
    SendToReport(
  Dispatch(
   {"Multidimensional Scaling Plot"}, 
   "MDS Report Plot", 
   FrameBox, 
   {Frame Size( 750, 500 )} 
  )
 )
);

//Hide the default Flip buttons:
(mds << Find( Button Box(1) ) ) << visibility( "collapse" );
(mds << Find( Button Box(2) ) ) << visibility( "collapse" );

//Add new Flip buttons that set the frame size
(mds << Find( Listbox(3) )) << Append( Button Box( 
 "Flip Vertical New" , 
 mds << Flip Vertical( 1 );
 (mds << Find( FrameBox(1) )) << Frame Size ( 750, 500 )
));

(mds << Find( Listbox(3) )) << Append( Button Box( 
 "Flip Horizontal New" , 
 mds << Flip Horizontal( 1 );
 (mds << Find( FrameBox(1) )) << Frame Size ( 750, 500 )
));