53833_zh-CN

liliconcom

如何在循环中执行行操作？

你好，

我有一张如下表。

ABC ..n 列

1 2 3

7 6 4

3 7 9

.

.

m 行

我想编写一个脚本，使得每一列“第 n 行的值 = 第 n 行的值 - 第一行的值”，最后将第一行重置为 0。 所以最后我的桌子应该看起来像

美国广播公司

0 0 0..

6 4 1

2 5 6

.

.

有人可以帮我编写这样一个操作的脚本吗？ 谢谢

 

Re: 如何在循环中执行行操作？谢谢txnelson。 它完美地工作。Re: 如何在循环中执行行操作？

这里有几种循环的方法............还有更多的方法，但我会让其他人展示它们

Names Default To Here( 1 );

// Open the data table
dt1 = Open( "$SAMPLE_DATA\Blood Pressure.jmp" );

// Create a second copy
dt2 = dt1 << subset( selected columns( 0 ), selected rows( 0 ) );

// Get all numeric, continuous column names 
colList = dt1 << get column names( string, numeric, continuous );

// Loop across all numeric, continuous columns and use a 
// matrix operation to handle the math
For( i = 1, i <= N Items( colList ), i++,
 mat = Column( dt1, colList[i] ) << get values;
 mat = mat - mat[1];
 Column( dt1, colList[i] ) << set values( mat );
);


// Now do the same thing looping with the data in place
// Loop across all numeric, continuous columns
For( i = 1, i <= N Items( colList ), i++, 

 // Go through each row, from the bottom to the top to subtract
 // the value of the first row from each rows value
 For( k = N Rows( dt2 ), k >= 1, k--,
  Column( dt2, colList[i] )[k] = Column( dt2, colList[i] )[k] - Column( dt2, colList[i] )[1]
 )
);