57887_zh-CN

liliconcom

从趋势线预测未知数

简单的问题，希望得到一些帮助。我不是统计专家。

 

 

未知物的吸光度为 0.027

我需要找到未知的浓度。

有人，请告诉我要运行什么测试以及如何填充测试的单元格。

先感谢您。

一个。 库珀

 

 

回复：从趋势线预测未知数

谢谢你，马克。这就是我对这种方法发表评论的原因。 我期待一个关于模型的回复。

 

回复：从趋势线预测未知数

此案被称为校准问题或者逆向预测在 JMP 中。 选择分析>拟合模型， 放绝对值在里面是角色，添加浓至效果， 选择不拦截，然后单击跑. 单击拟合最小二乘旁边的红色小三角并选择估计>逆向预测. 您可以输入多个 Y 值并指定感兴趣的置信区间。 您还将获得 X 值的图和它们的表格。

回复：从趋势线预测未知数

一百万谢谢。

如果没有您的指导，我永远不会找到所有可以点击的正确按钮。

奥斯汀

回复：从趋势线预测未知数

这不是统计测试。 这项任务是拟合模型和方程，并从模型中估计未知数。

1. 见链接https://www.wikihow.com/Calculate-Molar-Absorptivity
   Abs = e*l*Conc 或 Conc = k*Abs 其中 k = 1/(e*l)
2. 主菜单>分析>用 X 拟合 Y , 指定浓度为是和 Abs 为X ， 按好的
3. 找到图表上方的红色菜单图标，选择 >适合特别. 选中旁边的框将截距限制为0 , 按好的
4. 找到图表下方的红色菜单图标，选择 >保存预测. 该表现在有预测值 [线上的点]，最后一行有一个值，其中 Abs = 0.027

如果这是一个班级作业，那么这个方法可能不是你所期望的。 [阅读你的课堂笔记。]我附上了一个 JSL 脚本，其中包含描述单击步骤以自定义报告的注释（绿色文本）。

Names Default to Here(1);

//create the table
dt = New Table( "Fit",
 Add Rows( 6 ),
 New Column( "Conc",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [0, 0.2, 0.5, 1, 2, .] )
 ),
 New Column( "Abs",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [0, 0.011, 0.063, 0.112, 0.243, 0.027] )
 )
);

//See link https://www.wikihow.com/Calculate-Molar-Absorptivity
//Abs = e*l*Conc or Conc = k*Abs where k = 1/(e*l)

//

//draw the graph
fm = dt <<  Fit Y by X(
 Y( :Conc ),
 X( :Abs )
);

//From the red inverted triangle menu icon, select> Fit Special, then check 
//the box to Constarin Intercept to 0
fm << Fit Special( Intercept( 0 ), {Line Color( {212, 73, 88} )} );

//From the red inverted triangle menu below the graph select > Save Predicteds
fm << (Curve[1] << Save Predicteds);

//Double click on the X-axis and check the boxes for Grid, Major and Minor
report(fm) [ScaleBox(1)] << {Label Row( {Show Major Grid( 1 ), Show Minor Grid( 1 )} )};

//Double click on the Y-axis and check the boxes for Grid, Major and Minor
report(fm) [ScaleBox(2)] << {Label Row( {Show Major Grid( 1 ), Show Minor Grid( 1 )} )};

//Double click on the X-axis again and in the lower box labeled Reference Lines
//enter 0.027, select a color and line style
report(fm) [ScaleBox(1)] << {Add Ref Line( 0.027, "Dotted", "Medium Dark Red", "", 2 )};

report(fm)[FrameBox(1)] << Add Text Annotation(
          Text( "Abs =0.027 \!N Pred Conc = 0.xxx" ),  //enter the predicted value 
    Text Box( {85, 192, 199, 232} ),
    Background Color( "Light Yellow" )
      );