49520_zh-CN

liliconcom

将双变量图保存为JPEG

嗨，我能得到双变量情节。但我无法将情节保存为图片，因为我在保存时出错。

 

任何帮助都会很棒。谢谢。

 

 

 

<BR />Open("C:\jmp_data\NamesData.jmp", window bounds(600, 50, 500, 400), window state(maximized)); 

window_DATA = New Window("NAMES SHOW", Bivariate(Y(:Name("AGES")), X(:Name("GENDER")), Fit Line({Line Color({100, 50, 50})}))) << Maximize Display << Set Window Icon("FitYByX"); <BR />
window_DATA << save picture( "C:\jmp_data\NamesAge.JPG", JPEG );

 

回复：将双变量图保存为JPEG

显然，至少在13.2.1中，“保存图片”消息有效但未记录。至少对我来说，只需在原始代码中添加括号即可。

回复：将双变量图保存为JPEG

Window对象没有可用的Save Picture消息。  有关可以传递给Window对象的消息，请参阅脚本索引。  您需要做的是在窗口中保存一个支持Save Picture消息的对象。这是一种可能的解决方案

Names Default to Here( 1 );
Open(
 "C:\jmp_data\NamesData.jmp",
 window bounds( 600, 50, 500, 400 ),
 window state( maximized )
); 

window_DATA = New Window( "NAMES SHOW",
 Biv = Bivariate(
  Y( :Name( "AGES" ) ),
  X( :Name( "GENDER" ) ),
  Fit Line( {Line Color( {100, 50, 50} )} )
 )
) << Maximize Display << Set Window Icon( "FitYByX" );
report( Biv ) << save picture( "C:\jmp_data\NamesAge.JPG", JPEG );

回复：将双变量图保存为JPEG

我假设您得到的错误与需要可编写脚本的对象有关。  现在您向窗口发送消息并将发送消息的结果保存到window_DATA。  您想要保存对窗口本身的引用，然后向其发送消息。  有两种选择：

1. 在一个'line'中完成所有操作，类似于现在的代码，但是使用操作顺序来确保在向窗口发送消息之前定义变量，或者
2. 这两行做到这一点。

我推荐后者，因为它更具可读性。

Names default to here( 1 );

dt = Open("$Sample_data/iris.jmp"); 

//All at once
( window_DATA_1 = New Window( "NAMES SHOW", 
 Bivariate( 
  Y( :Name( "Sepal length" ) ), 
  X( :Name( "Petal length" ) ), 
  Fit Line( {Line Color( {100, 50, 50} )} )
 ) 
) ) << Maximize Display << Set Window Icon( "FitYByX" );

window_DATA_1 << save picture( "$Desktop\Picture_1.JPG", JPEG );

//In two steps
window_DATA_2 = New Window( "NAMES SHOW", 
 Bivariate( 
  Y( :Name( "Sepal length" ) ), 
  X( :Name( "Petal length" ) ), 
  Fit Line( {Line Color( {100, 50, 50} )} )
 ) 
);

window_DATA_2 << Maximize Display << Set Window Icon( "FitYByX" );

window_DATA_2 << save picture( "$Desktop\Picture_2.JPG", JPEG );