60425_zh-CN

liliconcom

如何在JSL中动态连接n个数据表

我正在创建一个脚本来为一位 JMP 新手用户自动化工作流程。 该脚本的第一个操作是合并模型运行中的所有数据迭代。 这是通过以下方式实现的：

 

1. 系统会提示用户选择代表各个数据表的目录n模型运行的迭代。
2. 该脚本打开所有具有预定义名称的迭代数据表，后跟迭代编号：“SGR Scenaio Iteration i”。
3. 打开每个迭代数据表时，会添加迭代列并预填充迭代编号。
4. 打开所有数据表后，将数据表 2 至 10 连接到第一个数据表，以创建一个名为“SGR Scenario Combined Iterations”的新组合数据表。
5. 然后关闭原始迭代而不保存；这是为了保留原始数据表。

以下是完成上面列出的任务的脚本第一部分的代码：

 

Names Default to Here(1);
Delete Symbols();

//----------------------------------------------------------------------------------------------
// Select file path, then import and combine all iteration data tables into a single data table 
// of replicates of sorties completed across iterations.
//----------------------------------------------------------------------------------------------
path = Pick Directory("Select the directory containing the iteration files.");

iterationFile = path || "SGR Scenario Iteration 1.jmp";
dtIterationTables = Open(iterationFile, "Invisible");

// add Iteration column
dtIterationTables << New Column(
 "Iteration",
 Ordinal,
 Set Each Value(1)
);

dtIterationTables << Move Selected Columns(
 {"Iteration"},
 After(:Time of Day)
);

// get remaining iteration tables
i = 2;
iterationFile = path || "SGR Scenario Iteration 2.jmp";
While(File Exists(iterationFile),
 nTables = i;
 dtIterationFile = Open(iterationFile, "Invisible");
 
 // add Iteration column
 dtIterationFile << New Column(
  "Iteration",
  Ordinal,
  Set Each Value(i)
 );

 dtIterationFile << Move Selected Columns(
  {"Iteration"},
  After(:Time of Day)
 );
 
 //look for next iteration table
 i++;
 iterationFile = path || "SGR Scenario Iteration " || Char(i) || ".jmp";
);

// concatenate current interation table to first iteration table
// NOTE: AWAITING RESPONSE ON HOW TO MAKE THIS PROCESS DYNAMIC
Data Table("SGR Scenario Iteration 1") << Concatenate(
 Data Table("SGR Scenario Iteration 2"),
 Data Table("SGR Scenario Iteration 3"),
 Data Table("SGR Scenario Iteration 4"),
 Data Table("SGR Scenario Iteration 5"),
 Data Table("SGR Scenario Iteration 6"),
 Data Table("SGR Scenario Iteration 7"),
 Data Table("SGR Scenario Iteration 8"),
 Data Table("SGR Scenario Iteration 9"),
 Data Table("SGR Scenario Iteration 10"),
 Output Table("SGR Scenario Combined Iterations")
);

// close original iteration tables
i = 1;
While(i <= nTables,
 dtIterationTable = Data Table("SGR Scenario Iteration " || Char(i));
 Close(dtIterationTable);
 Clear Symbols(dtIterationTable);
 i++;
);<BR />

我遇到的问题是第 4 步。 当前脚本被硬编码为连接 10 个数据表，但我需要能够连接n数据表，这样我的同事就不会被锁定只处理 10 次迭代，或者更糟糕的是，每次数据集大小发生变化时都必须尝试编辑 JSL 代码（阅读：来找我更改脚本）。 你可以在代码中看到我有一个变量， n表，这是打开的数据表数量的计数，因为每个其他代码块都设置为处理n数据表。

 

任何有关此事的帮助将不胜感激。

数据混合和清理回复：如何在 JSL 中动态连接 n 个数据表

我必须对您建议的解决方案进行一些清理，但它基本上有效。 这是我的脚本前端的更新代码：

 

Names Default to Here(1);
Delete Symbols();

//----------------------------------------------------------------------------------------------
// Select file path, then import and combine all iteration data tables into a single data table 
// of replicates of sorties completed by te hour across iterations.
//----------------------------------------------------------------------------------------------
path = Pick Directory("Select the directory containing the iteration files.");

iterationFile = path || "SGR Scenario Iteration 1.jmp";
dtIterationTables = Open(iterationFile, "Invisible");
dtIterationTables << Set Name("SGR Scenario Combined Iterations");

// add Iteration column
dtIterationTables << New Column(
 "Iteration",
 Ordinal,
 Set Each Value(1)
);

dtIterationTables << Move Selected Columns(
 {"Iteration"},
 After(:Time of Day)
);

// get remaining iteration tables
i = 2;
iterationFile = path || "SGR Scenario Iteration " || Char(i) || ".jmp";
While(File Exists(iterationFile),
 dtIterationFile = Open(iterationFile, "Invisible");
 
 // add Iteration column
 dtIterationFile << New Column(
  "Iteration",
  Ordinal,
  Set Each Value(i)
 );
 
 // append current iteration table to combined table
 dtIterationTables = dtIterationTables << Concatenate(
  dtIterationFile,
  Append to first table(1)
 );
 Close(dtIterationFile, NoSave);
 
 //look for next iteration data table
 i++;
 iterationFile = path || "SGR Scenario Iteration " || Char(i) || ".jmp";
);

//----------------------------------------------------------------------------------------------
// Add Replicate column and then create data table with simplified statistical model.
//----------------------------------------------------------------------------------------------
dtIterationTables << New Column(
 "Replicate",
 Ordinal,
 Formula(Num(Right(:Time of Day, Length(:Time of Day) - Contains(:Time of Day, " "))))
);

dtIterationTables << Move Selected Columns(
 {"Replicate"},
 After(:Iteration)
);

// make data set more flexible by stacking the hour columns to simplify the statistical model
dtIterationTables << Stack(
 columns(
  :Name("1200"),
  :Name("1300"),
  :Name("1400"),
  :Name("1500"),
  :Name("1600"),
  :Name("1700"),
  :Name("1800"),
  :Name("1900"),
  :Name("2000"),
  :Name("2100"),
  :Name("2200")
 ),
 Source Label Column("Hour"),
 Stacked Data Column("Sorties Completed"),
 Copy formula(0),
 Name("Non-stacked columns")(Keep(:Iteration, :Replicate)),
 Output Table("Combined SGR Scenario Iterations")
);

dtAllIterations = Data Table("Combined SGR Scenario Iterations");
Close(dtIterationTables, NoSave);

dtAllIterations:Hour << Set Modeling Type("Ordinal");
dtAllIterations << Save As(path || "Combined SGR Scenario Iterations.jmp");

谢谢您的帮助！

回复：如何在 JSL 中动态连接 n 个数据表

看看下面的代码。我应该给你想要的。我无法真正测试代码，但我相信它非常准确。它采用的方法不必跟踪已读入的数据表数量，因为它在输入每个文件后进行串联。

Names Default to Here(1);
Delete Symbols();

//----------------------------------------------------------------------------------------------
// Select file path, then import and combine all iteration data tables into a single data table 
// of replicates of sorties completed across iterations.
//----------------------------------------------------------------------------------------------
path = Pick Directory("Select the directory containing the iteration files.");

iterationFile = path || "SGR Scenario Iteration 1.jmp";
dtBaseIterationTables = Open(iterationFile, "Invisible");

dtBaseIterationTable << set name( "SGR Scenario Combined Iterations" );

// add Iteration column
dtBaseIterationTables << New Column(
 "Iteration",
 Ordinal,
 Set Each Value(1)
);

dtBaseIterationTables << Move Selected Columns(
 {"Iteration"},
 After(:Time of Day)
);

// get remaining iteration tables
i = 2;
//iterationFile = path || "SGR Scenario Iteration 2.jmp";
While(File Exists(path || "SGR Scenario Iteration " || char( i ) || ".jmp";),
 //nTables = i;
 dtIterationFile = Open(path || "SGR Scenario Iteration " || char( i ) || ".jmp", "Invisible");
 
 // add Iteration column
 dtIterationFile << New Column(
  "Iteration",
  Ordinal,
  Set Each Value(i)
 );

 /* // Not required since the columns from this table will align with the base table
 dtIterationFile << Move Selected Columns(
  {"Iteration"},
  After(:Time of Day)
 )*/;
 
 //look for next iteration table
 i++;
 // iterationFile = path || "SGR Scenario Iteration " || Char(i) || ".jmp"; 
 
 dtBaseIterationTables = dtBaseIterationTables << Concatenate( dtIterationFile, append to first table( 1 ) );
 
 close( dtIterationFile, nosave );
);<BR /><BR />dtBaseIterationTables << Show Window( 1 );

/*// concatenate current interation table to first iteration table
// NOTE: AWAITING RESPONSE ON HOW TO MAKE THIS PROCESS DYNAMIC
Data Table("SGR Scenario Iteration 1") << Concatenate(
 Data Table("SGR Scenario Iteration 2"),
 Data Table("SGR Scenario Iteration 3"),
 Data Table("SGR Scenario Iteration 4"),
 Data Table("SGR Scenario Iteration 5"),
 Data Table("SGR Scenario Iteration 6"),
 Data Table("SGR Scenario Iteration 7"),
 Data Table("SGR Scenario Iteration 8"),
 Data Table("SGR Scenario Iteration 9"),
 Data Table("SGR Scenario Iteration 10"),
 Output Table("SGR Scenario Combined Iterations")
);

// close original iteration tables
i = 1;
While(i <= nTables,
 dtIterationTable = Data Table("SGR Scenario Iteration " || Char(i));
 Close(dtIterationTable);
 Clear Symbols(dtIterationTable);
 i++;
);*/