在图形生成器中添加已知斜率的回归线大家好，
我喜欢使用 XY 相关图表的图形生成器而不是使用双变量。 有人知道图形生成器中的天气我们可以做回归线或用已知斜率拟合线吗？ 用户可以定义拟合斜率吗？我想使用图形生成器，因为我想将多个图表分成 GX 和 GY 组。
非常感谢您的投入。
内存
消费者和市场研究数据探索和可视化回复：具有已知斜率的 JMP Graph Builder 回归线（斜率用户定义）您可以在“Fit Y By X”中使用“Fit Special”，然后采用以下方法@tx尼尔森：
NamesDefaultToHere(1);
// Example data
dt = Open("$SAMPLE_DATA/Big Class.jmp");
// Plot data
biv = dt << Bivariate(Y( :height ), X( :weight ), Invisible);
// Fit Special
myIntercept = 0;
biv << Fit Special( Intercept( myIntercept ));
// Save formula to table
biv << (Curve[1] << savePredicteds);
// Close Bivariate
Report(biv) << closeWindow;
// Get the formula
form = Column(dt, "Predicted Height") << getFormula;
// Express the formula as a function of x so 'YFunction()' will work
SubstituteInto(form, Expr(:weight), Expr(x));
// Use Graph Builder
gb = dt << Graph Builder(
Show Control Panel( 0 ),
Variables( X( :weight ), Y( :height ) ),
Elements( Points( X, Y, Legend( 3 ) ) )
);
// Add the graphics script
gbRep = Report(gb);
addScript = Expr(gbRep[FrameBox(1)] << addGraphicsScript(PenColor("Red"); YFunction(formTBD, x)));
SubstituteInto(addScript, Expr(formTBD), NameExpr(form));
addScript;
回复：具有已知斜率的 JMP Graph Builder 回归线（斜率用户定义）如果我只知道截距而不知道斜率的情况怎么样？
回复：具有已知斜率的 JMP Graph Builder 回归线（斜率用户定义）你好@内存,
是的，您可以使用自定义图形脚本来完成此操作。 在图形生成器或任何与此相关的图形中，右键单击>自定义。 然后，单击加号添加新的图形脚本。 有一个适合您的 ay 函数模板，您可以自定义/更改 y 函数的斜率（或您喜欢的任何其他内容）。 下面是一个简短的视频展示了这一点。 这是您要找的吗？
我希望这有帮助！
朱利安
回复：具有已知斜率的 JMP Graph Builder 回归线（斜率用户定义）虽然没有什么像双变量图中那样简单，但为了添加函数，您可以使用图形生成器中的自定义功能，并显示您想要的任何类型的函数
这是使用以下自定义功能添加到图形生成器中的非常简单的线性方程
Pen Color( "red" );
Pen Size( 3 );
intercept = 50;
beta = .2;
Y Function( intercept + beta * x, x );
回复：具有已知斜率的 JMP Graph Builder 回归线（斜率用户定义）我如何调整斜率或如何改变拟合线的斜率。回复：具有已知斜率的 JMP Graph Builder 回归线（斜率用户定义）拟合线是可以放置在图形生成器图形上的项目之一
