187649_zh-TW

liliconcom

PCA - 相關性顏色圖

大家好，

 

我正在執行 PCA 分析，我非常喜歡使用「相關性顏色圖」來視覺化相關性。 但是，我希望在該圖的 x 和 y 處添加我的變數標籤（請參閱附圖）。 有什麼辦法可以做到這一點嗎？

 

謝謝你！

回覆：PCA - 相關性顏色圖

我正在瀏覽一些舊帖子，我想更新這個帖子。您會很高興知道在 JMP 15 中，相關性的顏色圖已得到改進，並且可以實現您在原始帖子中想要的功能。  

我喜歡 JMP 開發團隊傾聽並做出這樣的小改進，讓客戶滿意！  

回覆：PCA - 相關性顏色圖

您可以透過幾個步驟來完成此操作：

在多元平台或主成分平台中，顯示相關矩陣。

然後右鍵單擊該矩陣並選擇“製作成資料表”。

 

 

產生這個新表

 

 

您將必須對該相關表進行一些操作：
使用「表」>「堆疊」建立包含 3 列的高版本表：一列包含用於 X 軸類別的變數名稱，另一列包含 Y 軸類別，以及一列包含變數的相關性前兩列。

 

現在您可以使用圖形產生器來建立這些相關性的熱圖。我確實必須在軸設定中反轉 X 軸上變數的順序才能獲得您想要的結果。

 

 

這是一個腳本，它在範例資料表（“BodyMeasures.JMP”）上重新建立所有這些步驟，我用它來說明所有這些。

 

dt = Open( "$SAMPLE_DATA/Body Measurements.jmp" );
pca = dt << Principal Components(
 Y(
  :Mass,
  :Fore,
  :Bicep,
  :Chest,
  :Neck,
  :Shoulder,
  :Waist,
  :Height,
  :Calf,
  :Thigh,
  :Head
 ),
 Correlations( 1 ),

);

dtcorr = Report( pca )["Correlations"][Matrix Box( 1 )] <<
Make Into Data Table;

dtcorrstacked = dtcorr << Stack(
 columns(
  :Mass,
  :Fore,
  :Bicep,
  :Chest,
  :Neck,
  :Shoulder,
  :Waist,
  :Height,
  :Calf,
  :Thigh,
  :Head
 ),
 Source Label Column( "VariableYAxis" ),
 Stacked Data Column( "Correlation" )
);
dtcorrstacked << Set Name( "Stacked Correlations" );
Close( dtcorr, NoSave );
Column( dtcorrstacked, "Row" ) << Set Name( "VariableXAxis" );
dtcorrstacked << Graph Builder(
 Size( 531, 531 ),
 Show Control Panel( 0 ),
 Graph Spacing( 4 ),
 Variables(
  X( :VariableXAxis ),
  Y( :VariableYAxis ),
  Color( :Correlation )
 ),
 Elements( Heatmap( X, Y, Legend( 6 ) ) ),
 SendToReport(
  Dispatch( {}, "VariableXAxis", ScaleBox, {Reversed Scale} )
 )
);

 

回覆：PCA - 相關性顏色圖

僅供參考，我注意到“分析>多變量方法>多變量”為您提供了您想要的一半：