186735_es-ES

liliconcom

Gráfico de barras de Graph Builder filtrar por las 10 sumas principales

Tengo un gráfico de barras apiladas horizontales y quiero limitarlo solo a las 10 sumas principales por categoría del eje Y.  

 

Los datos tienen un año de pedidos de clientes.Cada fila es una línea de pedido que tiene un cliente, un valor y un país del cliente (entre otros datos).El eje x es la suma estadística de resumen del valor del pedido.El eje y es el nombre del cliente.Y el apilamiento (superposición) es por país del cliente.

 

Mi objetivo no es mostrar los 1000 clientes, sino solo los 10 principales por el total de los valores de sus pedidos.

El script en este momento se ve así, donde sales org. es el país del cliente

Graph Builder(
 Size( 905, 603 ),
 Variables(
  X( :Total Dollars Ordered ),
  Y(
   :Customer,
   Order By( :Total Dollars Ordered, Ascending, Order Statistic( "Sum" ) )
  ),
  Overlay( :Sales Organization Code )
 ),
 Elements(
  Bar( X, Y, Legend( 4 ), Bar Style( "Stacked" ), Summary Statistic( "Sum" ) )
 ),
 SendToReport(
  Dispatch(
   {},
   "graph title",
   TextEditBox,
   {Set Text( "Total Dollars Ordered by Customer" )}
  )
 )
)

Re: Gráfico de barras de Graph Builder filtrar por las 10 sumas principales

Esto es con lo que terminé yendo.Gracias por tu ayuda.

Los 20 primeros se veían mejor.

 

names default to here(1);
dt=current data table();

//Summarize the Total Dollars Ordered by Customer
dtSum = dt << Summary(
 Group( :Customer ),
 Sum( :Total Dollars Ordered ),
 Freq( "None" ),
 Weight( "None" ),
 statistics column name format( "column" ),
 Link to original data table( 0 )
);

//Sort the new data table
dtSum << sort( by(:Total Dollars Ordered), order(descending),replace table(1));

//Add Customer Sales Rank
//because the data is sorted the rank is the row number
dtSum << New Column("Customer Sales Rank", formula(Row()));
dtSum:Customer Sales Rank << delete property("formula");
dtSum << delete columns({"Total Dollars Ordered", "N Rows"});

//add the Customer Sales Rank back to the original data table
dt << Update(
 With( dtSum ) ,
 Match Columns( :Customer == :Customer )
);

//close the helper table
close(dtSum);

//Create the graph, horizontal bar graph, highest sales at the top, 
dt << Graph Builder(
 Size( 966, 804 ),
 //hide the control panel
 Show Control Panel( 0 ),
 Variables(
  X( :Total Dollars Ordered ),
  Y(
   :Customer,
   Order By( :Total Dollars Ordered, Ascending, Order Statistic( "Sum" ) )
  ),
  Overlay( :Sales Organization Code )
 ),
 Elements(
  Bar(
   X,
   Y,
   Legend( 4 ),
   Bar Style( "Stacked" ),
   Summary Statistic( "Sum" ),
   Label( "Label by Percent of Total Values" )
  )
 ),
 Local Data Filter(
  //hide the local filer
  Close Outline(1),
  Add Filter(
   columns( :Customer Sales Rank ),
   Where( :Customer Sales Rank >= 1 & :Customer Sales Rank <= 20 )
  )
 ),
 SendToReport(
  Dispatch(
   {},
   "graph title",
   TextEditBox,
   {Set Text( "Total Dollars Ordered by Customer" )}
  )
 )
)

Re: Gráfico de barras de Graph Builder filtrar por las 10 sumas principales

Vaya... mi error... ¡me alegro de que lo hayas captado!

Re: Gráfico de barras de Graph Builder filtrar por las 10 sumas principalesBien, el problema es "==", solo necesito uno "="Re: Gráfico de barras de Graph Builder filtrar por las 10 sumas principales

Me gusta el segundo enfoque.El script parece detenerse justo después de la primera sección del código.

dtSum == dt << Summary(
 Group( :Customer ),
 Sum( :Total Dollars Ordered ),
 Freq( "None" ),
 Weight( "None" ),
 statistics column name format( "column" ),
 Link to original data table( 0 )
);

Porque obtengo una nueva tabla de datos, pero no está ordenada y no tiene rango. Cuál es el siguiente conjunto de JSL.

Re: Gráfico de barras de Graph Builder filtrar por las 10 sumas principales

Le sugiero que cree una nueva tabla de datos que solo tenga los clientes que están en el top 10.El siguiente script genera el subconjunto y luego traza los datos.

names default to here(1);
dt=current data table();

dtSum == dt << Summary(
 Group( :Customer ),
 Sum( :Total Dollars Ordered ),
 Freq( "None" ),
 Weight( "None" ),
 statistics column name format( "column" )
);

dtSum << sort( by(:Total Dollars Ordered), order(descending),replace table(1));

dtSum << select where(Row()>10);

dtSum << delete rows;

dtFinal = dt<< Join(
 With( dtSum ),
 By Matching Columns( :Customer = :Customer ),
 Drop multiples( 0, 0 ),
 Include Nonmatches( 0, 0 ),
 Preserve main table order( 1 )
);

dtFinal << Graph Builder(
 Size( 905, 603 ),
 Variables(
  X( :Total Dollars Ordered ),
  Y(
   :Customer,
   Order By( :Total Dollars Ordered, Ascending, Order Statistic( "Sum" ) )
  ),
  Overlay( :Sales Organization Code )
 ),
 Elements(
  Bar( X, Y, Legend( 4 ), Bar Style( "Stacked" ), Summary Statistic( "Sum" ) )
 ),
 SendToReport(
  Dispatch(
   {},
   "graph title",
   TextEditBox,
   {Set Text( "Total Dollars Ordered by Customer" )}
  )
 )
);

No tenía una copia de sus datos, por lo que no probé completamente el script, pero creo que debería funcionar.

También puede modificar la secuencia de comandos para crear el número de pedido de la tabla de resumen y luego volver a unirlo a la tabla de datos original y usarlo en un filtro de datos local para permitir la selección en el pedido.

Aquí hay un script que es una aproximación de cómo crear el gráfico usando un filtro de datos local

names default to here(1);
dt=current data table();

dtSum == dt << Summary(
 Group( :Customer ),
 Sum( :Total Dollars Ordered ),
 Freq( "None" ),
 Weight( "None" ),
 statistics column name format( "column" ),
 Link to original data table( 0 )
);

dtSum << sort( by(:Total Dollars Ordered), order(descending),replace table(1));

dtSum << New Column("Rank", formula(Row()));
dtSum:Rank << delete property("formula");
dtSum << delete columns({"Total Dollars Ordered", "N Rows"})

dt<< Update(
 With( dtSum ) ,
 Match Columns( :Customer == :Customer )
);


dt << Graph Builder(
 Size( 905, 603 ),
 Variables(
  X( :Total Dollars Ordered ),
  Y(
   :Customer,
   Order By( :Total Dollars Ordered, Ascending, Order Statistic( "Sum" ) )
  ),
  Overlay( :Sales Organization Code )
 ),
 Elements(
  Bar( X, Y, Legend( 4 ), Bar Style( "Stacked" ), Summary Statistic( "Sum" ) )
 ),
 SendToReport(
  Dispatch(
   {},
   "graph title",
   TextEditBox,
   {Set Text( "Total Dollars Ordered by Customer" )}
  )
 ),
 Local Data Filter(
  Add Filter( columns( :Rank ), Where( :Rank >= 1 & :Rank <= 11 ) )
);