184128_es-ES

liliconcom

Cox-Snell R2

Hola a todos,

Estoy estimando una regresión logística y necesito obtener el Cox-Snell R ² ¿Está escondido en algún lugar o tengo que calcularlo manualmente? ¿Alguien tiene el guión a mano?

JMP solo me da McFadden y Nagelkerke por defecto.

Estas son las definiciones que estoy siguiendo:

https://stats.idre.ucla.edu/other/mult-pkg/faq/general/faq-what-are-pseudo-r-squareds/

 

¡gracias!

Ron

Re: Cox-Snell R2

Tendrá que calcularlo a partir de los resultados presentados en el informe de la prueba del modelo completo utilizando la fórmula que citó. No conozco un script para este cálculo, pero puede buscar en el área de intercambio de archivos de esta comunidad. No sé si es necesario un guión. La fórmula es bastante simple.

Re: Cox-Snell R2

El guión no es tan malo después de todo. Este ejemplo muestra una forma en que puedes hacerlo:

 

Names Default to Here( 1 );

// example case: Big Class
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

// fit binary logistic model
lr = dt << Fit Model(
 Y( :sex ),
 Effects( :age, :height, :weight ),
 Personality( "Nominal Logistic" ),
 Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) )
);

// access Whole Model Test report
lr rep = (lr << Report)["Whole Model Test"];

// obtain likelihood for reduced and full models
L intercept = Exp( -(lr rep[NumberColBox(1)] << Get( 3 )) );
L full      = Exp( -(lr rep[NumberColBox(1)] << Get( 2 )) );
N           = lr rep[NumberColBox(8)] << Get( 1 );

// compute Cox-Snell R square
r sqr cs    = 1 - (L intercept/L full)^(2/N);

// copy original report
label = lr rep[StringColBox(2)] << Insert Row( 2, { "RSquare (C-S)" } ) << Clone Box;
r sqr u = lr rep[NumberColBox(5)] << Get( 1 );
aicc    = lr rep[NumberColBox(6)] << Get( 1 );
bic     = lr rep[NumberColBox(7)] << Get( 1 );

// replace with new report
lr rep[Tablebox(2)] << Delete;
lr rep << Append(
 TableBox(
  label,
  Number Col Box( "", { r sqr u, r sqr cs, aicc, bic, N } )
 )
);

Re: Cox-Snell R2

¡Es interesante que todos mis comentarios hayan desaparecido!

Re: Cox-Snell R2Gracias Mark. funciona perfecto

Ron