184128_ko-KR

liliconcom

콕스-스넬 R2

안녕하세요 여러분,

로지스틱 회귀를 추정하고 있으며 다음을 얻어야 합니다. 콕스-스넬 아르 자형 ² 어딘가에 숨겨져 있나요? 아니면 수동으로 계산해야 하나요? 누구든지 스크립트를 편리하게 가지고 있나요?

JMP는 기본적으로 McFadden과 Nagelkerke만 제공합니다.

내가 따르는 정의는 다음과 같습니다.

https://stats.idre.ucla.edu/other/mult-pkg/faq/general/faq-what-are-pseudo-r-squareds/

 

감사합니다!

론

답장: 콕스-스넬 R2고마워요 마크. 완벽하게 작동합니다.

론
답장: 콕스-스넬 R2

결국 스크립트는 그리 나쁘지 않습니다. 이 예에서는 이를 수행할 수 있는 한 가지 방법을 보여줍니다.

 

Names Default to Here( 1 );

// example case: Big Class
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

// fit binary logistic model
lr = dt << Fit Model(
 Y( :sex ),
 Effects( :age, :height, :weight ),
 Personality( "Nominal Logistic" ),
 Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) )
);

// access Whole Model Test report
lr rep = (lr << Report)["Whole Model Test"];

// obtain likelihood for reduced and full models
L intercept = Exp( -(lr rep[NumberColBox(1)] << Get( 3 )) );
L full      = Exp( -(lr rep[NumberColBox(1)] << Get( 2 )) );
N           = lr rep[NumberColBox(8)] << Get( 1 );

// compute Cox-Snell R square
r sqr cs    = 1 - (L intercept/L full)^(2/N);

// copy original report
label = lr rep[StringColBox(2)] << Insert Row( 2, { "RSquare (C-S)" } ) << Clone Box;
r sqr u = lr rep[NumberColBox(5)] << Get( 1 );
aicc    = lr rep[NumberColBox(6)] << Get( 1 );
bic     = lr rep[NumberColBox(7)] << Get( 1 );

// replace with new report
lr rep[Tablebox(2)] << Delete;
lr rep << Append(
 TableBox(
  label,
  Number Col Box( "", { r sqr u, r sqr cs, aicc, bic, N } )
 )
);

답장: 콕스-스넬 R2

인용한 공식을 사용하여 전체 모델 테스트 보고서에 제시된 결과에서 이를 계산해야 합니다. 이 계산에 대한 스크립트는 모르지만 이 커뮤니티의 파일 교환 영역을 검색할 수 있습니다. 스크립트가 필요한지 모르겠습니다. 공식은 매우 간단합니다.