こんにちは、みんな、
ロジスティック回帰を推定しています。コックススネル R 2 それはどこかに隠れているのですかそれとも私はそれを手動で計算する必要がありますか？誰か便利なスクリプトを持っていますか？
JMPはデフォルトでMcFaddenとNagelkerkeのみを私に与えます。
これらは私がフォローしている定義です。
https://stats.idre.ucla.edu/other/mult-pkg/faq/general/faq-what-are-pseudo-r-squareds/
ありがとうございました！
ロン
あなたはあなたが引用した式を使用して全体モデルテストレポートに示された結果からそれを計算しなければならないでしょう。この計算のためのスクリプトはわかりませんが、このコミュニティの[File Exchange]領域を検索できます。スクリプトが必要かどうかわかりません。計算式はとても簡単です。
スクリプトは結局悪くないです。この例はあなたがそれをすることができる1つの方法を示しています：
Names Default to Here( 1 );
// example case: Big Class
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
// fit binary logistic model
lr = dt << Fit Model(
Y( :sex ),
Effects( :age, :height, :weight ),
Personality( "Nominal Logistic" ),
Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) )
);
// access Whole Model Test report
lr rep = (lr << Report)["Whole Model Test"];
// obtain likelihood for reduced and full models
L intercept = Exp( -(lr rep[NumberColBox(1)] << Get( 3 )) );
L full = Exp( -(lr rep[NumberColBox(1)] << Get( 2 )) );
N = lr rep[NumberColBox(8)] << Get( 1 );
// compute Cox-Snell R square
r sqr cs = 1 - (L intercept/L full)^(2/N);
// copy original report
label = lr rep[StringColBox(2)] << Insert Row( 2, { "RSquare (C-S)" } ) << Clone Box;
r sqr u = lr rep[NumberColBox(5)] << Get( 1 );
aicc = lr rep[NumberColBox(6)] << Get( 1 );
bic = lr rep[NumberColBox(7)] << Get( 1 );
// replace with new report
lr rep[Tablebox(2)] << Delete;
lr rep << Append(
TableBox(
label,
Number Col Box( "", { r sqr u, r sqr cs, aicc, bic, N } )
)
);