184128_de-DE

liliconcom

Cox-Snell R2

Hallo zusammen,

Ich schätze eine logistische Regression und muss die erhalten Cox-Snell R ² Versteckt es sich irgendwo oder muss ich es manuell berechnen? Hat jemand das Skript zur Hand?

JMP gibt mir standardmäßig nur McFadden und Nagelkerke.

Dies sind die Definitionen, denen ich folge:

https://stats.idre.ucla.edu/other/mult-pkg/faq/general/faq-what-are-pseudo-r-squareds/

 

Danke!

Ron

Betreff: Cox-Snell R2Danke Mark. Funktioniert perfekt.

Ron
Betreff: Cox-Snell R2

Das Drehbuch ist schließlich nicht schlecht. Dieses Beispiel zeigt eine Möglichkeit, wie Sie dies tun können:

 

Names Default to Here( 1 );

// example case: Big Class
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

// fit binary logistic model
lr = dt << Fit Model(
 Y( :sex ),
 Effects( :age, :height, :weight ),
 Personality( "Nominal Logistic" ),
 Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) )
);

// access Whole Model Test report
lr rep = (lr << Report)["Whole Model Test"];

// obtain likelihood for reduced and full models
L intercept = Exp( -(lr rep[NumberColBox(1)] << Get( 3 )) );
L full      = Exp( -(lr rep[NumberColBox(1)] << Get( 2 )) );
N           = lr rep[NumberColBox(8)] << Get( 1 );

// compute Cox-Snell R square
r sqr cs    = 1 - (L intercept/L full)^(2/N);

// copy original report
label = lr rep[StringColBox(2)] << Insert Row( 2, { "RSquare (C-S)" } ) << Clone Box;
r sqr u = lr rep[NumberColBox(5)] << Get( 1 );
aicc    = lr rep[NumberColBox(6)] << Get( 1 );
bic     = lr rep[NumberColBox(7)] << Get( 1 );

// replace with new report
lr rep[Tablebox(2)] << Delete;
lr rep << Append(
 TableBox(
  label,
  Number Col Box( "", { r sqr u, r sqr cs, aicc, bic, N } )
 )
);

Betreff: Cox-Snell R2

Sie müssen es anhand der im Gesamtmodelltestbericht dargestellten Ergebnisse anhand der von Ihnen genannten Formel berechnen. Ich kenne kein Skript für diese Berechnung, aber Sie könnten den Dateiaustauschbereich dieser Community durchsuchen. Ich weiß nicht, ob ein Skript notwendig ist. Die Formel ist ziemlich einfach.