184128_fr-FR

liliconcom

Cox-Snell R2

Salut tout le monde,

J'estime une régression logistique et j'ai besoin d'obtenir le Cox Snell R. ² est-ce qu'il se cache quelque part ou dois-je le calculer manuellement ? est-ce que quelqu'un a le script sous la main ?

JMP ne me donne que les McFadden et Nagelkerke par défaut.

voici les définitions que je suis:

https://stats.idre.ucla.edu/other/mult-pkg/faq/general/faq-what-are-pseudo-r-squareds/

 

merci!

Ron

Objet : Cox-Snell R2Merci Marc. fonctionne parfaitement.

Ron
Objet : Cox-Snell R2

Le scénario n'est pas trop mal finalement. Cet exemple montre une façon de procéder :

 

Names Default to Here( 1 );

// example case: Big Class
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

// fit binary logistic model
lr = dt << Fit Model(
 Y( :sex ),
 Effects( :age, :height, :weight ),
 Personality( "Nominal Logistic" ),
 Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) )
);

// access Whole Model Test report
lr rep = (lr << Report)["Whole Model Test"];

// obtain likelihood for reduced and full models
L intercept = Exp( -(lr rep[NumberColBox(1)] << Get( 3 )) );
L full      = Exp( -(lr rep[NumberColBox(1)] << Get( 2 )) );
N           = lr rep[NumberColBox(8)] << Get( 1 );

// compute Cox-Snell R square
r sqr cs    = 1 - (L intercept/L full)^(2/N);

// copy original report
label = lr rep[StringColBox(2)] << Insert Row( 2, { "RSquare (C-S)" } ) << Clone Box;
r sqr u = lr rep[NumberColBox(5)] << Get( 1 );
aicc    = lr rep[NumberColBox(6)] << Get( 1 );
bic     = lr rep[NumberColBox(7)] << Get( 1 );

// replace with new report
lr rep[Tablebox(2)] << Delete;
lr rep << Append(
 TableBox(
  label,
  Number Col Box( "", { r sqr u, r sqr cs, aicc, bic, N } )
 )
);

Objet : Cox-Snell R2

Vous devrez le calculer à partir des résultats présentés dans le rapport Whole Model Test en utilisant la formule que vous avez citée. Je ne connais pas de script pour ce calcul, mais vous pouvez effectuer une recherche dans la zone d'échange de fichiers de cette communauté. Je ne sais pas si un script est nécessaire. La formule est assez simple.