184128_zh-TW

liliconcom

考克斯-斯內爾 R2

大家好，

我正在估計邏輯回歸並且需要得到考克斯-斯內爾右²它隱藏在任何地方還是我必須手動計算它？有人手邊有腳本嗎？

預設情況下，JMP 僅提供 McFadden 和 Nagelkerke。

這些是我遵循的定義：

https://stats.idre.ucla.edu/other/mult-pkg/faq/general/faq-what-are-pseudo-r-squareds/

 

謝謝你！

榮恩

回覆：考克斯-斯內爾 R2謝謝馬克。工作完美。

榮恩
回覆：考克斯-斯內爾 R2

畢竟劇本還不錯。 此範例展示了一種實作方法：

 

Names Default to Here( 1 );

// example case: Big Class
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

// fit binary logistic model
lr = dt << Fit Model(
 Y( :sex ),
 Effects( :age, :height, :weight ),
 Personality( "Nominal Logistic" ),
 Run( Likelihood Ratio Tests( 1 ), Wald Tests( 0 ) )
);

// access Whole Model Test report
lr rep = (lr << Report)["Whole Model Test"];

// obtain likelihood for reduced and full models
L intercept = Exp( -(lr rep[NumberColBox(1)] << Get( 3 )) );
L full      = Exp( -(lr rep[NumberColBox(1)] << Get( 2 )) );
N           = lr rep[NumberColBox(8)] << Get( 1 );

// compute Cox-Snell R square
r sqr cs    = 1 - (L intercept/L full)^(2/N);

// copy original report
label = lr rep[StringColBox(2)] << Insert Row( 2, { "RSquare (C-S)" } ) << Clone Box;
r sqr u = lr rep[NumberColBox(5)] << Get( 1 );
aicc    = lr rep[NumberColBox(6)] << Get( 1 );
bic     = lr rep[NumberColBox(7)] << Get( 1 );

// replace with new report
lr rep[Tablebox(2)] << Delete;
lr rep << Append(
 TableBox(
  label,
  Number Col Box( "", { r sqr u, r sqr cs, aicc, bic, N } )
 )
);

回覆：考克斯-斯內爾 R2

您必須使用您引用的公式根據整個模型測試報告中提供的結果來計算它。 我不知道用於此計算的腳本，但您可以搜尋此社區的文件交換區域。 不知道是否需要腳本。 公式非常簡單。