MouseBox Selecting Multiple Images

msharp

I want to select multiple images using a mousebox.

 

Below is an example that I've scripted showing how one can select an image one at a time.  But since there could be potentially hundreds of pictures, I want my user to be able to select multiple images with a drag function instead of having to click each one.  Any tips?

 

Names Default To Here( 1 );

//dtFull contains image path information
dtFull = Current Data Table();
path1 = dtFull:LocalPath[20];
path2 = dtFull:LocalPath[21];
path3 = dtFull:LocalPath[22];
path4 = dtFull:LocalPath[23];
img = New Image( path1 );
img2 = New Image( path2 );
img3 = New Image( path3 );
img4 = New Image( path4 );

selected = [0, 0, 0, 0];
New Window( "test",
	H List Box(
		vlb = V List Box(
			mb = MouseBox(
				pb = Picture Box( img ),
				<<SetClickEnable( 1 ),
				<<SetClick(
					Function( {this, clickpt, event},
						If( event == "Pressed",
							selected[1] = !selected[1];
							If( selected[1],
								pb << Select,
								pb << Deselect
							);
						)
					)
				),

			),
			MouseBox(
				pb2 = Picture Box( img2 ),
				<<SetClickEnable( 1 ),
				<<SetClick(
					Function( {this, clickpt, event},
						If( event == "Pressed",
							selected[2] = !selected[2];
							If( selected[2],
								pb2 << Select,
								pb2 << Deselect
							);
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;
&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;						)
					)
				),

			)
		),
		V List Box(
			MouseBox(
				pb3 = Picture Box( img3 ),
				<<SetClickEnable( 1 ),
				<<SetClick(
					Function( {this, clickpt, event},
						If( event == "Pressed",
							selected[3] = !selected[3];
							If( selected[3],
								pb3 << Select,
								pb3 << Deselect
							);
						)
					)
				)
			),
			MouseBox(
				pb4 = Picture Box( img4 ),
				<<SetClickEnable( 1 ),
				<<SetClick(
					Function( {this, clickpt, event},
						If( event == "Pressed",
							selected[4] = !selected[4];
							If( selected[4],
								pb4 << Select,
								pb4 << Deselect
							);
						)
					)
				)
			)
		)
	)
);

Craige_Hales

 

You might need to turn off the page translate feature at the top of the page before grabbing this code.  The magic is in the last few lines; everything else is setup.  At the end, <<getChildBox(location) is being used in a loop for a grid of pixels (every 10 pixels X and Y) within the range selected by mouse down to the current mouse location.  getChildBox returns 1, 2, or 3 boxes in this example, depending if the pixel is in a bitmap (3rd box) or just in a border (2nd box), or just in the lineup child of the mousebox (1st box).  If a second box is found, make it have a red background.  Also notice the loop just before that that clears all the boxes to white.  This code runs on both mouse moves and a timer tick; the "button" argument tells why the function is called.  Pressed is the mouse-down location.  lb[borderbox(1)]<<getbackgroundcolor will tell you if a box is red or white when the Release event happens.  You could add a text label too.  Note the border left...bottom values are set based on the picture size to center the picture.  That will need some adjusting if text is added.

 

If you need more control, the graphbox with picture segments and mousetrap might be an alternative.

New Window( "selection test", mb = MouseBox( lb = Lineup Box( N Col( 10 ) ) ) );
// generate some pictures of various sizes
For( i = 1, i < 200, i++,
	rows = Random Uniform( 10, 100 );
	cols = Random Uniform( 10, 100 );
	ls = (120 - cols) / 2;
	rs = 120 - cols - ls;
	ts = (120 - rows) / 2;
	bs = 120 - rows - ts;
	red = J( rows, cols, Random Uniform( 0, 1 ) );
	green = J( rows, cols, Random Uniform( 0, 1 ) );
	blue = J( rows, cols, Random Uniform( 0, 1 ) );
	lb << append(
		Border Box( sides( 15 ), Left( ls ), Right( rs ), top( ts ), bottom( bs ), New Image( "rgb", {red, green, blue} ) )
	);
);
mb << setclickenable( 1 );
mb << setclick(
	Function( {this, coords, button},
		If( button == "Pressed",
			{pressedX, pressedY} = coords,
			{thisX, thisY} = coords;
			xstart = Min( thisX, pressedX ) - 5;
			xstop = Max( thisX, pressedX ) + 5;
			xstep = 10;
			ystart = Min( thisY, pressedY ) - 5;
			ystop = Max( thisY, pressedY ) + 5;
			ystep = 10;
&nbsp; // turn off all previous selections
&nbsp;			For( b = lb << child, !Is Empty( b ), b = b << sib,
				b << setbackgroundcolor( "white" )
			);
&nbsp; // test points in the selection box
&nbsp;			For( x = xstart, x <= xstop, x += xstep,
				For( y = ystart, y <= ystop, y += ystep,
					boxes = mb << getchildbox( {x, y} );
					If( N Items( boxes ) >= 2,
						boxes[2] << setbackgroundcolor( "red" )
					);
				)
			);
		)
	)
);