46592_it-IT

liliconcom

Rientro del testo COLBOX

Sto usando i colbox all'interno di una tablebox.I colbox contengono una serie di caselle di testo, che mi consentono di controllare il colore di primo piano e di sfondo, nonché il grassetto del testo.Il problema è che il testo è troppo vicino al lato sinistro della sua colonna.Ecco un esempio in cui la prima colonna è una colbox contenente le icone, la seconda una stringcolbox e la terza una colbox contenente le caselle di testo:

 

Sono stato in grado di spostare le caselle delle icone nel file Stato colonna sull'utilizzo << imbottitura(sinistra10)) , ma a corto di aggiungere uno o due spazi iniziali a Testo di esempio colonna Non so come spostarla un po' a destra.Il Nome icona la colonna è OK, in quanto è una stringacolbox.Ecco il codice:

 

nw = new window("Test Col Box Justification",
 tb = table box(
  cb = col box("Status",
   i1 = icon box("Go"),
   i2 = icon box("DebuggerRunWithoutBreakpoints"),
   i3 = icon box("Locked"),
   i4 = icon box("WinRelaunchAnalysis"),
   i5 = icon box("Excluded"),
   i6 = icon box("SASTableMeta"),
   i7 = icon box("ColStack"),
   i8 = icon box("DataTableBox"),
   i9 = icon box("WinFileNewDT"),
   i10 = icon box("SASExportData"),
  ),
  sb = string col box("Icon Name", {"Go", "DebuggerRunWithoutBreakpoints", 
   "Locked", "WinRelaunchAnalysis", "Excluded", "SASTableMeta", "ColStack", 
   "DataTableBox", "WinFileNewDT", "SASExportData"}),
  tcb = col box("Sample Text",
   t1 = text box("The"),
   t2 = text box("quick"),
   t3 = text box("red"),
   t4 = text box("fox"),
   t5 = text box("jumped"),
   t6 = text box("over"),
   t7 = text box("the"),
   t8 = text box("oak"),
   t9 = text box("brown"),
   t10 = text box("log"),
  ),
 )
);

t1 << font color(51) << Set Font Style("Bold") << background color(73);
t3 << font color(51);
t9 << font color(54);
tb << set underline headings(1) << set column borders(1) << set row borders(1) << set shade alternate rows(1);
i1 << Padding( Left( 10 ));  i2 << Padding( Left( 10 ));
i3 << Padding( Left( 10 ));  i4 << Padding( Left( 10 ));
i5 << Padding( Left( 10 ));  i6 << Padding( Left( 10 ));
i7 << Padding( Left( 10 ));  i8 << Padding( Left( 10 ));
i9 << Padding( Left( 10 ));  i10 << Padding( Left( 10 ));

Re: Rientro del testo COLBOXGrazie Justin e Jim. La soluzione della scatola di confine è abbastanza pulita.Re: Rientro del testo COLBOX

Un consiglio veloce. Puoi applicare il padding a tutte le IconBox nel ColBox usando XPath invece di tenere traccia delle variabili e inviare le variabili Padding a ciascuna di esse.

Questo fa tutto in una riga:

(cb << Xpath( "//IconBox" )) << Padding( Left( 10 ) );

Re: Rientro del testo COLBOX

puoi aggiungere un H List Box() e Spacer Box() davanti a ogni Text Box() in ColBox().

 

nw = New Window( "Test Col Box Justification",
 tb = Table Box(
  cb = Col Box(
   "Status",
   i1 = Icon Box( "Go" ),
   i2 = Icon Box( "DebuggerRunWithoutBreakpoints" ),
   i3 = Icon Box( "Locked" ),
   i4 = Icon Box( "WinRelaunchAnalysis" ),
   i5 = Icon Box( "Excluded" ),
   i6 = Icon Box( "SASTableMeta" ),
   i7 = Icon Box( "ColStack" ),
   i8 = Icon Box( "DataTableBox" ),
   i9 = Icon Box( "WinFileNewDT" ),
   i10 = Icon Box( "SASExportData" ),

  ), 
  
  sb = String Col Box( "Icon Name",
   {"Go", "DebuggerRunWithoutBreakpoints", "Locked", "WinRelaunchAnalysis", "Excluded",
   "SASTableMeta", "ColStack", "DataTableBox", "WinFileNewDT", "SASExportData"}
  ),
  tcb = Col Box(
   "Sample Text",
   H List Box( Spacer Box( size( 5, 0 ) ), t1 = Text Box( "The" ) ),
   t2 = Text Box( "quick" ),
   t3 = Text Box( "red" ),
   t4 = Text Box( "fox" ),
   t5 = Text Box( "jumped" ),
   t6 = Text Box( "over" ),
   t7 = Text Box( "the" ),
   t8 = Text Box( "oak" ),
   t9 = Text Box( "brown" ),
   t10 = Text Box( "log" ),

  ),

 )
);

t1 << font color( 51 ) << Set Font Style( "Bold" ) << background color( 73 );
t3 << font color( 51 );
t9 << font color( 54 );
tb << set underline headings( 1 ) << set column borders( 1 ) << set row borders( 1 ) <<
set shade alternate rows( 1 );
i1 << Padding( Left( 10 ) );
i2 << Padding( Left( 10 ) );
i3 << Padding( Left( 10 ) );
i4 << Padding( Left( 10 ) );
i5 << Padding( Left( 10 ) );
i6 << Padding( Left( 10 ) );
i7 << Padding( Left( 10 ) );
i8 << Padding( Left( 10 ) );
i9 << Padding( Left( 10 ) );
i10 << Padding( Left( 10 ) );

Re: Rientro del testo COLBOX

Lo farei mettendo un BorderBox attorno a ciascuna delle caselle di testo. Ho aggiornato il tuo esempio per utilizzare una funzione per generare il BorderBox contenente un TextBox e ha un riempimento sinistro di 10.

borderedText = Function( {txt},
 Border Box( Left( 10 ), Text Box( txt ) )
);

nw = new window("Test Col Box Justification",
 tb = table box(
  cb = col box("Status",
   i1 = icon box("Go"),
   i2 = icon box("DebuggerRunWithoutBreakpoints"),
   i3 = icon box("Locked"),
   i4 = icon box("WinRelaunchAnalysis"),
   i5 = icon box("Excluded"),
   i6 = icon box("SASTableMeta"),
   i7 = icon box("ColStack"),
   i8 = icon box("DataTableBox"),
   i9 = icon box("WinFileNewDT"),
   i10 = icon box("SASExportData"),
  ),
  sb = string col box("Icon Name", {"Go", "DebuggerRunWithoutBreakpoints", 
   "Locked", "WinRelaunchAnalysis", "Excluded", "SASTableMeta", "ColStack", 
   "DataTableBox", "WinFileNewDT", "SASExportData"}),
  tcb = col box("Sample Text",
   t1 = borderedText("The"),
   t2 = borderedText("quick"),
   t3 = borderedText("red"),
   t4 = borderedText("fox"),
   t5 = borderedText("jumped"),
   t6 = borderedText("over"),
   t7 = borderedText("the"),
   t8 = borderedText("oak"),
   t9 = borderedText("brown"),
   t10 = borderedText("log"),
  ),
 )
);

t1 << background color(73);
t1[Text Box(1)] << font color(51) << Set Font Style("Bold");
t3[Text Box(1)] << font color(51);
t9[Text Box(1)] << font color(54);
tb << set underline headings(1) << set column borders(1) << set row borders(1) << set shade alternate rows(1);
i1 << Padding( Left( 10 ));  i2 << Padding( Left( 10 ));
i3 << Padding( Left( 10 ));  i4 << Padding( Left( 10 ));
i5 << Padding( Left( 10 ));  i6 << Padding( Left( 10 ));
i7 << Padding( Left( 10 ));  i8 << Padding( Left( 10 ));
i9 << Padding( Left( 10 ));  i10 << Padding( Left( 10 ));

 

Modifica: corretto un errore nel mio codice dovuto al fatto che le variabili t(n) ora sono un BorderBox.

Modifica 2: apportata un'altra modifica per evidenziare l'intera cella anziché solo la casella di testo.