41159_it-IT

liliconcom

Come copiare automaticamente se mancano i dati della colonna? (Script)

Ho bisogno di aggiornare quotidianamente questa tabella (come sotto)

Aggiornerò ogni giorno nuovo ID prodotto e ricetta_A & ricetta_B.

Quindi ho bisogno di ordinare recipe_A & recipe_B ad altri due colonne (sort_A & sort_B).

 

quindi copio recipe_A & recipe_B to sort_A & sort_B, ed esegui questo script (come sotto)

In questo modo, posso ricodificare sort_A & sort_B.

Current Data Table() << Begin Data Update;
For Each Row( :sort_A = Match( :sort_A, "ZXC", "worse", "QWE", "better", "ASD", "good", :sort_A ) );
Current Data Table() << End Data Update;


Current Data Table() << Begin Data Update;
For Each Row( :sort_B = Match( :sort_B, "R123", "rrr", "H123", "hhh", "G123", "ggg", :sort_B ) );
Current Data Table() << End Data Update;

La mia domanda è :

Come creare uno script per copiare automaticamente recipe_A e recipe_B in sort_A & sort_B?

(copia automatica se mancano i dati sort_A e sort_B)?

 

 

Ri: Come copiare automaticamente se mancano i dati della colonna? (Script)

Di seguito è riportata una rielaborazione del codice per verificare se esiste una colonna sort_A o sort_B e, in caso contrario, crearla e popolarla.  Se esiste, ripopola.  Poiché i risultati di sort_A e sort_B si basano sui valori di recipe_A e recipe_B, non è necessario copiare i valori in sort_A e sort_B e quindi modificare i valori in ciascuno.  È molto più semplice utilizzare i valori in recipe_A e recipe_B per impostare i valori in sort_A e sort_B.

Names Default To Here( 1 );
dt = Current Data Table();

// Get a list of the current columns in the data table
ColList = dt << get column names( string );

// See if a column named "sort_A" does not exist
If( N Rows( Loc( ColList, "sort_A" ) ) == 0,
    // If it does not exist, create the new column and use a formula to populate the values based upon the recipe_A values
 dt << New Column( "sort_A", character, formula( Match( :recipe_A, "ZXC", "worse", "QWE", "better", "ASD", "good", :recipe_A ) ) );
 // Remove the formula which will leave the results
 dt:sort_A << delete formula;
,
 // If the column already exists, then loop through the data table creating new values for sort_A based upon the recipe_A values
 For Each Row( :sort_A = Match( :recipe_A, "ZXC", "worse", "QWE", "better", "ASD", "good", :recipe_A ) )
);

// See if a column named "sort_B" does not exist
If( N Rows( Loc( ColList, "sort_B" ) ) == 0,
 // If it does not exist, create the new column and use a formula to populate the values based upon the recipe_B values
 dt << New Column( "sort_B", character, formula( Match( :recipe_B, "R123", "rrr", "H123", "hhh", "G123", "ggg", :recipe_B ) ) );
 dt:sort_B << delete formula;
,
 // If the column already exists, then loop through the data table creating new values for sort_B based upon the recipe_B values
 For Each Row( :sort_B = Match( :recipe_B, "R123", "rrr", "H123", "hhh", "G123", "ggg", :recipe_B ) )
);