41159_fr-FR

liliconcom

Comment copier automatiquement si les données de la colonne sont manquantes? (Script)

Je dois mettre à jour quotidiennement ce tableau (comme ci-dessous)

Je mettrai à jour les nouveaux produits ID & recette_A & recipe_B tous les jours.

Ensuite, j'ai besoin de trier recipe_A & recipe_B aux deux autres colonnes (sort_A et sort_B).

 

donc je copie recipe_A & recipe_B to sort_A & sort_B, et exécutez ce script (comme ci-dessous)

De cette façon, je peux recoder sort_A & sort_B.

Current Data Table() << Begin Data Update;
For Each Row( :sort_A = Match( :sort_A, "ZXC", "worse", "QWE", "better", "ASD", "good", :sort_A ) );
Current Data Table() << End Data Update;


Current Data Table() << Begin Data Update;
For Each Row( :sort_B = Match( :sort_B, "R123", "rrr", "H123", "hhh", "G123", "ggg", :sort_B ) );
Current Data Table() << End Data Update;

Ma question est :

Comment créer un script pour copier automatiquement recette_A & recipe_B dans sort_A & sort_B?

(copie automatique si les données sort_A et sort_B sont manquantes)?

 

 

Re: Comment copier automatiquement si les données de la colonne sont manquantes? (Script)

Vous trouverez ci-dessous une retouche de votre code pour vérifier si une colonne sort_A ou sort_B existe et, dans le cas contraire, créez-la et remplissez-la.  S'il existe, alors repeupler.  Les résultats de sort_A et sort_B étant basés sur les valeurs de recipe_A et recipe_B, il n'est pas nécessaire de copier les valeurs dans sort_A et sort_B, puis de modifier les valeurs correspondantes.  Il est beaucoup plus facile d'utiliser simplement les valeurs de recipe_A et recipe_B pour définir les valeurs dans sort_A et sort_B.

Names Default To Here( 1 );
dt = Current Data Table();

// Get a list of the current columns in the data table
ColList = dt << get column names( string );

// See if a column named "sort_A" does not exist
If( N Rows( Loc( ColList, "sort_A" ) ) == 0,
    // If it does not exist, create the new column and use a formula to populate the values based upon the recipe_A values
 dt << New Column( "sort_A", character, formula( Match( :recipe_A, "ZXC", "worse", "QWE", "better", "ASD", "good", :recipe_A ) ) );
 // Remove the formula which will leave the results
 dt:sort_A << delete formula;
,
 // If the column already exists, then loop through the data table creating new values for sort_A based upon the recipe_A values
 For Each Row( :sort_A = Match( :recipe_A, "ZXC", "worse", "QWE", "better", "ASD", "good", :recipe_A ) )
);

// See if a column named "sort_B" does not exist
If( N Rows( Loc( ColList, "sort_B" ) ) == 0,
 // If it does not exist, create the new column and use a formula to populate the values based upon the recipe_B values
 dt << New Column( "sort_B", character, formula( Match( :recipe_B, "R123", "rrr", "H123", "hhh", "G123", "ggg", :recipe_B ) ) );
 dt:sort_B << delete formula;
,
 // If the column already exists, then loop through the data table creating new values for sort_B based upon the recipe_B values
 For Each Row( :sort_B = Match( :recipe_B, "R123", "rrr", "H123", "hhh", "G123", "ggg", :recipe_B ) )
);