40245_de-DE

liliconcom

Prozess-Screening-Plattform

Wenn ich mehrere Spalten mit benutzerdefinierten Steuergrenzwerten (als Column-Eigenschaft) und RunProcess Screening habe, werden in der resultierenden Tabelle die Grenzwerte nicht angezeigt. Alle Tests und zugehörigen Alarme werden schön angezeigt, aber es wäre auch schön, die Grenzen zu sehen. Gibt es eine Möglichkeit, sie zu zeigen?

Re: Prozess-Screening-PlattformDanke Ian! Ich hatte gehofft, dass es eine Plattformnachricht gibt oder etwas, das ein- und ausgeschaltet werden kann. In jedem Fall wird das funktionieren!Re: Prozess-Screening-Plattform

Sie können immer so etwas tun:

NamesDefaultToHere(1);

// Make a table
dt = New Table( "Test",
   New Column( "Column 1",
    Numeric,
    "Continuous",
    Formula( Random Normal() ),
    Set Property(
     "Control Limits",
     {Individual Measurement( Avg( 1 ), LCL( 0 ), UCL( 2 ) )}
    )
   ),
   New Column( "Column 2",
    Numeric,
    "Continuous",
    Formula( Random Normal( 3 ) ),
    Set Property( "Control Limits", {XBar( Avg( 3 ), LCL( 0 ), UCL( 6 ) )} )
   )
  );
dt << addRows(1000);

// Do the Process Screening
ps = dt << Process Screening( Y( :Column 1, :Column 2 ), Control Chart Type( "Indiv and MR" ) );

// Add the limits
tb = Report(ps)[TableBox(1)];
cols = Report(ps)[StringColBox(1)] << get;
avg_ = J(NItems(cols), 1, .);
lcl_ = J(NItems(cols), 1, .);
ucl_ = J(NItems(cols), 1, .);
for (c=1, c<=NItems(cols), c++,
 clExpr = Column(dt, cols[c]) << getProperty("Control Limits");
 avg_[c] = Arg(Arg(Arg(clExpr,1), 1), 1);
 lcl_[c] = Arg(Arg(Arg(clExpr,1), 2), 1);
 ucl_[c] = Arg(Arg(Arg(clExpr,1), 3), 1);
);
tb << Append(
   ColSpanBox("Control Limits",
    NumberColBox("Average", avg_),
    NumberColBox("LCL", lcl_),
    NumberColBox("UCL", ucl_),
    )
   );

Aber ich vermute, das wussten Sie schon!