36331_es-ES

liliconcom

Error en JMP 13.1 para la función de cambio de fila de cuadro de tabla

Hola usuarios JMP,

 

He encontrado un error con la función de cambio de fila para un cuadro de tabla.  Estoy tratando de cambiar el enfoque a una pestaña diferente dentro de la función pero se ignora.  Me puse en contacto con el soporte técnico de JMP y dijo que se solucionaría en JMP 13.2 o 14.  Este es un tapón de show para mí.  Me preguntaba si alguien más notó este comportamiento y pudo encontrar una solución alternativa.

 

Gracias,

Peter

 

Aquí está el programa que demuestra el error:

nw = new window("test",
       tabx = tab box(
              "First Tab",
                     tb = table box(
                           scb1 = string col box("One", {"AAA", "BBB", "CCC"}),
                           scb2 = string col box("Two", {"XXX", "YYY", "ZZZ"}),
                           scb3 = string col box("Three", {"Giant", "Awesome", "Stupendous"}),
                           ncb  = number col box("Four", {44, 33, 22}),
                     ),
              "Second Tab",
                     txb = text box("Nothing selected"),
       ),
);

tb << Set Selectable Rows(1);

tb << set row change function(
       function({this},
              rlist = this << get selected rows;
              if (nrows(rlist) > 0,
                     print(rlist[1]);
                     txb << set text(char(rlist[1]));
                     tabx << set selected(2);
              );
       );
);

Re: Error en JMP 13.1 para la función de cambio de fila de cuadro de tabla

Gracias dan Es una solución de rube goldberg-ish pero funciona!

Re: Error en JMP 13.1 para la función de cambio de fila de cuadro de tabla

Hola Pedro,

 

Este problema se debió a la adición de enfoque para el cuadro de la pestaña en JMP 13.  Cuando haces clic en una página de pestañas, quiere enfocar si aún no tiene el foco.  La sincronización está rompiendo cosas en este caso, porque el cambio de fila en los conjuntos de devolución de llamada se enfoca en la segunda página de la pestaña, y luego la pestaña en la que hizo clic inmediatamente la recupera.

 

Para solucionar el problema, necesitamos una forma de configurar la pestaña después de que se haya completado el procesamiento del clic.  Aquí hay un ejemplo en el que configuro una variable para la página de la pestaña a la que quiero cambiar, y luego, en una secuencia de gráficos de Frame Box, la página de la pestaña se restablece.  Esto sucede en el próximo sorteo, lo que ocurrirá inmediatamente después de que se haya completado el clic.

 

¡Espero que eso ayude!

 

-Dan

 

tabOverride = 0;

nw = New Window( "test",
 V List Box(
  tabx = Tab Box(
   "First Tab",
   tb = Table Box(
    scb1 = String Col Box( "One", {"AAA", "BBB", "CCC"} ),
    scb2 = String Col Box( "Two", {"XXX", "YYY", "ZZZ"} ),
    scb3 = String Col Box( "Three", {"Giant", "Awesome", "Stupendous"} ),
    ncb = Number Col Box( "Four", {44, 33, 22} ),

   ),
   "Second Tab",
   txb = Text Box( "Nothing selected" ),

  ),
  gb = Graph Box( Frame Size( 1, 1 ), XName( "" ), YName( "" ) )
 )
);

Try(gb[AxisBox( 1 )] << Delete Box);
Try(gb[AxisBox( 1 )] << Delete Box);
Try(gb[Text Edit Box( 1 )] << Delete Box);
Try(gb[Border Box(1)] << Top(0) << Bottom(0) << Left(0) << Right(0));
gb[FrameBox( 1 )] << Add Graphics Script(
 If( tabOverride > 0,
  tabx << Set Selected( tabOverride );
  tabOverride = 0;
 )
);

tb << Set Selectable Rows( 1 );

tb << set row change function(
 Function( {this},
  rlist = this << get selected rows;
  If( N Rows( rlist ) > 0,
   Print( rlist[1] );
   txb << set text( Char( rlist[1] ) );
   tabOverride = 2;
   tabx << set selected( 2 );
  );
 )
);

Re: Error en JMP 13.1 para la función de cambio de fila de cuadro de tabla

Pete

Me he encontrado con problemas similares con las pestañas.  Varias veces resolví los problemas eliminando el inserto específico y luego reconstruyéndolo con la nueva información.  Visualmente, no tiene ningún efecto en lo que concierne al usuario, por lo que cuando funciona, es una buena solución.  Sin embargo, hice un intento de hacer lo mismo con su secuencia de comandos de muestra y no pude superar su problema de "selección".