62460_es-ES

liliconcom

Verifique los datos en filas de una tabla para ver si están en columnas de otra

Primera mesa:

 

Segunda mesa

 

Estoy tratando de verificar los valores máximos en la cuarta fila de la primera tabla contra sus columnas adyacentes de la segunda tabla. 

Hasta ahora, he extraído nombres de columna y valores de fila de la primera tabla:

dt1 = Open();
namesForCols = dt1 << get column names("String");
show(namesForCols);

row4 = dt1[4, 0];
show(row4);

close(dt1,nosave);

¿Cómo puedo verificar si los valores en la lista fila4 existen en las columnas de la segunda tabla? Gracias.

 

 

Re: verifique los datos en filas de una tabla para ver si están en columnas de otra

Aquí hay un simple script que responde a su pregunta.

Names Default To Here( 1 );
dt1 = Data Table( "Table 1" );
dt2 = Data Table( "Table 2" );

// Get the numeric columns
colNamesList = dt1 << get column names( numeric, string );

// Add a new row of data, that will tell how many rows in
// Table 2 have the maximumn values from row 4
dt1 << add rows( 1 );
dt1:Column 1[N Rows( dt1 )] = "Number of Rows Found";

// Loop across the numeric columns in table 1
For( i = 1, i <= N Items( colNamesList ), i++,
 // If the column in table 2 exists, process
 If( Try( Column( dt2, colNamesList[i] ) << get name, "" ) != "",
  // Get the value from table 1 to compare with in table 2
  compareValue = Column( dt1, colNamesList[i] )[4];
  
  // Find the number of rows in table 2 that match the 
  // value in row 4 of table 1 and save it into row 5
  // of table 1
  Column( dt1, ColNamesList[i] )[N Rows( dt1 )] =
  N Rows(
   dt2 << get rows where(
    As Column( dt2, colNamesList[i] ) == compareValue
   )
  );
 )
);