61101_es-ES

liliconcom

Para la funcion

Hola a todos,

 

Es probable que esto sea bastante básico, pero soy muy nuevo en JSL, ¡así que sé amable!

 

¿Cómo creo una columna que cumpla con los siguientes criterios?

 

Para cada Orden de Reabastecimiento hay un retraso en la columna de inventario hasta que el inventario sea positivo. En este ejemplo, tiraría 2/1/18 porque el retraso anterior a eso da como resultado un número positivo.

 

Tipo Semana Inventario Lag

Existencias 1/7/18 10

Pedido del cliente 2/1/18 -150

Pedido del cliente 3/1/18 -250

Orden de reposición 4/1/18 500 2/1/18

Re: Para Función

Este es un ejemplo del uso de una fórmula para su columna Lag que producirá los resultados que desea

names Default to Here( 1 );
New Table( "Example",
 Add Rows( 4 ),
 Set Header Height( 44 ),
 New Column( "Type",
  Character,
  "Nominal",
  Set Values(
   {"Stock", "Customer Order", "Customer Order", "Replenishment Order"}
  ),
  Set Display Width( 118 )
 ),
 New Column( "Week",
  Numeric,
  "Continuous",
  Format( "m/d/y", 12 ),
  Input Format( "m/d/y" ),
  Set Values( [3598128000, 3600288000, 3602707200, 3605385600] )
 ),
 New Column( "Inventory",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [10, -150, -250, 500] )
 ),
 New Column( "lag",
  Numeric,
  "Continuous",
  Format( "m/d/y", 12 ),
  Input Format( "m/d/y" ),
  Formula(
   If( Row() == 1, holdval = . );
   If( :Inventory < 0 & Is Missing( holdval ) == 1,
    holdval = :Week
   );
   finalval = .;
   If( :Inventory > 0,
    finalval = holdval;
    holdval = .;
   );
   finalval;
  )
 )
)