61101_it-IT

liliconcom

Per funzione

Ciao a tutti,

 

Questo è probabilmente piuttosto semplice, ma io sono molto nuovo a JSL quindi sii gentile!

 

Come posso creare una colonna che soddisfi i seguenti criteri.

 

Per ogni ordine di rifornimento c'è un ritardo nella colonna di inventario finché l'inventario non è positivo. In questo esempio tirerebbe 2/1/18 perché il ritardo prima che si traduce in un numero positivo.

 

Digitare Week Inventory Lag

Azione 1/7/18 10

Ordine cliente 2/1/18 -150

Ordine cliente 3/1/18 -250

Ordine di riacquisto 4/1/18 500 2/1/18

Re: per funzione

Ecco un esempio di utilizzo di una formula per la colonna Lag che produrrà i risultati desiderati

names Default to Here( 1 );
New Table( "Example",
 Add Rows( 4 ),
 Set Header Height( 44 ),
 New Column( "Type",
  Character,
  "Nominal",
  Set Values(
   {"Stock", "Customer Order", "Customer Order", "Replenishment Order"}
  ),
  Set Display Width( 118 )
 ),
 New Column( "Week",
  Numeric,
  "Continuous",
  Format( "m/d/y", 12 ),
  Input Format( "m/d/y" ),
  Set Values( [3598128000, 3600288000, 3602707200, 3605385600] )
 ),
 New Column( "Inventory",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [10, -150, -250, 500] )
 ),
 New Column( "lag",
  Numeric,
  "Continuous",
  Format( "m/d/y", 12 ),
  Input Format( "m/d/y" ),
  Formula(
   If( Row() == 1, holdval = . );
   If( :Inventory < 0 & Is Missing( holdval ) == 1,
    holdval = :Week
   );
   finalval = .;
   If( :Inventory > 0,
    finalval = holdval;
    holdval = .;
   );
   finalval;
  )
 )
)