61101_zh-TW

liliconcom

對於功能

大家好，

 

這可能是非常基本的，但我對JSL很新，所以要溫柔！

 

如何創建符合以下條件的列。

 

對於每個補貨訂單，庫存列都有滯後，直到庫存為正。在這個例子中它將拉2/1/18，因為之前的滯後導致正數。

 

鍵入周庫存滯後

股票1/7/18 10

客戶訂單2/1/18 -150

客戶訂單3/1/18 -250

補貨訂單4/1/18 500 2/1/18

回复：功能

以下是使用Lag列的公式生成所需結果的示例

names Default to Here( 1 );
New Table( "Example",
 Add Rows( 4 ),
 Set Header Height( 44 ),
 New Column( "Type",
  Character,
  "Nominal",
  Set Values(
   {"Stock", "Customer Order", "Customer Order", "Replenishment Order"}
  ),
  Set Display Width( 118 )
 ),
 New Column( "Week",
  Numeric,
  "Continuous",
  Format( "m/d/y", 12 ),
  Input Format( "m/d/y" ),
  Set Values( [3598128000, 3600288000, 3602707200, 3605385600] )
 ),
 New Column( "Inventory",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [10, -150, -250, 500] )
 ),
 New Column( "lag",
  Numeric,
  "Continuous",
  Format( "m/d/y", 12 ),
  Input Format( "m/d/y" ),
  Formula(
   If( Row() == 1, holdval = . );
   If( :Inventory < 0 & Is Missing( holdval ) == 1,
    holdval = :Week
   );
   finalval = .;
   If( :Inventory > 0,
    finalval = holdval;
    holdval = .;
   );
   finalval;
  )
 )
)