67534_es-ES

liliconcom

Combina tablas con filas faltantes y aplica la fórmula

Tengo dos conjuntos de datos. Uno es un promedio de recuentos de insectos que se realizaron en un lote semanal o quincenal. El otro es el rendimiento que se mide cada semana. Estoy tratando de combinar estas dos tablas de datos para poder analizar el impacto de los insectos en el rendimiento.

 

Tengo esto:

 

Y estoy tratando de producir esto en JMP.

  

 

Tenga en cuenta que para las semanas 44 y 45 simplemente muevo el valor de rendimiento, pero para la semana 47 necesito sumar el rendimiento de las semanas 46 y 47. Lo mismo para la semana 49. Para la semana 52 sumo el rendimiento de las semanas 50-52.

 

Tengo muchas parcelas y semanas desiguales de muestreo de insectos y rendimiento.

 

Gracias por cualquier ayuda.

Re: Combina tablas con filas faltantes y aplica la fórmula

Aquí hay un método para obtener lo que quieres

names default to here(1);
dtInsects = New Table( "Insects",
 Add Rows( 10 ),
 New Column( "Week",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [39, 40, 41, 42, 43, 44, 45, 47, 49, 52] )
 ),
 New Column( "Plot#",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [59.01, 59.01, 59.01, 59.01, 59.01, 59.01, 59.01, 59.01, 59.01, 59.01]
  )
 ),
 New Column( "Insects",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [0, 0.2, 0.2, 3.6, 15.4, 2.6, 0.3, 0.3, 0.3, 0.7] )
 )
);
dtYields = New Table( "Yields",
 Add Rows( 9 ),
 New Column( "Week",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values( [44, 45, 46, 47, 48, 49, 50, 51, 52] )
 ),
 New Column( "Plot#",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [59.01, 59.01, 59.01, 59.01, 59.01, 59.01, 59.01, 59.01, 59.01]
  )
 ),
 New Column( "Yield",
  Numeric,
  "Continuous",
  Format( "Best", 12 ),
  Set Values(
   [130.96, 343.1, 466.2, 903.59, 2611.25, 1052.88, 1335.74, 1414.32,
   500.25]
  )
 )
);

// Join the data
dtTogether = dtInsects << Join(
 With( dtYields ),
 Merge Same Name Columns,
 By Matching Columns( :Week = :Week, :Plot# = :Plot# ),
 Drop multiples( 0, 0 ),
 Include Nonmatches( 1, 1 ),
 Preserve main table order( 0 ),
 Output Table( "All Together" )
);

dtTogether << New Column( "Calculated Yield",
 formula(
  rowNum = Row() - 1;
  cumSum = :Yield;
  If( Is Missing( :Yield ) == 0,
   While( :Match Flag[rowNum] == 2,
    cumSum = cumSum + :Yield[rowNum];
    rowNum--;
   )
  );
  cumSum;
 )
);

// Make formula columns static values
dtTogether:Calculated Yield << delete formula;

// Delete rows that only came from the With Data Table
dtTogether << select where( :Match Flag == 2 ) << delete rows;

// Delete the Match Flag column
dtTogether << delete columns("Match Flag");