49574_es-ES

liliconcom

Modificación de las declaraciones de "Elementos" en la salida de Graph Builder mediante secuencias de comandos

Hola,

 

Adjunto un script que genera una pequeña tabla de datos con un script JSL adjunto llamado "Cuadrícula de diagramas de dispersión codificados por colores", que si lo ejecuta debería producir una salida de Graph Builder que muestre una cuadrícula (2x2) de diagramas de dispersión en cada uno de los cuales Todos los puntos reciben diferentes colores y/o símbolos.

 

El problema que tengo es que estoy intentando escribir un script que me permita intercambiar las variables en dicho gráfico por un conjunto diferente de columnas dentro del mismo conjunto de datos, y/o el número de variables que se grafican en uno o ambos ejes X e Y (por ejemplo, el ejemplo actualmente muestra una cuadrícula (2x2), pero es posible que desee cambiarla a una cuadrícula (3x2) agregando una tercera columna de datos X en el eje X).

 

Sé cómo aplicar las propiedades "<< Agregar variable" y "<< Eliminar variable" a gb[GraphBuilderBox(1)], donde gb es el objeto Graph Builder, para intercambiar un conjunto de variables en el gráfico por otro conjunto. Lo que yo no lo he hecho Lo que he podido resolver es cómo modificar las declaraciones de Elementos correspondientes. Hay un ejemplo en el índice de secuencias de comandos que se aplica al cuadro de visualización de GraphBuilderBox, pero el ejemplo "<< Agregar elemento" se relaciona con agregar una línea ajustada, y no veo cómo relacionar esto con mi problema, que implica agregar elementos. con los parámetros "Posición" y "Puntos".

 

¿Alguien puede indicarme algunos ejemplos de sintaxis que podría adaptar?

Muchas gracias.

 

New Table( "JMP Script Demo",
 Add Rows( 4 ),
 Compress File When Saved( 1 ),
 New Script("Grid of Color-Coded Scatter Plots",
  Graph Builder(
   Size( 713, 469 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Grid Color( "White" ),
   Graph Spacing( 10 ),
   Spacing Borders( 1 ),
   Variables(
    X( :X1 ),
    X( :X2 ),
    Y( :Y3A ),
    Y( :Y3B, Position( 1 ) ),
    Y( :Y3C, Position( 1 ) ),
    Y( :Y3D, Position( 1 ) ),
    Y( :Y2A ),
    Y( :Y2B, Position( 2 ) ),
    Y( :Y2C, Position( 2 ) ),
    Y( :Y2D, Position( 2 ) )
   ),
   Elements( Position( 1, 1 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 73 ) ) ),
   Elements( Position( 1, 2 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 78 ) ) ),
   Elements( Position( 2, 1 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 77 ) ) ),
   Elements( Position( 2, 2 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 79 ) ) ),
   SendToReport(
    Dispatch( {}, "X1", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch( {}, "X2", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch( {}, "Y3A", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch( {}, "Y2A", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch(
     {},
     "400",
     ScaleBox,
     {Legend Model(
      73,
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     ), Legend Model(
      78,
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     ), Legend Model(
      77,
      Base( 0, 0, 0 ),
      Base( 1, 0, 1 ),
      Base( 2, 0, 2 ),
      Base( 3, 0, 3 ),
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     ), Legend Model(
      79,
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     )}
    ),
    Dispatch( {}, "graph title", TextEditBox, {Set Text( "Grid of Color-Coded Scatter Plots" )} ),
    Dispatch( {}, "Y title", TextEditBox, {Set Text( "Y3A, Y3B, Y3C & Y3D" )} ),
    Dispatch( {}, "Y 1 title", TextEditBox, {Set Text( "Y2A, Y2B, Y2C & Y2D" )} )
   )
  )
 ),
 New Column( "Sample",
  Character( 24 ),
  "Nominal",
  Set Values( {"Sample A", "Sample B", "Sample C", "Sample D"} )
 ),
 New Column( "X1",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 10, 2 ),
  Set Values( [6.14, 5.14, 6.64, 6.72] )
 ),
 New Column( "X2",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 10, 2 ),
  Set Values( [4.62, 4.52, 4.66, 4.84] )
 ),
 New Column( "X3",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 10, 2 ),
  Set Values( [2.17, 2.52, 3.48, 2.25] )
 ),
 New Column( "Y1A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [6.14, ., ., .] ) ),
 New Column( "Y1B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., 5.14, ., .] ) ),
 New Column( "Y1C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., 6.64, .] ) ),
 New Column( "Y1D", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., 6.72] ) ),
 New Column( "Y2A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [4.62, ., ., .] ) ),
 New Column( "Y2B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., 4.52, ., .] ) ),
 New Column( "Y2C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., 4.66, .] ) ),
 New Column( "Y2D", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., 4.84] ) ),
 New Column( "Y3A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2.17, ., ., .] ) ),
 New Column( "Y3B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., 2.52, ., .] ) ),
 New Column( "Y3C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., 3.48, .] ) ),
 New Column( "Y3D", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., 2.25] ) ),
 Set Row States( [8, 8, 8, 8] ),
 Set Label Columns( :Sample )
)

 

Re: Modificar las declaraciones de "Elementos" en la salida del Generador de gráficos mediante secuencias de comandos

Utilizo la opción "reemplazar" con frecuencia.Así es como normalmente lo implemento, observe cómo el script para crear el gráfico solo aparece una vez:

Names default to here( 1 );

dt = Open( "$SAMPLE_DATA/iris.jmp" );

UpdateGraph = Function( { x_low },
 Try( gb << Delete );
 
 lb << Append(
  gb = Graph Builder(
   Size( 500, 500 ),
   Show Control Panel( 0 ),
   Variables( X( :Sepal length ), Y( :Petal length ) ),
   Elements( Points( X, Y, Legend( 3 ) ) ),
   SendToReport(
    Dispatch(
     {},
     "Sepal length",
     ScaleBox,
     {Min( x_low ), Max( x_low + 4 ), Inc( 0.5 ),
     Minor Ticks( 0 )}
    )
   )
  )
 )
);

win = New Window( "Swapping Graphs",
 V List Box(
  Button Box("Swap Graph", UpdateGraph( random uniform( 2, 6 ) ), << Padding( 10 ) ),
  lb = H List Box()
 );
);

UpdateGraph( 4 );

Re: Modificar las declaraciones de "Elementos" en la salida del Generador de gráficos mediante secuencias de comandos

Hola,

Sí, mientras experimentaba, descubrí que agregar y/o eliminar columnas parece tener un impacto indirecto en la declaración "Elementos", en el sentido de que cuando inspecciono el script Graph Builder después de haber realizado algunos de esos cambios, la declaración "Elementos" parece se han actualizado automáticamente (y aparentemente correctamente).

Sin embargo , descubrí que posteriormente no podía aplicar los comandos necesarios "<< Enviar a informe (Dispatch(...))" al Generador de gráficos que cambiarían los colores y símbolos a los que realmente quería. Simplemente no funcionaron: no sé por qué no (y de hecho, todavía no estoy 100% seguro de no haber cometido ningún error cuando intentaba hacerlo), y esto fue en parte lo que me impulsó. Primero intente encontrar algunos ejemplos de cómo se deben especificar los elementos.

En cuanto a su segundo punto, consideré simplemente eliminar el gráfico y reemplazarlo, y todavía puedo recurrir a esa opción si no puedo resolverlo de otra manera. La razón principal por la que no quería seguir ese camino fue que la salida de Graph Builder está incorporada en mi propio panel personalizado, y si luego empiezo a eliminar y reemplazar componentes de ese panel, las secuencias de comandos podrían volverse un poco complicadas. .Dicho esto, su ejemplo sugiere que podría ser menos complicado de lo que pensaba anteriormente.

Muchas gracias por su ayuda y sugerencias; Si logro ordenar las declaraciones del "Elemento", publicaré una actualización de mi ejemplo para mostrar cómo se hizo.

Re: Modificar las declaraciones de "Elementos" en la salida del Generador de gráficos mediante secuencias de comandos

No estoy seguro de qué otras implicaciones tiene esto, pero puedes agregar y eliminar columnas y filas sin modificar los Elementos directamente, simplemente agrega variables a las nuevas posiciones:

gb = Graph Builder(
 Size( 713, 469 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Grid Color( "White" ),
 Graph Spacing( 10 ),
 Spacing Borders( 1 ),
 Variables(
  X( :X1 ),
  X( :X2 ),
  Y( :Y3A, Position( 1 ) ),
  Y( :Y3B, Position( 2 ) ),
 )
);

gbb = Report( gb )[Graph Builder Box( 1 )];
gbb << Add Variable( { :Y3C, Role( "Y" ), Position( 3 ) } );
gbb << Remove Variable( {:Y3A, Role( "Y" ), Position( 1 ) } )

 

Como alternativa, puedes simplemente reemplazar el gráfico por uno nuevo que tenga la cantidad correcta de elementos:

New Window( "Graph",
 lb = H list box( 
  gb = Graph Builder(
   Size( 713, 469 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Grid Color( "White" ),
   Graph Spacing( 10 ),
   Spacing Borders( 1 ),
   Variables(
    X( :X1 ),
    X( :X2 ),
    Y( :Y3A, Position( 1 ) ),
    Y( :Y3B, Position( 2 ) ),
   )
  )
 );
);

Try( gb << Delete );
lb << Append(
 gb = Graph Builder(
  Size( 713, 469 ),
  Show Control Panel( 0 ),
  Show Legend( 0 ),
  Grid Color( "White" ),
  Graph Spacing( 10 ),
  Spacing Borders( 1 ),
  Variables(
   X( :X1 ),
   X( :X2 ),
   Y( :Y3A, Position( 1 ) ),
   Y( :Y3C, Position( 2 ) ),
  )
 )
);