49574_de-DE

liliconcom

Ändern der „Elements“-Anweisungen in der Graph Builder-Ausgabe durch Skripterstellung

Hallo,

 

Ich hänge ein Skript an, das eine kleine Datentabelle mit einem angehängten JSL-Skript namens „Grid of Color-Coded Scatter Plots“ generiert. Wenn Sie es ausführen, sollte es eine Graph Builder-Ausgabe erzeugen, die jeweils ein (2x2) Raster von Streudiagrammen zeigt Alle Punkte erhalten unterschiedliche Farben und/oder Symbole.

 

Das Problem, das ich habe, besteht darin, dass ich versuche, ein Skript zu schreiben, das es mir ermöglicht, die Variablen in einem solchen Diagramm gegen einen anderen Satz von Spalten innerhalb desselben Datensatzes und/oder die Anzahl der Variablen, die in einem Diagramm dargestellt werden, auszutauschen Sowohl die

 

Ich weiß, wie man die Eigenschaften „<< Variable hinzufügen“ und „<< Variable entfernen“ auf gb[GraphBuilderBox(1)] anwendet, wobei gb das Graph Builder-Objekt ist, um einen Satz Variablen im Diagramm gegen einen anderen Satz auszutauschen. Was ich nicht Ich konnte herausfinden, wie die entsprechenden Elements-Anweisungen geändert werden können. Es gibt ein Beispiel im Scripting Index, das sich auf das Anzeigefeld GraphBuilderBox bezieht, aber das Beispiel „<< Element hinzufügen“ bezieht sich dort auf das Hinzufügen einer angepassten Linie – und ich kann dies nicht mit meinem Problem in Verbindung bringen, bei dem es um das Hinzufügen von Elementen geht mit den Parametern „Position“ und „Punkte“.

 

Kann mir jemand einige Beispiele für die Syntax nennen, die ich möglicherweise anpassen kann?

Vielen Dank.

 

New Table( "JMP Script Demo",
 Add Rows( 4 ),
 Compress File When Saved( 1 ),
 New Script("Grid of Color-Coded Scatter Plots",
  Graph Builder(
   Size( 713, 469 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Grid Color( "White" ),
   Graph Spacing( 10 ),
   Spacing Borders( 1 ),
   Variables(
    X( :X1 ),
    X( :X2 ),
    Y( :Y3A ),
    Y( :Y3B, Position( 1 ) ),
    Y( :Y3C, Position( 1 ) ),
    Y( :Y3D, Position( 1 ) ),
    Y( :Y2A ),
    Y( :Y2B, Position( 2 ) ),
    Y( :Y2C, Position( 2 ) ),
    Y( :Y2D, Position( 2 ) )
   ),
   Elements( Position( 1, 1 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 73 ) ) ),
   Elements( Position( 1, 2 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 78 ) ) ),
   Elements( Position( 2, 1 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 77 ) ) ),
   Elements( Position( 2, 2 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 79 ) ) ),
   SendToReport(
    Dispatch( {}, "X1", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch( {}, "X2", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch( {}, "Y3A", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch( {}, "Y2A", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch(
     {},
     "400",
     ScaleBox,
     {Legend Model(
      73,
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     ), Legend Model(
      78,
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     ), Legend Model(
      77,
      Base( 0, 0, 0 ),
      Base( 1, 0, 1 ),
      Base( 2, 0, 2 ),
      Base( 3, 0, 3 ),
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     ), Legend Model(
      79,
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     )}
    ),
    Dispatch( {}, "graph title", TextEditBox, {Set Text( "Grid of Color-Coded Scatter Plots" )} ),
    Dispatch( {}, "Y title", TextEditBox, {Set Text( "Y3A, Y3B, Y3C & Y3D" )} ),
    Dispatch( {}, "Y 1 title", TextEditBox, {Set Text( "Y2A, Y2B, Y2C & Y2D" )} )
   )
  )
 ),
 New Column( "Sample",
  Character( 24 ),
  "Nominal",
  Set Values( {"Sample A", "Sample B", "Sample C", "Sample D"} )
 ),
 New Column( "X1",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 10, 2 ),
  Set Values( [6.14, 5.14, 6.64, 6.72] )
 ),
 New Column( "X2",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 10, 2 ),
  Set Values( [4.62, 4.52, 4.66, 4.84] )
 ),
 New Column( "X3",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 10, 2 ),
  Set Values( [2.17, 2.52, 3.48, 2.25] )
 ),
 New Column( "Y1A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [6.14, ., ., .] ) ),
 New Column( "Y1B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., 5.14, ., .] ) ),
 New Column( "Y1C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., 6.64, .] ) ),
 New Column( "Y1D", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., 6.72] ) ),
 New Column( "Y2A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [4.62, ., ., .] ) ),
 New Column( "Y2B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., 4.52, ., .] ) ),
 New Column( "Y2C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., 4.66, .] ) ),
 New Column( "Y2D", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., 4.84] ) ),
 New Column( "Y3A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2.17, ., ., .] ) ),
 New Column( "Y3B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., 2.52, ., .] ) ),
 New Column( "Y3C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., 3.48, .] ) ),
 New Column( "Y3D", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., 2.25] ) ),
 Set Row States( [8, 8, 8, 8] ),
 Set Label Columns( :Sample )
)

 

Betreff: Ändern der „Elements“-Anweisungen in der Graph Builder-Ausgabe durch Skripterstellung

Ich verwende die Option „Ersetzen“ häufig.So stelle ich es normalerweise bereit. Beachten Sie, dass das Skript zum Erstellen des Diagramms nur einmal erscheint:

Names default to here( 1 );

dt = Open( "$SAMPLE_DATA/iris.jmp" );

UpdateGraph = Function( { x_low },
 Try( gb << Delete );
 
 lb << Append(
  gb = Graph Builder(
   Size( 500, 500 ),
   Show Control Panel( 0 ),
   Variables( X( :Sepal length ), Y( :Petal length ) ),
   Elements( Points( X, Y, Legend( 3 ) ) ),
   SendToReport(
    Dispatch(
     {},
     "Sepal length",
     ScaleBox,
     {Min( x_low ), Max( x_low + 4 ), Inc( 0.5 ),
     Minor Ticks( 0 )}
    )
   )
  )
 )
);

win = New Window( "Swapping Graphs",
 V List Box(
  Button Box("Swap Graph", UpdateGraph( random uniform( 2, 6 ) ), << Padding( 10 ) ),
  lb = H List Box()
 );
);

UpdateGraph( 4 );

Betreff: Ändern der „Elements“-Anweisungen in der Graph Builder-Ausgabe durch Skripterstellung

Hallo,

Ja – ich habe beim Experimentieren selbst herausgefunden, dass das Hinzufügen und/oder Entfernen von Spalten scheinbar indirekte Auswirkungen auf die „Elements“-Anweisung hat. Wenn ich mir das Graph Builder-Skript ansehe, nachdem ich einige solcher Änderungen vorgenommen habe, scheint die „Elements“-Anweisung dies zu tun wurden automatisch (und anscheinend korrekt) aktualisiert.

Jedoch , stellte ich fest, dass ich anschließend nicht in der Lage war, die erforderlichen „<< Send to Report( Dispatch( ... ) )“-Befehle auf den Graph Builder anzuwenden, die die Farben und Symbole auf die tatsächlich gewünschten Werte ändern würden. Sie haben einfach nicht funktioniert: Ich weiß nicht, warum nicht (und tatsächlich bin ich noch nicht hundertprozentig sicher, dass ich bei dem Versuch, das zu tun, keine Fehler gemacht habe), und das war zum Teil der Auslöser für mich Versuchen Sie zunächst, einige Beispiele dafür zu finden, wie die Elemente spezifiziert werden sollten.

Zu Ihrem zweiten Punkt: Ich habe darüber nachgedacht, das Diagramm einfach zu löschen und zu ersetzen – und ich werde möglicherweise noch auf diese Option zurückgreifen, wenn ich das Problem nicht anders lösen kann. Der Hauptgrund, warum ich diesen Weg nicht unbedingt einschlagen wollte, war, dass die Graph Builder-Ausgabe in ein eigenes benutzerdefiniertes Dashboard integriert ist und wenn ich dann anfange, Komponenten dieses Dashboards zu löschen und zu ersetzen, könnte die Skripterstellung möglicherweise etwas chaotisch werden .Allerdings deutet Ihr Beispiel darauf hin, dass es weniger chaotisch sein könnte, als ich bisher gedacht hatte.

Vielen Dank für Ihre Hilfe und Vorschläge; Wenn es mir gelingt, die „Element“-Anweisungen zu sortieren, werde ich ein Update meines Beispiels veröffentlichen, um zu zeigen, wie es gemacht wurde.

Betreff: Ändern der „Elements“-Anweisungen in der Graph Builder-Ausgabe durch Skripterstellung

Ich bin nicht sicher, welche weiteren Auswirkungen dies hat, aber Sie können Spalten und Zeilen hinzufügen und entfernen, ohne die Elemente direkt zu ändern. Fügen Sie einfach Variablen an neuen Positionen hinzu:

gb = Graph Builder(
 Size( 713, 469 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Grid Color( "White" ),
 Graph Spacing( 10 ),
 Spacing Borders( 1 ),
 Variables(
  X( :X1 ),
  X( :X2 ),
  Y( :Y3A, Position( 1 ) ),
  Y( :Y3B, Position( 2 ) ),
 )
);

gbb = Report( gb )[Graph Builder Box( 1 )];
gbb << Add Variable( { :Y3C, Role( "Y" ), Position( 3 ) } );
gbb << Remove Variable( {:Y3A, Role( "Y" ), Position( 1 ) } )

 

Alternativ können Sie das Diagramm einfach durch ein neues mit der richtigen Anzahl von Elementen ersetzen:

New Window( "Graph",
 lb = H list box( 
  gb = Graph Builder(
   Size( 713, 469 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Grid Color( "White" ),
   Graph Spacing( 10 ),
   Spacing Borders( 1 ),
   Variables(
    X( :X1 ),
    X( :X2 ),
    Y( :Y3A, Position( 1 ) ),
    Y( :Y3B, Position( 2 ) ),
   )
  )
 );
);

Try( gb << Delete );
lb << Append(
 gb = Graph Builder(
  Size( 713, 469 ),
  Show Control Panel( 0 ),
  Show Legend( 0 ),
  Grid Color( "White" ),
  Graph Spacing( 10 ),
  Spacing Borders( 1 ),
  Variables(
   X( :X1 ),
   X( :X2 ),
   Y( :Y3A, Position( 1 ) ),
   Y( :Y3C, Position( 2 ) ),
  )
 )
);