49574_fr-FR

liliconcom

Modification des instructions "Elements" dans la sortie de Graph Builder par script

Salut,

 

Je joins un script qui génère une petite table de données avec un script JSL joint appelé "Grille de nuages de points codés par couleur", qui, si vous l'exécutez, devrait produire une sortie Graph Builder montrant une grille (2x2) de nuages de points dans chacun desquels tous les points reçoivent des couleurs et/ou des symboles différents.

 

Le problème que j'ai est que j'essaie d'écrire un script qui me permettra d'échanger les variables d'un tel graphique contre un ensemble différent de colonnes dans le même ensemble de données, et/ou le nombre de variables représentées sur ou les axes X et Y (par exemple, l'exemple montre actuellement une grille (2x2), mais je souhaiterais peut-être la changer en une grille (3x2) en ajoutant une troisième colonne de données X sur l'axe X).

 

Je sais comment appliquer les propriétés "<< Add Variable" et "<< Remove Variable" à gb[GraphBuilderBox(1)], où gb est l'objet Graph Builder, pour échanger un ensemble de variables dans le graphique contre un autre ensemble. Ce que je n'ai pas J'ai pu comprendre comment modifier les instructions Elements correspondantes. Il y a un exemple dans l'index de script qui s'applique à la zone d'affichage GraphBuilderBox, mais l'exemple "<< Ajouter un élément" concerne l'ajout d'une ligne ajustée - et je ne vois pas comment relier cela à mon problème, qui implique l'ajout d'éléments avec les paramètres "Position" et "Points".

 

Quelqu'un peut-il me donner quelques exemples de syntaxe que je pourrais adapter ?

Merci beaucoup.

 

New Table( "JMP Script Demo",
 Add Rows( 4 ),
 Compress File When Saved( 1 ),
 New Script("Grid of Color-Coded Scatter Plots",
  Graph Builder(
   Size( 713, 469 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Grid Color( "White" ),
   Graph Spacing( 10 ),
   Spacing Borders( 1 ),
   Variables(
    X( :X1 ),
    X( :X2 ),
    Y( :Y3A ),
    Y( :Y3B, Position( 1 ) ),
    Y( :Y3C, Position( 1 ) ),
    Y( :Y3D, Position( 1 ) ),
    Y( :Y2A ),
    Y( :Y2B, Position( 2 ) ),
    Y( :Y2C, Position( 2 ) ),
    Y( :Y2D, Position( 2 ) )
   ),
   Elements( Position( 1, 1 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 73 ) ) ),
   Elements( Position( 1, 2 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 78 ) ) ),
   Elements( Position( 2, 1 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 77 ) ) ),
   Elements( Position( 2, 2 ), Points( X, Y( 1 ), Y( 2 ), Y( 3 ), Y( 4 ), Legend( 79 ) ) ),
   SendToReport(
    Dispatch( {}, "X1", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch( {}, "X2", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch( {}, "Y3A", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch( {}, "Y2A", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
    Dispatch(
     {},
     "400",
     ScaleBox,
     {Legend Model(
      73,
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     ), Legend Model(
      78,
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     ), Legend Model(
      77,
      Base( 0, 0, 0 ),
      Base( 1, 0, 1 ),
      Base( 2, 0, 2 ),
      Base( 3, 0, 3 ),
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     ), Legend Model(
      79,
      Properties( 0, {Line Color( 3 ), Marker( "Filled Diamond" )} ),
      Properties( 1, {Line Color( 36 ), Marker( "FilledCircle" )} ),
      Properties( 2, {Line Color( 5 ), Marker( "Square" )} ),
      Properties( 3, {Line Color( 8 ), Marker( "FilledCircle" )} )
     )}
    ),
    Dispatch( {}, "graph title", TextEditBox, {Set Text( "Grid of Color-Coded Scatter Plots" )} ),
    Dispatch( {}, "Y title", TextEditBox, {Set Text( "Y3A, Y3B, Y3C & Y3D" )} ),
    Dispatch( {}, "Y 1 title", TextEditBox, {Set Text( "Y2A, Y2B, Y2C & Y2D" )} )
   )
  )
 ),
 New Column( "Sample",
  Character( 24 ),
  "Nominal",
  Set Values( {"Sample A", "Sample B", "Sample C", "Sample D"} )
 ),
 New Column( "X1",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 10, 2 ),
  Set Values( [6.14, 5.14, 6.64, 6.72] )
 ),
 New Column( "X2",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 10, 2 ),
  Set Values( [4.62, 4.52, 4.66, 4.84] )
 ),
 New Column( "X3",
  Numeric,
  "Continuous",
  Format( "Fixed Dec", 10, 2 ),
  Set Values( [2.17, 2.52, 3.48, 2.25] )
 ),
 New Column( "Y1A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [6.14, ., ., .] ) ),
 New Column( "Y1B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., 5.14, ., .] ) ),
 New Column( "Y1C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., 6.64, .] ) ),
 New Column( "Y1D", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., 6.72] ) ),
 New Column( "Y2A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [4.62, ., ., .] ) ),
 New Column( "Y2B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., 4.52, ., .] ) ),
 New Column( "Y2C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., 4.66, .] ) ),
 New Column( "Y2D", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., 4.84] ) ),
 New Column( "Y3A", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [2.17, ., ., .] ) ),
 New Column( "Y3B", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., 2.52, ., .] ) ),
 New Column( "Y3C", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., 3.48, .] ) ),
 New Column( "Y3D", Numeric, "Continuous", Format( "Best", 12 ), Set Values( [., ., ., 2.25] ) ),
 Set Row States( [8, 8, 8, 8] ),
 Set Label Columns( :Sample )
)

 

Re : Modification des instructions "Elements" dans la sortie de Graph Builder par script

J'utilise fréquemment l'option « remplacer ».Voici comment je le déploie normalement, remarquez comment le script pour créer le graphique n'apparaît qu'une seule fois :

Names default to here( 1 );

dt = Open( "$SAMPLE_DATA/iris.jmp" );

UpdateGraph = Function( { x_low },
 Try( gb << Delete );
 
 lb << Append(
  gb = Graph Builder(
   Size( 500, 500 ),
   Show Control Panel( 0 ),
   Variables( X( :Sepal length ), Y( :Petal length ) ),
   Elements( Points( X, Y, Legend( 3 ) ) ),
   SendToReport(
    Dispatch(
     {},
     "Sepal length",
     ScaleBox,
     {Min( x_low ), Max( x_low + 4 ), Inc( 0.5 ),
     Minor Ticks( 0 )}
    )
   )
  )
 )
);

win = New Window( "Swapping Graphs",
 V List Box(
  Button Box("Swap Graph", UpdateGraph( random uniform( 2, 6 ) ), << Padding( 10 ) ),
  lb = H List Box()
 );
);

UpdateGraph( 4 );

Re : Modification des instructions "Elements" dans la sortie de Graph Builder par script

Salut,

Oui - j'ai découvert en expérimentant que l'ajout et/ou la suppression de colonnes semblent avoir un impact indirect sur l'instruction "Elements", dans la mesure où lorsque j'inspecte le script Graph Builder après avoir apporté de telles modifications, l'instruction "Elements" semble ont été automatiquement (et apparemment correctement) mis à jour.

Cependant , j'ai constaté que je n'étais par la suite pas en mesure d'appliquer les commandes nécessaires "<< Send to Report( Dispatch( ... ) )" au Graph Builder qui changeraient les couleurs et les symboles pour ceux que je souhaitais réellement. Ils n'ont tout simplement pas fonctionné : je ne sais pas pourquoi (et en effet, je ne suis pas encore sûr à 100% de n'avoir commis aucune erreur en essayant de faire ça), et c'est en partie ce qui m'a poussé d'abord pour essayer de trouver quelques exemples de la façon dont les éléments doivent être spécifiés.

Concernant votre deuxième point, j'ai envisagé simplement de supprimer le graphique et de le remplacer - et je pourrai encore recourir à cette option si je ne parviens pas à le résoudre autrement. La principale raison pour laquelle je ne voulais pas particulièrement emprunter cette voie était que la sortie de Graph Builder est incorporée dans mon propre tableau de bord personnalisé, et si je commence ensuite à supprimer et à remplacer des composants de ce tableau de bord, le script pourrait potentiellement devenir un peu compliqué. .Cela dit, votre exemple suggère que cela pourrait être moins compliqué que je ne le pensais auparavant.

Merci beaucoup pour votre aide et vos suggestions ; si je parviens à trier les instructions "Element", je publierai une mise à jour de mon exemple pour montrer comment cela a été fait.

Re : Modification des instructions "Elements" dans la sortie de Graph Builder par script

Je ne suis pas sûr des autres implications que cela a, mais vous pouvez ajouter et supprimer des colonnes et des lignes sans modifier directement les éléments, ajoutez simplement des variables à de nouvelles positions :

gb = Graph Builder(
 Size( 713, 469 ),
 Show Control Panel( 0 ),
 Show Legend( 0 ),
 Grid Color( "White" ),
 Graph Spacing( 10 ),
 Spacing Borders( 1 ),
 Variables(
  X( :X1 ),
  X( :X2 ),
  Y( :Y3A, Position( 1 ) ),
  Y( :Y3B, Position( 2 ) ),
 )
);

gbb = Report( gb )[Graph Builder Box( 1 )];
gbb << Add Variable( { :Y3C, Role( "Y" ), Position( 3 ) } );
gbb << Remove Variable( {:Y3A, Role( "Y" ), Position( 1 ) } )

 

Alternativement, vous pouvez simplement remplacer le graphique par un nouveau comportant le nombre correct d'éléments :

New Window( "Graph",
 lb = H list box( 
  gb = Graph Builder(
   Size( 713, 469 ),
   Show Control Panel( 0 ),
   Show Legend( 0 ),
   Grid Color( "White" ),
   Graph Spacing( 10 ),
   Spacing Borders( 1 ),
   Variables(
    X( :X1 ),
    X( :X2 ),
    Y( :Y3A, Position( 1 ) ),
    Y( :Y3B, Position( 2 ) ),
   )
  )
 );
);

Try( gb << Delete );
lb << Append(
 gb = Graph Builder(
  Size( 713, 469 ),
  Show Control Panel( 0 ),
  Show Legend( 0 ),
  Grid Color( "White" ),
  Graph Spacing( 10 ),
  Spacing Borders( 1 ),
  Variables(
   X( :X1 ),
   X( :X2 ),
   Y( :Y3A, Position( 1 ) ),
   Y( :Y3C, Position( 2 ) ),
  )
 )
);