105042_it-IT

liliconcom

come ottenere valori da datatable e utilizzare per tracciare grafici variabili utilizzando for loop

Salve, sono nuovo nello scripting JMP. Ho una tabella di dati (test data.jmp) con poche colonne come esempio, manualmente ho tracciato il grafico delle variabili e manualmente ho aggiunto le linee di riferimento e poi ho ottenuto lo script dal menu di salvataggio dello script. Qui ho tracciato 3 colonne. Ho quasi 50 colonne da tracciare. L'unica differenza in ogni grafico è l'asse Y e la posizione delle linee di riferimento. Sto cercando di capire come estrarre questi dati da un altro datatable (spec limits.jmp) e quindi incorporarli con un ciclo For e tracciare il grafico delle variabili.Ho allegato i dati del test, i dati sui limiti delle specifiche e lo script che sto utilizzando.Posso avere un aiuto per favore.

Ri: come ottenere valori da datatable e usarli per tracciare grafici variabili usando il ciclo for

main = open( ); //Open test data
//open();
//main = current data table();

parameter_dt = Open( );
dt = Current Data Table();

Param_List = Column( parameter_dt, "Process") << Get Values;
LSL_spec = Column( parameter_dt, "LSL") << Get Values; 
USL_spec = Column( parameter_dt, "USL") << Get Values; 
LCL_spec = Column( parameter_dt, "LCL") << Get Values; 
UCL_spec = Column( parameter_dt, "UCL") << Get Values; 
Median_spec = Column( parameter_dt, "Median") << Get Values; 
Yinc_spec = Column( parameter_dt, "Yinc") << Get Values; 
Ymax_spec = Column( parameter_dt, "Ymax") << Get Values;
Ymin_spec = Column( parameter_dt, "Ymin") << Get Values; 

nw = New Window( "test data", container = V List Box() );

For ( i=1, i<=N items(Param_List), i++,
 content = V List Box(
  Eval(
   Substitute(
    Expr(
     main << Variability Chart(
     Y( __ParamList__ ),
     X( :Test date ),
     Show Range Bars( 0 ),
     Show Cell Means( 0 ),
     Std Dev Chart( 0 ),
     SendToReport(
      Dispatch(
       {__VarChart__},
       "2",
       ScaleBox,
       {Min( Ymin_spec[i] ), Max( Ymax_spec[i] ), Inc( Yinc_spec[i] ), Minor Ticks( 1 ),
       Add Ref Line( 0, "Dotted", "Medium Light Gray", "", 1 ),
       Add Ref Line( LSL_spec[i], "Solid", "Black", "LSL", 1 ),
       Add Ref Line( USL_spec[i], "Solid", "Black", "USL", 1 ),
       Add Ref Line( LCL_spec[i], "Solid", "Magenta", "LCL", 1 ),
       Add Ref Line( UCL_spec[i], "Solid", "Magenta", "UCL", 1 ),
       Add Ref Line( Median_spec[i], "Solid", "Magenta", "Median", 1 )}
       )
      )
     )
    ),
    Expr(__ParamList__), Parse( ":" || Char(Param_List[i])),
    Expr(__VarChart__), "Variability Chart for " || Char( Param_List[i])
   )
  );
 );
 container << Append(content)
);

Ciao Jim,

 

Ho seguito il tuo copione e ho trovato pochi altri post e ho risolto la mia domanda. Ecco la sceneggiatura che ho finalmente.

Grazie per l'aiuto

Ri: come ottenere valori da datatable e usarli per tracciare grafici variabili usando il ciclo for

Grazie per la tua risposta. Quello che hai dato (aiutato) è tracciare un grafico. Ho un datatable con più di 50 colonne, se traccio un grafico variabile e aggiungo manualmente le linee di riferimento, regolo Y min e Y max e poi converto in script, va bene. Stavo pensando se avessi un altro datatable con tutte le specifiche come UCL, LCL, mediana, Ymax, ecc. Come ottenere i dati da quella specifica datatable e aggiungere ogni valore come array e quindi incorporare quei valori nella trama.

Ri: come ottenere valori da datatable e usarli per tracciare grafici variabili usando il ciclo for

Una ricerca nelle discussioni della comunità trova diverse voci che coprono le domande che stai ponendo.Tuttavia, comprendendo che sei nuovo in JMP, di seguito è riportato uno script completo che dovrebbe fornirti ciò che desideri

main << Variability Chart(
 Y( :C ),
 X( :Test date ),
 Show Range Bars( 0 ),
 Show Cell Means( 0 ),
 Std Dev Chart( 0 ),
 SendToReport(
  Dispatch(
   {"Variability Chart for C"},
   "2",
   ScaleBox,
   {Min( 0.1 ), Max( 0.106 ), Inc( 0.001 ), Minor Ticks( 1 ),
   Add Ref Line( 0, "Dotted", "Medium Light Gray", "", 1 ),
   Add Ref Line( 665, "Solid", "Black", "LSL", 1 ),
   Add Ref Line( 685, "Solid", "Black", "USL", 1 ),
   Add Ref Line( 670, "Solid", "Magenta", "LCL", 1 ),
   Add Ref Line( 680, "Solid", "Magenta", "UCL", 1 ),
   Add Ref Line( 675, "Solid", "Magenta", "Median", 1 )}
  )
 )
)