79498_es-ES

liliconcom

Plot Legend se elimina cuando está dentro de un cuadro de lista

Hola a todos,

 

Así que tengo un problema con una trama que estoy creando a través de una función. La función es la siguiente:

 

 

 

 

myRunChart = Function( {dt, y1, y2, y3, x, colour_col},
{Default Local}, 

dt << Control Chart(
Sample Label( Eval( x ) ),
KSigma( 3 ),
Chart Col( Eval( y1 ), Run Chart( Show Center Line( 0 ) ) ),
Chart Col( Eval( y2 ), Run Chart( Show Center Line( 0 ) ) ),
Chart Col( Eval( y3 ), Run Chart( Show Center Line( 0 ) ) ),
SendToReport(
Dispatch(
{Eval( "Run Chart of "|| y1 )},
"Run Chart",
FrameBox,
{Frame Size( 436, 114 ), Row Legend(
Eval( colour_col ),
Color( 1 ),
Color Theme( "JMP Default" ),
Marker( 0 ),
Marker Theme( "" ),
Continuous Scale( 0 ),
Reverse Scale( 0 ),
Excluded Rows( 0 )
)}
),
Dispatch( {Eval( "Run Chart of "|| y1 )}, "Control Chart Limits frame", FrameBox, {Frame Size( 69, 114 )} ),
Dispatch(
{Eval( "Run Chart of "|| y2 )},
"Run Chart",
FrameBox,
{Frame Size( 436, 114 ), Row Legend(
Eval( colour_col ),
Color( 1 ),
Color Theme( "JMP Default" ),
Marker( 0 ),
Marker Theme( "" ),
Continuous Scale( 0 ),
Reverse Scale( 0 ),
Excluded Rows( 0 )
)}
),
Dispatch( {Eval( "Run Chart of "|| y2 )}, "Control Chart Limits frame", FrameBox, {Frame Size( 69, 114 )} ),
Dispatch(
{Eval( "Run Chart of "|| y3 )},
"Run Chart",
FrameBox,
{Frame Size( 436, 114 ), Row Legend(
Eval( colour_col ),
Color( 1 ),
Color Theme( "JMP Default" ),
Marker( 0 ),
Marker Theme( "" ),
Continuous Scale( 0 ),
Reverse Scale( 0 ),
Excluded Rows( 0 )
)}
),
Dispatch( {Eval( "Run Chart of "|| y3 )}, "Control Chart Limits frame", FrameBox, {Frame Size( 69, 114 )} )
)
);

);

 

 

 

Cuando llamo a esta función por sí misma, todo está bien. La trama y la leyenda trazan como normal. Sin embargo, cuando llamo a la función dentro de un cuadro de lista, la leyenda se elimina y el tamaño de los gráficos cambia.

 

En el siguiente código, llamo a la función dos veces en una ventana. La primera vez está dentro de un cuadro de lista H y se elimina la leyenda. Pero la segunda llamada de la función funciona como normal.

 

nw2 = New Window("temp",

H list box(
rc2 = myRunChart(
dt_temp,
"column1",
"column2",
"column3",
time_col,
colour_col
)),
rc3 = myRunChart(
dt_temp,
"column4",
"column5",
"column6",
time_col,
colour_col
)

);

 

 

 

¿Alguien tiene una idea de lo que podría ser el problema?

 

 

Re: Plot Legend se elimina cuando está dentro de un cuadro de lista

Funciona un encanto. Gracias por tu ayuda. Estoy seguro de que esto tomó un poco de su tiempo.

 

Es muy apreciado,

David

Re: Plot Legend se elimina cuando está dentro de un cuadro de lista

Aparentemente, desde el cuadro de lista H (), o incluso cuando usé un cuadro de esquema (), no se está realizando la concatenación de "Ejecutar gráfico de" y las variables y1, y2 o y3.  He modificado el script, forzando que la cadena se calcule correctamente, y luego el script se completa correctamente

myRunChart = Function( {dt, y1, y2, y3, x, colour_col},
 {Default Local},
 Eval(
  Substitute(
    Expr(
     dt << Control Chart(
      Sample Label( Eval( x ) ),
      KSigma( 3 ),
      Chart Col( Eval( y1 ), Run Chart( Show Center Line( 0 ) ) ),
      Chart Col( Eval( y2 ), Run Chart( Show Center Line( 0 ) ) ),
      Chart Col( Eval( y3 ), Run Chart( Show Center Line( 0 ) ) ),
      SendToReport(
       Dispatch(
        { __y1__ },
        "Run Chart",
        FrameBox,
        {Frame Size( 436, 114 ),
        Row Legend(
         Eval( colour_col ),
         Color( 1 ),
         Color Theme( "JMP Default" ),
         Marker( 0 ),
         Marker Theme( "" ),
         Continuous Scale( 0 ),
         Reverse Scale( 0 ),
         Excluded Rows( 0 )
        )}
       ),
       Dispatch(
        { __y2__ },
        "Run Chart",
        FrameBox,
        {Frame Size( 436, 114 ),
        Row Legend(
         Eval( colour_col ),
         Color( 1 ),
         Color Theme( "JMP Default" ),
         Marker( 0 ),
         Marker Theme( "" ),
         Continuous Scale( 0 ),
         Reverse Scale( 0 ),
         Excluded Rows( 0 )
        )}
       ),
       Dispatch(
        { __y3__ },
        "Run Chart",
        FrameBox,
        {Frame Size( 436, 114 ),
        Row Legend(
         Eval( colour_col ),
         Color( 1 ),
         Color Theme( "JMP Default" ),
         Marker( 0 ),
         Marker Theme( "" ),
         Continuous Scale( 0 ),
         Reverse Scale( 0 ),
         Excluded Rows( 0 )
        )}
       )
      )
     )
    ),
   Expr( __y1__ ), "Run Chart of " || y1,
   Expr( __y2__ ), "Run Chart of " || y2,
   Expr( __y3__ ), "Run Chart of " || y3
  )
 );
 
 Wait( 0 );
);

dt_temp = Open( "$SAMPLE_DATA\Solubility.jmp" );

Wait( 0 );

dt_temp << New Column( "Colour example" );
dt_temp:Colour Example << set formula( Modulo( Row(), 2 ) + 1 );

dt_temp << New Column( "Row Numbers" );
dt_temp:Row Numbers << set formula( Row() );

time_col = "Row Numbers";
colour_col = "Colour Example";

Wait( 0 );

nw2 = New Window( "temp", 

 H List Box(
  "charts",
  rc2 = myRunChart(
   dt_temp,
   "Chloroform",
   "Benzene",
   "Hexane",
   time_col,
   colour_col
  )
 ),
 rc3 = myRunChart(
  dt_temp,
  "Chloroform",
  "Benzene",
  "Hexane",
  time_col,
  colour_col
 )

);

Re: Plot Legend se elimina cuando está dentro de un cuadro de lista

Entonces cuando ejecuto este script:

 

myRunChart = Function( {dt, y1, y2, y3, x, colour_col},
 {Default Local}, 

 dt << Control Chart(
  Sample Label( Eval( x ) ),
  KSigma( 3 ),
  Chart Col( Eval( y1 ), Run Chart( Show Center Line( 0 ) ) ),
  Chart Col( Eval( y2 ), Run Chart( Show Center Line( 0 ) ) ),
  Chart Col( Eval( y3 ), Run Chart( Show Center Line( 0 ) ) ),
  SendToReport(
   Dispatch(
    {Eval( "Run Chart of " || y1 )},
    "Run Chart",
    FrameBox,
    {Frame Size( 436, 114 ), Row Legend(
     Eval( colour_col ),
     Color( 1 ),
     Color Theme( "JMP Default" ),
     Marker( 0 ),
     Marker Theme( "" ),
     Continuous Scale( 0 ),
     Reverse Scale( 0 ),
     Excluded Rows( 0 )
    )}
   ),
   Dispatch(
    {Eval( "Run Chart of " || y2 )},
    "Run Chart",
    FrameBox,
    {Frame Size( 436, 114 ), Row Legend(
     Eval( colour_col ),
     Color( 1 ),
     Color Theme( "JMP Default" ),
     Marker( 0 ),
     Marker Theme( "" ),
     Continuous Scale( 0 ),
     Reverse Scale( 0 ),
     Excluded Rows( 0 )
    )}
   ),
   Dispatch(
    {Eval( "Run Chart of " || y3 )},
    "Run Chart",
    FrameBox,
    {Frame Size( 436, 114 ), Row Legend(
     Eval( colour_col ),
     Color( 1 ),
     Color Theme( "JMP Default" ),
     Marker( 0 ),
     Marker Theme( "" ),
     Continuous Scale( 0 ),
     Reverse Scale( 0 ),
     Excluded Rows( 0 )
    )}
   )
  )
 );
 
 wait(0);
);

dt_temp = Open("C:\Program Files\SAS\JMP\14\Samples\Data\Solubility.jmp");

wait(0);

dt_temp << new Column ("Colour example");
dt_temp:Colour Example << set formula(modulo(row(),2) + 1);

dt_temp << new column ("Row Numbers");
dt_temp:Row Numbers << set formula(row());

time_col = "Row Numbers";
colour_col = "Colour Example";

wait(0);

nw2 = New Window( "temp", 

 H List Box( rc2 = myRunChart( dt_temp, "Chloroform", "Benzene", "Hexane", time_col, colour_col ) ),
 rc3 =  myRunChart( dt_temp, "Chloroform", "Benzene", "Hexane", time_col, colour_col )

);

Obtengo esta salida:

 

Como puede ver, la leyenda solo aparece para la llamada de función fuera del cuadro de lista H.

 

 

 

 

Ver el registro:

 

 

 

¿Puedes confirmar si ves este problema? ¿Alguna idea sobre que podría ir mal?

Re: Plot Legend se elimina cuando está dentro de un cuadro de listaGracias por su respuesta.

De Verdad? Ambas llamadas de la función produjeron una trama con una leyenda?

Eso es interesante. Tendré que mirar más de cerca. Tal vez sea algo que ver con los datos. También estoy ejecutando JMP 14Re: Plot Legend se elimina cuando está dentro de un cuadro de lista

Ejecuté su script en JMP 14 y no vi ningún problema.