79498_fr-FR

liliconcom

La légende de tracé est supprimée à l'intérieur d'une zone de liste

Salut à tous,

 

J'ai donc un problème avec un complot que je crée à travers une fonction. La fonction est la suivante:

 

 

 

 

myRunChart = Function( {dt, y1, y2, y3, x, colour_col},
{Default Local}, 

dt << Control Chart(
Sample Label( Eval( x ) ),
KSigma( 3 ),
Chart Col( Eval( y1 ), Run Chart( Show Center Line( 0 ) ) ),
Chart Col( Eval( y2 ), Run Chart( Show Center Line( 0 ) ) ),
Chart Col( Eval( y3 ), Run Chart( Show Center Line( 0 ) ) ),
SendToReport(
Dispatch(
{Eval( "Run Chart of "|| y1 )},
"Run Chart",
FrameBox,
{Frame Size( 436, 114 ), Row Legend(
Eval( colour_col ),
Color( 1 ),
Color Theme( "JMP Default" ),
Marker( 0 ),
Marker Theme( "" ),
Continuous Scale( 0 ),
Reverse Scale( 0 ),
Excluded Rows( 0 )
)}
),
Dispatch( {Eval( "Run Chart of "|| y1 )}, "Control Chart Limits frame", FrameBox, {Frame Size( 69, 114 )} ),
Dispatch(
{Eval( "Run Chart of "|| y2 )},
"Run Chart",
FrameBox,
{Frame Size( 436, 114 ), Row Legend(
Eval( colour_col ),
Color( 1 ),
Color Theme( "JMP Default" ),
Marker( 0 ),
Marker Theme( "" ),
Continuous Scale( 0 ),
Reverse Scale( 0 ),
Excluded Rows( 0 )
)}
),
Dispatch( {Eval( "Run Chart of "|| y2 )}, "Control Chart Limits frame", FrameBox, {Frame Size( 69, 114 )} ),
Dispatch(
{Eval( "Run Chart of "|| y3 )},
"Run Chart",
FrameBox,
{Frame Size( 436, 114 ), Row Legend(
Eval( colour_col ),
Color( 1 ),
Color Theme( "JMP Default" ),
Marker( 0 ),
Marker Theme( "" ),
Continuous Scale( 0 ),
Reverse Scale( 0 ),
Excluded Rows( 0 )
)}
),
Dispatch( {Eval( "Run Chart of "|| y3 )}, "Control Chart Limits frame", FrameBox, {Frame Size( 69, 114 )} )
)
);

);

 

 

 

Lorsque j'appelle cette fonction seule, tout va bien. Le complot et la légende complètent normalement. Toutefois, lorsque j'appelle la fonction dans une zone de liste, la légende est supprimée et la taille des graphiques est modifiée.

 

Dans le code suivant, j'appelle la fonction deux fois dans une fenêtre. La première fois que vous vous trouvez dans une liste déroulante H, la légende est supprimée. Mais le second appel de la fonction fonctionne normalement.

 

nw2 = New Window("temp",

H list box(
rc2 = myRunChart(
dt_temp,
"column1",
"column2",
"column3",
time_col,
colour_col
)),
rc3 = myRunChart(
dt_temp,
"column4",
"column5",
"column6",
time_col,
colour_col
)

);

 

 

 

Quelqu'un at-il une idée de ce que pourrait être le problème?

 

 

Re: La légende du tracé est supprimée à l'intérieur d'une zone de liste

Fonctionne un charme. Merci de votre aide. Je suis sûr que cela vous a pris pas mal de temps.

 

C'est grandement apprécié

David

Re: La légende du tracé est supprimée à l'intérieur d'une zone de liste

Apparemment, à partir de la zone de liste H (), ou même lorsque j'ai utilisé une zone de contour (), la concaténation du "Tableau d'analyse de" et des variables y1, y2 ou y3 n'est pas effectuée.  J'ai retravaillé le script, forçant la chaîne à être calculée correctement, et le script se termine ensuite correctement

myRunChart = Function( {dt, y1, y2, y3, x, colour_col},
 {Default Local},
 Eval(
  Substitute(
    Expr(
     dt << Control Chart(
      Sample Label( Eval( x ) ),
      KSigma( 3 ),
      Chart Col( Eval( y1 ), Run Chart( Show Center Line( 0 ) ) ),
      Chart Col( Eval( y2 ), Run Chart( Show Center Line( 0 ) ) ),
      Chart Col( Eval( y3 ), Run Chart( Show Center Line( 0 ) ) ),
      SendToReport(
       Dispatch(
        { __y1__ },
        "Run Chart",
        FrameBox,
        {Frame Size( 436, 114 ),
        Row Legend(
         Eval( colour_col ),
         Color( 1 ),
         Color Theme( "JMP Default" ),
         Marker( 0 ),
         Marker Theme( "" ),
         Continuous Scale( 0 ),
         Reverse Scale( 0 ),
         Excluded Rows( 0 )
        )}
       ),
       Dispatch(
        { __y2__ },
        "Run Chart",
        FrameBox,
        {Frame Size( 436, 114 ),
        Row Legend(
         Eval( colour_col ),
         Color( 1 ),
         Color Theme( "JMP Default" ),
         Marker( 0 ),
         Marker Theme( "" ),
         Continuous Scale( 0 ),
         Reverse Scale( 0 ),
         Excluded Rows( 0 )
        )}
       ),
       Dispatch(
        { __y3__ },
        "Run Chart",
        FrameBox,
        {Frame Size( 436, 114 ),
        Row Legend(
         Eval( colour_col ),
         Color( 1 ),
         Color Theme( "JMP Default" ),
         Marker( 0 ),
         Marker Theme( "" ),
         Continuous Scale( 0 ),
         Reverse Scale( 0 ),
         Excluded Rows( 0 )
        )}
       )
      )
     )
    ),
   Expr( __y1__ ), "Run Chart of " || y1,
   Expr( __y2__ ), "Run Chart of " || y2,
   Expr( __y3__ ), "Run Chart of " || y3
  )
 );
 
 Wait( 0 );
);

dt_temp = Open( "$SAMPLE_DATA\Solubility.jmp" );

Wait( 0 );

dt_temp << New Column( "Colour example" );
dt_temp:Colour Example << set formula( Modulo( Row(), 2 ) + 1 );

dt_temp << New Column( "Row Numbers" );
dt_temp:Row Numbers << set formula( Row() );

time_col = "Row Numbers";
colour_col = "Colour Example";

Wait( 0 );

nw2 = New Window( "temp", 

 H List Box(
  "charts",
  rc2 = myRunChart(
   dt_temp,
   "Chloroform",
   "Benzene",
   "Hexane",
   time_col,
   colour_col
  )
 ),
 rc3 = myRunChart(
  dt_temp,
  "Chloroform",
  "Benzene",
  "Hexane",
  time_col,
  colour_col
 )

);

Re: La légende du tracé est supprimée à l'intérieur d'une zone de liste

Alors quand je lance ce script:

 

myRunChart = Function( {dt, y1, y2, y3, x, colour_col},
 {Default Local}, 

 dt << Control Chart(
  Sample Label( Eval( x ) ),
  KSigma( 3 ),
  Chart Col( Eval( y1 ), Run Chart( Show Center Line( 0 ) ) ),
  Chart Col( Eval( y2 ), Run Chart( Show Center Line( 0 ) ) ),
  Chart Col( Eval( y3 ), Run Chart( Show Center Line( 0 ) ) ),
  SendToReport(
   Dispatch(
    {Eval( "Run Chart of " || y1 )},
    "Run Chart",
    FrameBox,
    {Frame Size( 436, 114 ), Row Legend(
     Eval( colour_col ),
     Color( 1 ),
     Color Theme( "JMP Default" ),
     Marker( 0 ),
     Marker Theme( "" ),
     Continuous Scale( 0 ),
     Reverse Scale( 0 ),
     Excluded Rows( 0 )
    )}
   ),
   Dispatch(
    {Eval( "Run Chart of " || y2 )},
    "Run Chart",
    FrameBox,
    {Frame Size( 436, 114 ), Row Legend(
     Eval( colour_col ),
     Color( 1 ),
     Color Theme( "JMP Default" ),
     Marker( 0 ),
     Marker Theme( "" ),
     Continuous Scale( 0 ),
     Reverse Scale( 0 ),
     Excluded Rows( 0 )
    )}
   ),
   Dispatch(
    {Eval( "Run Chart of " || y3 )},
    "Run Chart",
    FrameBox,
    {Frame Size( 436, 114 ), Row Legend(
     Eval( colour_col ),
     Color( 1 ),
     Color Theme( "JMP Default" ),
     Marker( 0 ),
     Marker Theme( "" ),
     Continuous Scale( 0 ),
     Reverse Scale( 0 ),
     Excluded Rows( 0 )
    )}
   )
  )
 );
 
 wait(0);
);

dt_temp = Open("C:\Program Files\SAS\JMP\14\Samples\Data\Solubility.jmp");

wait(0);

dt_temp << new Column ("Colour example");
dt_temp:Colour Example << set formula(modulo(row(),2) + 1);

dt_temp << new column ("Row Numbers");
dt_temp:Row Numbers << set formula(row());

time_col = "Row Numbers";
colour_col = "Colour Example";

wait(0);

nw2 = New Window( "temp", 

 H List Box( rc2 = myRunChart( dt_temp, "Chloroform", "Benzene", "Hexane", time_col, colour_col ) ),
 rc3 =  myRunChart( dt_temp, "Chloroform", "Benzene", "Hexane", time_col, colour_col )

);

Je reçois cette sortie:

 

Comme vous pouvez le constater, la légende n'apparaît que pour l'appel de fonction en dehors de la liste déroulante H.

 

 

 

 

Voir le journal:

 

 

 

Pouvez-vous confirmer si vous voyez ce problème? Des idées ce qui pourrait être le problème?

Re: La légende du tracé est supprimée à l'intérieur d'une zone de listeMerci pour votre réponse.

Vraiment? Les deux appels de la fonction ont produit un complot avec une légende?

C'est intéressant. Je vais devoir regarder de plus près. C'est peut-être quelque chose à voir avec les données. Je cours aussi JMP 14Re: La légende du tracé est supprimée à l'intérieur d'une zone de liste

J'ai exécuté votre script dans JMP 14 et je ne voyais aucun problème.