85320_it-IT

liliconcom

Come impostare la posizione di legendbox passando la variabile?

Ciao,

Voglio impostare la posizione di LegendBox da una lista come segue jsl, ma non è lavoro. come faccio a passare la "mia lista" in posizione?

l'elenco "mylist" sarà un risultato dinamico di altre funzioni, quindi ho bisogno di passare la variabile mentre installo il programma di creazione di grafici o aggiornare il generatore di grafici dopo l'annuncio.

Ho bisogno del legendbox del grafico come l'immagine.  

 

 

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = Graph Builder(
 Show Control Panel( 0 ),
 Variables(
  X( :height ),
  Y( :weight ),
  Overlay( :sex )
 ),
 Elements(
  Points( X, Y, Legend( 0 ) ),
  Smoother( X, Y, Legend( 1 ) )
 )
);

mylist={-1, -1, 1, 0};

Report( gb )[LegendBox( 1 )] << Position(mylist );

 

 

Ri: Come impostare la posizione di legendbox passando la variabile?

Il messaggio di posizione apparentemente non supporta la valutazione prima della sua esecuzione, quindi utilizzando la funzione Sostituto () è possibile forzare la valutazione.

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
 Elements(
  Points( X, Y, Legend( 0 ) ),
  Smoother( X, Y, Legend( 1 ) )
 )
);

mylist = {-1, -1, 1, 0};
Eval(
 Substitute(
   Expr(
    Report( gb )[LegendBox( 1 )] << Position( __myList__ )
   ),
  Expr( __myList__ ), myList
 )
);