85320_fr-FR

liliconcom

Comment définir la position de la légende en passant variable?

Salut,

Je veux définir la position LegendBox par une liste comme suit jsl, mais ce n'est pas le travail. Comment puis-je passer le "mylist" en position?

la liste "mylist" sera un résultat dynamique provenant d'une autre fonction. Je dois donc transmettre la variable lors de la configuration du générateur de graphique ou la mise à jour du générateur de graphique après l'annonce.

J'ai besoin de la légende des graphes, comme dans l'image.  

 

 

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = Graph Builder(
 Show Control Panel( 0 ),
 Variables(
  X( :height ),
  Y( :weight ),
  Overlay( :sex )
 ),
 Elements(
  Points( X, Y, Legend( 0 ) ),
  Smoother( X, Y, Legend( 1 ) )
 )
);

mylist={-1, -1, 1, 0};

Report( gb )[LegendBox( 1 )] << Position(mylist );

 

 

Re: Comment définir la position de la légende en passant variable?

Le message de position ne prend apparemment pas en charge l'évaluation avant son exécution. Par conséquent, en utilisant la fonction Substitute (), vous pouvez forcer l'évaluation.

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = Graph Builder(
 Show Control Panel( 0 ),
 Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
 Elements(
  Points( X, Y, Legend( 0 ) ),
  Smoother( X, Y, Legend( 1 ) )
 )
);

mylist = {-1, -1, 1, 0};
Eval(
 Substitute(
   Expr(
    Report( gb )[LegendBox( 1 )] << Position( __myList__ )
   ),
  Expr( __myList__ ), myList
 )
);