108141_fr-FR

liliconcom

Enregistrement de plusieurs graphiques en JSL

Bonjour, j'exécute ce script où les dataCols sont des colonnes numériques.

OWA = Data Table ("Filtered_raw") << Oneway( 
  Y(eval( dataCols)), 
  X( " WhichTest"),
  Each Pair( 0 ),
  Means( 0 ),
  Plot Actual by Quantile( 0 ),
  Plot Quantile by Actual( 1 ),
  Mean Diamonds( 1 )
);

Cela crée des tracés d'analyse unidirectionnelle et de quantile normal de mes colonnes numériques. Maintenant, j'essaie de sauvegarder ces tracés avec ce script :

OWA << report;
OWA << Save MSWord( "\\snl\home\malepp\Software\JMP\JMP_Report\Oneway_normalQ.doc");

Le problème est qu'il enregistre uniquement le tracé Oneway/Quantile de la dernière colonne. Comment puis-je tous les enregistrer dans le document ?

 

Merci!

Re : Enregistrer plusieurs graphiques en JSL

Un code bien meilleur ......... merci Wendy

Re : Enregistrer plusieurs graphiques en JSL

Pour ajouter à @txnelson Dans la réponse de, vous pouvez éliminer la boucle For() en envoyant le message Journal à la liste des objets Oneway.OWA représentant une liste, le message Journal est envoyé à chaque élément de la liste.Ensuite, tout ce que vous avez à faire est d'obtenir une référence au journal à l'aide de la fonction Current Journal().Vous trouverez ci-dessous une version modifiée de l'exemple de script ci-dessus.

 

Names Default To Here( 1 );

// Setup an Example Data table
dt = Open( "$SAMPLE_DATA/blood pressure.jmp" );
dataCols = dt << get column names( continuous );
dt:Dose << set name( "WhichTest" );
dt << set name( "Filtered_raw" );

// Run the charts
OWA = Data Table( "Filtered_raw" ) << Oneway(
 Y( Eval( dataCols ) ),
 X( "WhichTest" ),
 Each Pair( 0 ),
 Means( 0 ),
 Plot Actual by Quantile( 0 ),
 Plot Quantile by Actual( 1 ),
 Mean Diamonds( 1 )
);

// Create a journal containing each Oneway
OWA << Journal;
// Obtain a reference to the journal
jj = Current Journal();

// Save the journal to disk
jj << Save MSWord( "$DOCUMENTS\Oneway_normalQ.doc" );

jj << Close Window;

 

Re : Enregistrer plusieurs graphiques en JSL

Beau! J'avais essayé une approche similaire en parcourant les N éléments et en essayant d'ajouter dans chaque boucle, mais je n'arrivais toujours pas à la faire fonctionner. Mais je n'utilisais pas de Jounal.

 

Des conseils pour faire la même chose mais en enregistrant sur un PowerPoint ? En particulier, formater le ppt ? J'ai opté pour Word car il donne une analyse par page (un Oneway et un Normal Quantile Plot, et les titres semblaient normaux). Alors qu'avec ppt, il faut 3 pages pour une analyse et le formatage est foiré.

 

Merci!!!!

 

 

Re : Enregistrer plusieurs graphiques en JSL

Le problème que vous rencontrez est qu'il n'y a pas une seule sortie de rapport mais plutôt un nombre n de sorties basées sur le nombre réel d'analyses OneWay effectuées.Ainsi, lorsque vous effectuez votre sauvegarde MSWord, chaque sortie est enregistrée une par une.Cependant, il n'ajoute pas la sortie au fichier .doc, mais la remplace.Il faut donc placer chacune des sorties dans un journal JMP, puis enregistrer le journal.C'est ce qui se fait dans le script ci-dessous

Names Default To Here( 1 );

// Setup an Example Data table
dt = Open( "$SAMPLE_DATA/blood pressure.jmp" );
dataCols = dt << get column names( continuous );
dt:Dose << set name( "WhichTest" );
dt << set name( "Filtered_raw" );

// Run the charts
OWA = Data Table( "Filtered_raw" ) << Oneway(
 Y( Eval( dataCols ) ),
 X( " WhichTest" ),
 Each Pair( 0 ),
 Means( 0 ),
 Plot Actual by Quantile( 0 ),
 Plot Quantile by Actual( 1 ),
 Mean Diamonds( 1 )
);

// Create a Journal to store the output in
jj = New Window( "The Output", <<JOURNAL></JOURNAL>