44624_es-ES

liliconcom

Probabilidad de tasa de rechazo

Hola a todos

Tengo lo que considero una pregunta un tanto complicada, al menos para mí, me parece que es así. Quiero saber si es posible usar la desviación estándar de la población y la media de Xi para predecir la tasa de rechazo de un grupo empaquetado de Xi. 

 

Así que para el contexto, trabajo para un fabricante de alimentos que hace barras de caramelo. Tengo acceso a los datos de población de cualquier ciclo de producción, que durará entre 1 y 6 días o aproximadamente 4.8 millones de barras. Hay dos grupos de Xi empaquetados, un conteo de 4 y un conteo de 72.

 

Aquí están las unidades objetivo de conversión y los límites de especificaciones más bajos.

1 barra = 40 gramos (LSL = 36.4)

1 4 cajas de cartón = 160 gramos (LSL = 149.2)

1 caja de 12 conteos = 480 gramos (LSL = 460)

 

Un ejemplo de media observada de la población y desviación estándar son 40.5 y 1.96 respectivamente.

 

La razón por la que quiero determinar esta información es que usamos la tecnología de rayos X para eliminar las Xi ligeras antes de que entren en una caja de cartón. Sin embargo, recientemente he visto una tendencia en la que la radiografía se sale de la calibración y agrega 3.5 gramos adicionales de peso a la lectura. Esto, a su vez, toma barras que de otro modo serían consideradas ligeras y les permite pasar y abrirse camino en una caja de cartón. A partir de ahí, si demasiadas barras de luz se convierten en una caja de cartón, el peso medio descenderá por debajo de la LSL y se eliminará causando el desperdicio de la caja. Esto es importante porque 1 caja es más cara que incluso 2 o 3 envoltorios.

 

¿Tengo todos los datos adecuados para alcanzar mi objetivo o me estoy perdiendo algo? Si no, ¿podría alguien ayudarme a resolver esto? ¡Gracias!

 

Re: Probabilidad de tasa de rechazo

Las fórmulas para las columnas '4 Pack' y '12 Pack 'no dependen del resto de la tabla, entradas aleatorias o de otro tipo. Pero también eran una forma "rápida y sucia" de obtener lo que quería, y ciertamente existen formas más sólidas de definir tales "columnas de agrupación".

Esto parece un poco tangencial a la pregunta original, pero si puede dar más detalles sobre el código que está utilizando y el error que ve, estoy seguro de que alguien puede ayudarlo.

Re: Probabilidad de tasa de rechazo

¿Su fórmula para crear los subgrupos de columnas solo funciona para datos aleatorios? Cada vez que trato de hacer una columna de tal manera que pueda resumirla usando esa columna, recibo mensajes de error.

Re: Probabilidad de tasa de rechazo

Tomando sus cifras a su valor nominal (y asumiendo que no cometí un error) hice algunos datos aleatorios que creo que podrían ayudarlo. En general, tales simulaciones pueden ser una buena manera de eludir alguna teoría. Para ver el resultado, haga 'Archivo> Nuevo> Nuevo script' y copie y pegue el siguiente código en la ventana resultante. Luego haga 'Editar> Ejecutar secuencia de comandos' (puede demorar un segundo) e inspeccione los resultados.

NamesDefaultToHere(1);

n12 = 10000; // Number of boxes of 12 bars made
n = 12*n12;  // Number of bars made

// Generate data assuming an in-control process
dt = New Table( "Candy Bar Production",
    Add Rows( n ),
    New Column( "Weight",
     Numeric,
     "Continuous",
     Format( "Best", 12 ),
     Formula( Random Normal( 40.5, 1.96 ) ),
     Set Property( "Spec Limits", {LSL( 36.4 ), Target( 40 ), Show Limits( 0 )} )
    ),
    New Column( "4 Pack",
     Numeric,
     "Nominal",
     Format( "Best", 12 ),
     Formula( Modulo( Row(), Floor(n/4) ) )
    ),
    New Column( "12 Pack",
     Numeric,
     "Nominal",
     Format( "Best", 12 ),
     Formula( Modulo( Row(), Floor(n/12) ) )
    )
   );

// Make data for the 4 pack weights
dt4 = dt << Summary(
   Group( :Name( "4 Pack" ) ),
   Sum( :Weight ),
   statistics column name format( "column" )
  );
Column(dt4, "Weight") << Set Property( "Spec Limits", {LSL( 149.2 ), Target( 160 ), Show Limits( 0 )} );

// Make data for the 12 pack weights
dt12 = dt << Summary(
   Group( :Name( "12 Pack" ) ),
   Sum( :Weight ),
   statistics column name format( "column" )
  );
Column(dt12, "Weight") << Set Property( "Spec Limits", {LSL( 460 ), Target( 480 ), Show Limits( 0 )} );

// Use Control Chart Builder
dt << Control Chart Builder(Variables( Y( :Weight ) ));
dt4 << Control Chart Builder(Variables( Y( :Weight ) ));
dt12 << Control Chart Builder(Variables( Y( :Weight ) ));

La utilidad de esto dependerá de los detalles de su situación. Soy muy cauteloso cuando veo la palabra "distribución" en el contexto de Control Estadístico de Procesos: como se indica en el código, estos datos se generaron asumiendo un proceso perfectamente "en control" (muestras aleatorias independientes de una distribución Gaussiana fija) , y si eso fuera realmente cierto no necesitarías SPC.