44624_de-DE

liliconcom

Wahrscheinlichkeit der Ablehnungsrate

Hallo zusammen

Ich habe eine meiner Meinung nach etwas komplizierte Frage, zumindest scheint es mir so. Ich möchte wissen, ob es möglich ist, die Populationsstandardabweichung und den Mittelwert von Xi zu verwenden, um die Ausschussrate einer verpackten Gruppe von Xi vorherzusagen. 

 

Im Kontext arbeite ich für einen Lebensmittelhersteller, der Schokoriegel herstellt. Ich habe Zugriff auf die Bevölkerungsdaten jedes Produktionslaufs, der zwischen 1 - 6 Tagen oder etwa 4,8 Millionen Barren dauern kann. Es gibt zwei Gruppen von verpackten Xis, eine 4 und eine 72.

 

Hier sind die Zieleinheiten für die Umwandlung und die unteren Grenzwerte.

1 Bar = 40 Gramm (LSL = 36,4)

1 4 Zählkarton = 160 Gramm (LSL = 149,2)

1 12 Zählkarton = 480 Gramm (LSL = 460)

 

Ein Beispiel für die gemittelte mittlere und Standardabweichung der Bevölkerung ist 40,5 bzw. 1,96.

 

Der Grund, warum ich diese Informationen ermitteln möchte, besteht darin, dass wir die X-Ray-Technologie verwenden, um die leichten Xi abzublasen, bevor sie in einen Karton gelangen. Ich habe jedoch kürzlich einen Trend gesehen, bei dem der Röntgenstrahl aus der Kalibrierung ausfällt und dem Messwert weitere 3,5 Gramm hinzufügen. Dies wiederum erfordert Barren, die ansonsten als leichtgewichtig betrachtet würden, und sie können passieren und in einen Karton gelangen. Wenn zu viele Lichtstäbe in einen Karton gelangen, sinkt das mittlere Gewicht unter die LSL und bläst ab, was zu Kartonabfällen führt. Dies ist von Bedeutung, da 1 Karton teurer ist als 2 oder 3 Verpackungen.

 

Verfüge ich über die richtigen Daten, um mein Ziel zu erreichen, oder fehlt mir etwas? Wenn nicht, könnte mir jemand helfen, das herauszufinden? Vielen Dank!

 

Re: Wahrscheinlichkeit der Ablehnungsrate

Die Formeln für die Spalten '4 Pack' und '12 Pack' hängen nicht vom Rest der Tabelle ab, von zufälligen Einträgen oder anderen. Sie waren aber auch eine "schnelle und schmutzige" Methode, um das zu bekommen, was ich wollte, und es gibt sicherlich robustere Möglichkeiten, solche "Gruppierungsspalten" zu definieren.

Dies scheint ein wenig tangential zu der ursprünglichen Frage zu sein, aber wenn Sie weitere Details zu dem von Ihnen verwendeten Code und dem Fehler, den Sie sehen, angeben können, bin ich sicher, dass jemand helfen kann.

Re: Wahrscheinlichkeit der Ablehnungsrate

Funktioniert Ihre Formel zum Erstellen der Spaltenuntergruppen nur für Zufallsdaten? Jedes Mal, wenn ich versuche, eine Kolumne so zu erstellen, dass ich sie anhand dieser Spalte zusammenfassen kann, erhalte ich Fehlermeldungen.

Re: Wahrscheinlichkeit der Ablehnungsrate

Wenn ich Ihre Zahlen für bare Münze nehme (und vorausgesetzt, ich habe keinen Fehler gemacht), habe ich einige zufällige Daten gemacht, von denen ich denke, dass sie Ihnen vielleicht helfen könnten. Im Allgemeinen können solche Simulationen eine gute Methode sein, um einige Theorien zu umgehen. Um das Ergebnis anzuzeigen, führen Sie 'Datei> Neu> Neues Skript' aus, kopieren Sie den folgenden Code und fügen Sie ihn in das resultierende Fenster ein. Führen Sie dann 'Bearbeiten> Skript ausführen' aus (dauert etwa eine Sekunde), und überprüfen Sie die Ergebnisse.

NamesDefaultToHere(1);

n12 = 10000; // Number of boxes of 12 bars made
n = 12*n12;  // Number of bars made

// Generate data assuming an in-control process
dt = New Table( "Candy Bar Production",
    Add Rows( n ),
    New Column( "Weight",
     Numeric,
     "Continuous",
     Format( "Best", 12 ),
     Formula( Random Normal( 40.5, 1.96 ) ),
     Set Property( "Spec Limits", {LSL( 36.4 ), Target( 40 ), Show Limits( 0 )} )
    ),
    New Column( "4 Pack",
     Numeric,
     "Nominal",
     Format( "Best", 12 ),
     Formula( Modulo( Row(), Floor(n/4) ) )
    ),
    New Column( "12 Pack",
     Numeric,
     "Nominal",
     Format( "Best", 12 ),
     Formula( Modulo( Row(), Floor(n/12) ) )
    )
   );

// Make data for the 4 pack weights
dt4 = dt << Summary(
   Group( :Name( "4 Pack" ) ),
   Sum( :Weight ),
   statistics column name format( "column" )
  );
Column(dt4, "Weight") << Set Property( "Spec Limits", {LSL( 149.2 ), Target( 160 ), Show Limits( 0 )} );

// Make data for the 12 pack weights
dt12 = dt << Summary(
   Group( :Name( "12 Pack" ) ),
   Sum( :Weight ),
   statistics column name format( "column" )
  );
Column(dt12, "Weight") << Set Property( "Spec Limits", {LSL( 460 ), Target( 480 ), Show Limits( 0 )} );

// Use Control Chart Builder
dt << Control Chart Builder(Variables( Y( :Weight ) ));
dt4 << Control Chart Builder(Variables( Y( :Weight ) ));
dt12 << Control Chart Builder(Variables( Y( :Weight ) ));

Wie nützlich dies ist, hängt von den Details Ihrer Situation ab. Ich bin sehr vorsichtig, wenn ich das Wort "Verteilung" im Kontext von Statistical Process Control sehe: Wie im Code angegeben, wurden diese Daten unter der Voraussetzung eines perfekt kontrollierten Prozesses generiert (unabhängige Zufallsstichproben aus einer festen Gaußschen Verteilung). und wenn das wirklich wahr wäre, brauchen Sie keine SPC.