74645_ja-JP

liliconcom

行を非表示/除外したときに更新されないグラフィックススクリプトを追加

平均値と標準偏差を使用してヒストグラムにテキストラベルを追加します。私はグラフィックススクリプトを追加するためのカスタマイズ機能を通してそれをする方法を考え出しました。Y値はどのように設定すればよいのかまだわかりません。なぜなら、Y値は軸の単位に関連しているようには見えないからですが、私はそれを回避することができます。私の問題は、ラベルがローカルデータフィルタに応答して、または行を隠したり除外したりしても更新されないことです。機能する唯一のものは、行を削除することです。私はcol mean（）とcol std dev（）を使っています。他のものを使うべきですか？

 

NamesDefaultToHere(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << Distribution(
 Stack( 1 ),
 Automatic Recalc( 1 ),
 Continuous Distribution(
  Column( :height ),
  Summary Statistics( 1 ),
  Horizontal Layout( 1 ),
  Vertical( 0 ),
  Count Axis( 1 ),
  Set Quantile Increment( 0.25 ),
  Customize Summary Statistics(
   Std Err Mean( 0 ),
   Upper Mean Confidence Interval( 0 ),
   Lower Mean Confidence Interval( 0 ),
   N( 0 ),
   Median( 0 )
  )
 ),
 Histograms Only,
 Local Data Filter( Grouped by AND( 1 ), Add Filter( columns( :height ) ) ),
 SendToReport(
  Dispatch(
   {"height"},
   "Distrib Histogram",
   FrameBox,
   {Frame Size( 414, 428 ),
   Add Graphics Script(
    2,
    Description( "Script" ),
    Text(
     Right Justified,
     {72, 0.11},
     "Mean: " || Format( Col Mean( :height ), "Fixed Dec", 12, 2 )
    );
    Text(
     Right Justified,
     {72, 0.105},
     "StdDev: " || Format(
      Col Std Dev( :height ),
      "Fixed Dec",
      12,
      2
     )
    );
   ), Grid Line Order( 1 ), Reference Line Order( 3 )}
  )
 )
);

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

ローカルデータフィルタにはプライベートテーブルがあり、そのハンドルを取得する方法がわかりません。ただし、次の方法で計算を正しくすることができます。

• ローカルデータからフィルタ処理された行を取得します。これらは制限を適用した後に残っている行です。除外されていることは考慮されていません。
• データテーブルから除外された行を取得します
• 除外対象をフィルタ対象から削除します
• それから統計を計算する

ヒストグラムに関するこの問題は、私の考えでは、枠の中に配置するのが難しいということです。フォーラムの誰かが、テキストを左上隅からのオフセットとして設定する方法を説明できます。  私はおそらくそれ自身のテキストボックスにそれを書き出すだろう？下のスクリーンショットは、テキストがサマリーテーブルと一致することを示しています。  スクリプトが添付されています。

   

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

ローカルデータフィルタによって失敗することがわかりました。回避策としてテーブルレベルでフィルタを設定することもできます。そのため、フィルタを非表示にしたり除外したりすることができますが、これは私の当面のニーズには十分に近いでしょう。ありがとう。

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

ありがとう。  Graph Builderの例で使用したコードは、同じテキストを使用しています（Center Justified、{_ x_、_ y_}、"_ text_"）。配布プラットフォームの例で使用したコマンドなので、構文がどのように機能するのか明確ではありません。

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

Col Mean（）についての私の投稿を見てください。また、yuがTextBoxを使用している場合（コードが表示されていない場合）は、マークアップを使用してテキストに下線を引くことができます。これは、Display Box> TextBox> MarkupのJMPスクリプティングインデックスの例です。

Names Default To Here( 1 );
win = New Window( "Example", fontobj = text = Text Box( "Example Text" ) );
text << setText(
 "This is <B>bold</B> text. This is <I>italic</I> text. This is <U>underlined</U> text. This is <B><I><U>bold, italic, underlined</U></I></B> text."
);
text << markup;

 

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

****この提案は無視してください。これはローカルデータフィルタなので、テーブルの行は取り出されません*** 

 

別の方法は、除外されていない行のみを使用することです。

Text(
 Right Justified,
 {72, 0.11},
 "Mean: " || Format( Col Mean( If(Excluded(),empty(),1)*:height ), "Fixed Dec", 12, 2 )
);
Text(
 Right Justified,
 {72, 0.105},
 "StdDev: " || Format(
  Col Std Dev(If(Excluded(),empty(),1) *:height ),
  "Fixed Dec",
  12,
  2
 )
);

 

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

あなたが単語の下にline（）関数を追加した場合を除いて、私はテキストに下線を引く方法を見ない

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

ありがとう。下線を引く方法を知っていますか。私はヘッダを追加しました、そして今のところ私はテキストをより大きくし、そしてそれを相殺しました、しかし、それはよりよく下線を引かれるように見えるでしょう。 

 

また、どのようにしてGraph Builderでこれを機能させるかについては何か考えがありますか。

 

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

Y軸の位置はY / 100です。

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

_y_の値の選び方について何か手引きがありますか？_x_の値はx軸の目盛りと結びついているように見えますが、_y_はそうではありません。

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

私は自分の例に要約統計を含めて、何が起こると予想していたかを示しましたが、それを私のアプリケーションで使用することを計画していませんでした。私はそれを可能にすることができると思いますが、それを私がプレゼンテーションに挿入するためにグラフをコピーするときそれが含まれないように最小化します。残念なことに、これらの機能は予期しない方法で動作しているように見えますが、作業は完了します。ありがとう。

再：非表示/除外行を更新しないグラフィックスクリプトを追加します。

あなたが抱えている問題は、Col Mean（）とCol Std Dev（）関数がExcluded dataルールに従わないことです。  だからあなたはあなたが望む値を得るために何らかの方法を持つ必要があります。  以下がその方法の1つです。

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dis = dt << Distribution(
 Stack( 1 ),
 Automatic Recalc( 1 ),
 Continuous Distribution(
  Column( :height ),
  Summary Statistics( 1 ),
  Horizontal Layout( 1 ),
  Vertical( 0 ),
  Count Axis( 1 ),
  Set Quantile Increment( 0.25 ),
  Customize Summary Statistics(
   Std Err Mean( 0 ),
   Upper Mean Confidence Interval( 0 ),
   Lower Mean Confidence Interval( 0 ),
   N( 0 ),
   Median( 0 )
  )
 ),
 Histograms Only,
 Local Data Filter( Grouped by AND( 1 ), Add Filter( columns( :height ) ) ),
 SendToReport(
  Dispatch(
   {"height"},
   "Distrib Histogram",
   FrameBox,
   {Frame Size( 414, 428 ), Add Graphics Script(
    2,
    Description( "Script" ),
    Text(
     Right Justified,
     {72, 0.11},
     "Mean: " || Format(report(dis)[numbercolbox(1)][1]/* Col Mean( :height )*/, "Fixed Dec", 12, 2 )
    );
    Text(
     Right Justified,
     {72, 0.105},
     "StdDev: " || Format(report(dis)[numbercolbox(1)][2]/* Col Std Dev( :height )*/, "Fixed Dec", 12, 2 )
    );
   ), Grid Line Order( 1 ), Reference Line Order( 3 )}
  )
 )
);