공식 편집기의 선형 회귀여보세요,
나는 선형 회귀 분석을 사용하여 임상 연구에서 시간에 따른 생물학적 변수의 기울기를 연구하고 있습니다.
수식 편집기를 사용하여 새 열의 기울기를 계산할 수 있습니까? 또는 그러한 열을 생성하는 또 다른 방법은 무엇입니까?
나는 JMP 12를 사용하고있다.
도와 줘서 고마워.
플로랑
제목 : Re : 선형 회귀 수식 편집기에서다음은 길이 - 길이 회귀 기울기를 계산하는 열 수식의 두 가지 예입니다. "Big Class"예제 테이블이 사용됩니다.
첫 번째는 모든 관측치를 기반으로 한 기울기를 계산하고 열을 통해 동일한 숫자를 반복하는 대신 첫 번째 행에 표시합니다.
두 번째 단계에서는 점차적으로 기울기를 계산하고 (사용자가 요구할 수도 있음) 더 많은 데이터가 포함될 때 기울기가 어떻게 변화 / 안정화되는지보고 최종적으로 전체 기울기 (예 : 첫 번째 예)와 수렴합니다.
이것을 자신의 데이터에 적용하려면 전체 공식을에서 괄호 안에 복사하십시오. F = Expr () 수식 편집기에 붙여 넣은 다음 대입합니다. 무게 과 신장 귀하의 변수.
dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt << New Column("Slope",
Formula(
If(Row() == 1,
Col Sum((:height - Col Mean(:height)) * (:weight - Col Mean(:weight))) /
Col Sum((:height - Col Mean(:height)) ^ 2),
.
)
)
);
F = Expr(
Eval(
Eval Expr(
Col Sum(
(:height - Col Mean(:height, Row() <= Expr(Row()))) * (:weight
-Col Mean(:weight, Row() <= Expr(Row()))),
Row() <= Expr(Row())
) / Col Sum(
(:height - Col Mean(:height, Row() <= Expr(Row()))) ^ 2,
Row() <= Expr(Row())
)
)
)
);
dt << New Column("Incremental Slope", Formula(Name Expr(F)));
제목 : Re : 선형 회귀 수식 편집기에서기울기 값을 데이터와 동일한 테이블의 열에 넣는 것은 잘못되었습니다.
그러나 이것이 실제로 당신이 의도 한 것이고 JMP 플랫폼을 사용하지 않으려는 경우, JMP 12에서이를 수행하는 한 가지 방법이 있습니다.
NamesDefaultToHere(1);
myLinearRegression =
Function({x, y}, {Default Local},
// Add the unit vector to the design matrix
x = J(NRow(x), 1, 1)||x;
// Get the parameters
betas = Transpose(Inv(x`*x)*x`*y);
);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
Wait(3);
xVals = Column(dt, "height") << getValues;
yVals = Column(dt, "weight") << getValues;
betas = myLinearRegression(xVals, yVals);
slope = betas[2];
dt << NewColumn("Slope of weight vs. height", Numeric, Continuous, Values(Repeat(slope, NRow(dt))));
'파일> 새로 만들기> 새 스크립트'를 실행하고 위의 JSL을 잘라내어 붙여 넣은 다음 '편집> 스크립트 실행'을 선택하십시오.
물론 계산 된 기울기를 신뢰하기 전에 데이터를 플롯하는 것이 항상 좋은 생각입니다. 'Analyze> Fit Y By X'가 설계되었습니다.
