74645_it-IT

liliconcom

Aggiungi lo script di grafica che non si aggiorna quando le file sono nascoste / escluse

Voglio aggiungere etichette di testo a un istogramma con la media e la deviazione standard. Ho capito come farlo attraverso la funzione di personalizzazione per aggiungere uno script di grafica. Non sono ancora chiaro su come impostare il valore y, dal momento che non sembra essere collegato alle unità dell'asse, ma posso aggirarlo. Il mio problema è che le etichette non si aggiornano in risposta a un filtro dati locale o nascondendo / escludendo righe. L'unica cosa che funziona è eliminare le righe. Sto usando col mean () & col std dev (); dovrei usare qualcos'altro?

 

NamesDefaultToHere(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << Distribution(
 Stack( 1 ),
 Automatic Recalc( 1 ),
 Continuous Distribution(
  Column( :height ),
  Summary Statistics( 1 ),
  Horizontal Layout( 1 ),
  Vertical( 0 ),
  Count Axis( 1 ),
  Set Quantile Increment( 0.25 ),
  Customize Summary Statistics(
   Std Err Mean( 0 ),
   Upper Mean Confidence Interval( 0 ),
   Lower Mean Confidence Interval( 0 ),
   N( 0 ),
   Median( 0 )
  )
 ),
 Histograms Only,
 Local Data Filter( Grouped by AND( 1 ), Add Filter( columns( :height ) ) ),
 SendToReport(
  Dispatch(
   {"height"},
   "Distrib Histogram",
   FrameBox,
   {Frame Size( 414, 428 ),
   Add Graphics Script(
    2,
    Description( "Script" ),
    Text(
     Right Justified,
     {72, 0.11},
     "Mean: " || Format( Col Mean( :height ), "Fixed Dec", 12, 2 )
    );
    Text(
     Right Justified,
     {72, 0.105},
     "StdDev: " || Format(
      Col Std Dev( :height ),
      "Fixed Dec",
      12,
      2
     )
    );
   ), Grid Line Order( 1 ), Reference Line Order( 3 )}
  )
 )
);

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

Il filtro dati locale ha una tabella privata e non so come ottenerlo. Tuttavia, è possibile ottenere il calcolo corretto mediante:

• ottiene le righe filtrate dai dati locali, queste sono le righe rimanenti dopo l'applicazione della restrizione, non tiene conto dell'esclusione
• ottenere le righe escluse dalla tabella dei dati
• rimuovere gli esclusi dal filtrato
• quindi calcola le statistiche

Questo problema con l'istogramma è che il posizionamento nel frambox è a mio avviso fasullo. Forse qualcuno sul forum, può spiegare come impostare il testo come offset dall'angolo in alto a sinistra.  Probabilmente scriverò nella sua casella di testo vero ?? Lo screenshot qui sotto mostra il testo corrisponde alla tabella riassuntiva.  Lo script è allegato.

   

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

Vedo ora che il filtro dati locale causerà un errore. Potrei mettere il filtro a livello di tabella come un aggiramento, quindi dovrebbe nascondere / escludere, ma funzionerà abbastanza vicino per le mie esigenze immediate. Grazie.

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

Grazie.  Il codice che ho usato per l'esempio di Graph Builder utilizza lo stesso testo (giustificato al centro, {_x_, _y_}, "_text_"); comando che ho usato per l'esempio della piattaforma di distribuzione, quindi non sono chiaro su come funzionerebbe la sintassi.

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

Vedi il mio post sul Col Mean (). Inoltre, se stai usando un TextBox (il tuo codice non è visibile) puoi usare il markup per sottolineare il testo. Questo è l'esempio dell'indice di scripting JMP per la casella di visualizzazione> TextBox> Markup

Names Default To Here( 1 );
win = New Window( "Example", fontobj = text = Text Box( "Example Text" ) );
text << setText(
 "This is <B>bold</B> text. This is <I>italic</I> text. This is <U>underlined</U> text. This is <B><I><U>bold, italic, underlined</U></I></B> text."
);
text << markup;

 

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

**** Ignora questo suggerimento. Questo è un filtro dati locale, quindi le righe della tabella non sono escluse *** 

 

Un'alternativa è usare solo righe non escluse

Text(
 Right Justified,
 {72, 0.11},
 "Mean: " || Format( Col Mean( If(Excluded(),empty(),1)*:height ), "Fixed Dec", 12, 2 )
);
Text(
 Right Justified,
 {72, 0.105},
 "StdDev: " || Format(
  Col Std Dev(If(Excluded(),empty(),1) *:height ),
  "Fixed Dec",
  12,
  2
 )
);

 

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

Non vedo un modo per sottolineare il testo, tranne se hai aggiunto una funzione line () sotto la parola

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

Grazie. Conosci qualche modo per sottolineare il testo? Ho aggiunto le intestazioni e per ora ho ingrandito il testo e lo ho compensato, ma sarebbe stato meglio sottolineato. 

 

Inoltre, hai qualche idea su come farlo funzionare in Graph Builder, dal momento che non ha statistiche riassuntive da cui estrarre?

 

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

sembra che la posizione dell'asse Y sia Y / 100

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

Qualche guida su come scegliere il valore _y_? il valore _x_ sembra legato alla scala dell'asse x, ma il _y_ no.

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

Ho incluso le statistiche riassuntive nel mio esempio per mostrare quello che mi aspettavo che accadesse, ma non avevo programmato di usarlo nella mia applicazione. Immagino di poterlo abilitare, ma averlo minimizzato in modo che non venga incluso quando copio il grafico per l'inserimento in una presentazione. Sembra un kludge, e che queste funzioni si stanno comportando in modo inaspettato, ma farà il lavoro. Grazie.

Ri: aggiungere lo script di grafica non si aggiorna quando le righe sono nascoste / escluse

Il problema che si sta verificando è che le funzioni Col Mean () e Col Std Dev () non seguono le regole dei dati esclusi.  Quindi devi avere un modo per ottenere i valori che desideri.  Di seguito è un modo per farlo.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

dis = dt << Distribution(
 Stack( 1 ),
 Automatic Recalc( 1 ),
 Continuous Distribution(
  Column( :height ),
  Summary Statistics( 1 ),
  Horizontal Layout( 1 ),
  Vertical( 0 ),
  Count Axis( 1 ),
  Set Quantile Increment( 0.25 ),
  Customize Summary Statistics(
   Std Err Mean( 0 ),
   Upper Mean Confidence Interval( 0 ),
   Lower Mean Confidence Interval( 0 ),
   N( 0 ),
   Median( 0 )
  )
 ),
 Histograms Only,
 Local Data Filter( Grouped by AND( 1 ), Add Filter( columns( :height ) ) ),
 SendToReport(
  Dispatch(
   {"height"},
   "Distrib Histogram",
   FrameBox,
   {Frame Size( 414, 428 ), Add Graphics Script(
    2,
    Description( "Script" ),
    Text(
     Right Justified,
     {72, 0.11},
     "Mean: " || Format(report(dis)[numbercolbox(1)][1]/* Col Mean( :height )*/, "Fixed Dec", 12, 2 )
    );
    Text(
     Right Justified,
     {72, 0.105},
     "StdDev: " || Format(report(dis)[numbercolbox(1)][2]/* Col Std Dev( :height )*/, "Fixed Dec", 12, 2 )
    );
   ), Grid Line Order( 1 ), Reference Line Order( 3 )}
  )
 )
);