107338_de-DE

liliconcom

So zeigen Sie in der Grafik nur den fehlgeschlagenen T-Test an

Hallo zusammen,

Ich verwende das folgende Skript, um einen T-Test zwischen zwei Gruppen durchzuführen (gestresste Abd-Kontrolle).

 Oneway(
    Y( :Shift ),
    X( :Group ),
    by(:Test),
    t Test( 1 ),
    Box Plots( 1 ),
    X Axis Proportional( 0 ),
    Points Jittered( 1 ),
    Grand Mean( 0 ),
    SendToReport(
    Dispatch(
    {},
    "Oneway Plot",
    FrameBox,
    {DispatchSeg(
    Box Plot Seg( 1 ),
    {Box Type( "Outlier" ), Line Color( "Red" )}
    ), DispatchSeg(
    Box Plot Seg( 2 ),
    {Box Type( "Outlier" ), Line Color( "Red" )}
    )}
    )
    )
   );

Wie Sie sehen können, führe ich den T-Test für jeden „Test“ durch und habe Tausende von Tests. Meine Frage: Gibt es eine Option, in der Grafik nur den Test anzuzeigen, bei dem der T-Test fehlgeschlagen ist?

 

Danke!!

Betreff: So zeigen Sie in der Grafik nur den fehlgeschlagenen T-Test an

@Adir52 Für einen Vergleich mit zwei Stichproben wird nach Möglichkeit empfohlen, in jeder Gruppe die gleiche Anzahl von Einheiten zu verwenden.

 

Die Stichprobengröße ist der Faktor, der zur Reduzierung des Risikos eines Typ-II-Fehlers verwendet wird.

 

" In statistische Hypothesentests , A Fehler vom Typ I ist die Ablehnung eines wahren Nullhypothese (auch bekannt als „falsch positiver“ Befund), während a Fehler vom Typ II ist das Versäumnis, eine falsche Nullhypothese abzulehnen (auch bekannt als „falsch negativer“ Befund). ^[1] Einfacher ausgedrückt besteht ein Fehler vom Typ I darin, fälschlicherweise auf die Existenz von etwas zu schließen, das nicht vorhanden ist (wodurch die allgemeine Meinung mit falschen Informationen bestätigt wird), während ein Fehler vom Typ II darin besteht, fälschlicherweise auf die Abwesenheit von etwas zu schließen, das nicht vorhanden ist (was dem widerspricht). allgemeiner Glaube mit falschen Informationen). "

 

Ausschnitt aus https://en.wikipedia.org/wiki/Type_I_and_type_II_errors . Auch wenn Sie als Nullhypothese angeben, dass die Kontrollprobe und die unbelastete Probe unterschiedlich sind, lautet die Nullhypothese des Zweistichprobentests (ANOVA für 2 Gruppen), dass die Mittelwerte von Gruppe 1 und Gruppe 2 äquivalent und gleich sind.Sie müssen Ihr Experiment also so gestalten, dass der Test einen bestimmten Unterschied erkennen kann. Wenn Sie beispielsweise zu 95 % sicher sein möchten, dass Ihr Experiment einen Unterschied von 0,5 Sigma erkennt, können Sie JMP verwenden, um die Anzahl der Einheiten auszuwählen.

Wählen Sie im JMP-Hauptmenü die Option DOE. Je nach JMP-Version enthält das Menü oder eines der Untermenüs Folgendes: Stichprobengröße und Leistung Taschenrechner. In JMP 14 finden Sie es, indem Sie DOE > Design Diagnostics auswählen. Dann auswählen Zwei Beispielmittel . Unten finden Sie einen Screenshot. Da jeder Test wahrscheinlich eine andere Standardabweichung aufweist, wird dieser Entwurfsschritt mit relativen Werten durchgeführt. Angeben Standardabw als 1 und dann die Unterschied als der zu erkennende Unterschied. Nachfolgend wird es mit 1 angegeben. Wenn Sie drücken Weitermachen Die Stichprobengröße beträgt 54 oder 27 Einheiten für jede Gruppe. Löschen Sie die Stichprobengröße und geben Sie die an Unterschied 0,5 oder die Hälfte der Std.-Abw betragen soll, und drücken Sie dann Weitermachen, Die Stichprobengröße beträgt 210 oder 105 Einheiten für jede Gruppe. Oder löschen Sie „Differenz“ und geben Sie unter „Stichprobengröße“ (80 Einheiten pro Gruppe) den Wert 160 ein. Dann wird die Differenz als 0,57 gemeldet, oder Ihr Test hat die Gewissheit, dass in 95 % der Fälle eine Differenz von 0,57 Sigma erkannt wird.

Wenn Sie einen Statistiker oder einen Statistikprofessor an einer Universität in der Nähe haben, der mit Ihrer Branche vertraut ist, empfehle ich Ihnen, darüber zu sprechen.In Ihrer spezifischen Studie gibt es möglicherweise eine lange Historie der Kontrolle, und die Anzahl der Kontrolleinheiten dient lediglich der Überprüfung, ob die Kontrolle innerhalb der Basislinie liegt.Aber noch wichtiger ist die Auswahl der Einheiten und die Art und Weise, wie das Experiment durchgeführt wird, um einen fairen Vergleich zu ermöglichen und auf welche Population diese Schlussfolgerungen zutreffen.

Betreff: So zeigen Sie in der Grafik nur den fehlgeschlagenen T-Test an

pValue ist die Wahrscheinlichkeit, dass Ihr statistischer Test signifikant ist.Die Signifikanz wird historisch als 1 zu 20 (pValue <= .05) oder 2 zu 20 (pValue <= .1) definiert.Und ja, in Ihrem Fall möchten Sie herausfinden, wo der pValue > .05 oder > .1 ist, da Ihr Ho Group1=Group2 ist.

Betreff: So zeigen Sie in der Grafik nur den fehlgeschlagenen T-Test an

Hallo @gzmorgan0

Haben Sie eine Empfehlung bezüglich der Stichprobengröße der Kontrolleinheiten?

Die Anzahl der Straßeneinheiten wird 80 Einheiten betragen.

Betreff: So zeigen Sie in der Grafik nur den fehlgeschlagenen T-Test anHallo Txnelson
Zunächst einmal vielen Dank für Ihren Beitrag, er war sehr hilfreich.
ich hatte eine falsche Frage. Ich möchte die Tests anzeigen, bei denen die Gruppen statistisch nicht gleich sind. Es ist ganz einfach, Ihren Code zu verwenden und die folgende Zeile zu löschen:
dt << Zeilenauswahl umkehren;

Könnten Sie uns die Bedeutung des PValue erläutern?
ist es = Prob>|t|?
Ich stelle diese Frage, weil mein H0 Gruppe1=Gruppe2 istBetreff: So zeigen Sie in der Grafik nur den fehlgeschlagenen T-Test an

@txnelson (Jim), es ist so lustig, ich habe auch eine Antwort mit einer Tabelle aus Semiconductor Capability.jmp begonnen, die aus Loszusammenfassungen von Waferzusammenfassungen besteht und zufällig Lose aus Gruppe A oder Gruppe B auswählt. Da ich Ihre Antwort gesehen habe, werde ich die Einzelheiten nicht aufschreiben. Im Anhang finden Sie die Datentabelle und das Skript zum Erstellen der folgenden Grafik, beispielsweise alle 100 Tests oder eine logische Gruppierung von Tests.

 

In der Praxis ist es sinnvoll, den F-Test und den p-Wert hinzuzufügen, um Standardabweichungen zu vergleichen und einen Vergleich mit n, der Anzahl der getesteten Einheiten für jede Gruppe, durchzuführen. Seit @Adir52 Die Gruppen waren kontrolliert und gestresst, Stress konnte zu nicht messbaren (leeren) Ergebnissen führen.Auch wenn es Tausende von Tests gibt, beispielsweise Halbleitertests, könnten einige Tests korreliert sein, sagen wir, dass alle PNP-Tests nach oben verschoben wurden, aber nicht alle waren signifikant. Dies würde als T-Verhältnisse größer als 0 angezeigt.

Als Statistiker muss ich vor der statistischen Signifikanz warnen. Beachten Sie, dass für diese zufällig gruppierten Daten 118 t-Tests (128 Tests, 10 hatten null Standardabweichung und kein t-Verhältnis) 11 mit einem p-Wert von < 0,10 gekennzeichnet waren, was der erwarteten Fehlerrate entspricht (und 5 Tests mit p -Wert < 0,05).Es gibt also viele Vorbehalte, wenn die Beurteilung nur auf p-Werten und nur auf der Mittelwertprüfung basiert.

 

Letzter Vorbehalt an @Adir52 Wenn die Messungen von automatisierten Testgeräten gemeldet werden, kann die Reihenfolge wichtig sein.Wenn ein Zeitelement vorhanden ist, empfehle ich für jeden Test so etwas wie diese Anzeige.

 

Betreff: So zeigen Sie in der Grafik nur den fehlgeschlagenen T-Test an

Es gibt mehrere Möglichkeiten, diese Frage in JMP zu lösen.Ich verwende Response Screening lieber, um einen sehr schnellen Durchlauf der Daten durchzuführen, um nur die p-Werte der Analysen zu erhalten, und nehme dann diese Ergebnisse und wähle die gewünschten Daten für die Analyse aus.Unten finden Sie ein einfaches Skript, das dies für einige von mir erstellte Beispieldaten ausführt, damit diese mit den Spaltennamen Ihrer spezifischen Datentabelle übereinstimmen.

names default to here(1);

// Modify a sample data table to mimic your t-test code
dtSemi = open("$SAMPLE_DATA/semiconductor capability.jmp", invisible);

dtSemi << select where( :Site > 2 );
dtSemi << delete rows;
dtSemi:Site << set name( "Group" );
colNames = dtSemi << get column names( continuous );

dt = dtSemi << stack( columns(colNames) ,
 Source Label Column( "Test" ),
 Stacked Data Column( "Shift" ),
 Name( "Non-stacked columns" )(Keep( :Group ))
);

close( dtSemi, nosave );

// The above code just creates a sample data table....The code below generates
// the desired output

// Now run the Response Screening to get the failed t-tests
rs = dt << Response Screening( Y( :Shift ), X( :Group ), Grouping( :Test ) );
dtRS = rs << Get PValues;
//dtRS << show window( 0 );
report(rs) << close window;

// select all of the failed t-tests and get their test names
// We are using failue of .1 as the target.....just change the
// target value if you want .05 or something else as the failure value
dtRS << select where( :PValue <= .1 );

If( N Rows(dtRS << get selected rows ) > 0,
 dtRS << delete rows;
);

failingTests = dtRS:Test << get values;

// close the dtRS data table that is no longer needed
close( dtRS, nosave );

// Now select the Tests in the original data table that are not significant
dt << select where( contains( failingTests, :Test ) );

If( N Rows( dt << get selected rows ) > 0,
 dt << invert row selection;
 dt << hide and exclude ;
 dt << clear select;
);

// Run your code
Oneway(
    Y( :Shift ),
    X( :Group ),
    by(:Test),
    t Test( 1 ),
    Box Plots( 1 ),
    X Axis Proportional( 0 ),
    Points Jittered( 1 ),
    Grand Mean( 0 ),
    SendToReport(
    Dispatch(
    {},
    "Oneway Plot",
    FrameBox,
    {DispatchSeg(
    Box Plot Seg( 1 ),
    {Box Type( "Outlier" ), Line Color( "Red" )}
    ), DispatchSeg(
    Box Plot Seg( 2 ),
    {Box Type( "Outlier" ), Line Color( "Red" )}
    )}
    )
    )
   );