41166_de-DE

liliconcom

Consumer Research: Kategorisch: Reihenfolge absteigend nach Durchschnittswert oder nach Gesamtantworten

Liebe Community,

 

Ich habe das folgende Skript mit " Sortieren nach Mittelwert ( 1 ) "beeinflusst das Endergebnis jedoch nicht. Hat Panel Box solche Auswirkungen oder mache ich etwas falsch?

 

Schätzen Sie jede Idee ....

 

 

 

Panel Box(
    "Resorts:YASMIN, Report:GSQ, SubReport:Marketing, Author:SaitCopuroglu,  " || Long Date( Today() ) || " "
     || Format( Time Of Day( Today() ), "h:m" ),
    Data Table( "Veri_SelectionsTest2016RESORTS.jmp" ) << Categorical(
        Grouping Option( Each Individually ),
        X( :Agency ),
        Responses( :Answer Categorical ),
        Frequencies( 0 ),
        Share Chart( 0 ),
        Legend( 0 ),
        Mean Score( 1 ),
        Std Dev Score( 1 ),
        Order by Mean Score( 1 ),
        Local Data Filter(
            Close Outline( 1 ),
            Conditional,
            Add Filter(
                columns( :Resort, :Year, :Record Date ),
                Where( :Resort == "YASMIN" ),
                Where( :Year == 2017 ),
                Where( :Record Date >= 01May2017 & :Record Date <= Today() ),
                Display( :Resort, Size( 123, 21 ), Check Box Display ),
                Display( :Year, Size( 110, 40 ), Check Box Display )
            )
        ),
        SendToReport(
            Dispatch( {}, "Categorical", OutlineBox, {Set Title( "YASMIN RESORT 2017" )} ),
            Dispatch( {}, "(Resort = YASMIN) and (Record Date == 22May2017)", TextBox, {Set Wrap( 1200 )} ),
            Dispatch(
                {},
                "Responses( Answer Categorical ) By Agency",
                OutlineBox,
                {Set Title( "Responses By AGENCY" )}
            )
        )
    )
)

 

Re: Consumer Research: Kategorisch: Reihenfolge absteigend nach Durchschnittswert oder nach Gesamtantworten

Um das Problem zu lösen, müssen Sie nicht zu Excel gehen.  Die Lösung ist zwar nicht die einfachste Lösung, die Ausgabe der Categorical Platform kann jedoch direkt in eine JMP-Datentabelle konvertiert werden.  Nachfolgend finden Sie ein "nicht generisches" Skript, das zeigt, wie das geht.  Das Skript kann in einen generischen Code umgewandelt werden, der für die meisten Fälle geeignet ist.

Names Default To Here( 1 );
dt = Current Data Table();
rpt = dt << Categorical(
 GroupingOption( EachIndividually ),
 X( :SECTION, :MARKET, :COUNTRY ),
 Responses( :VALUE ),
 Frequencies( 0 ),
 ShareChart( 0 ),
 Legend( 0 ),
 MeanScore( 1 ),
 OrderByMeanScore( 1 )
);

dtCountry = New Table( "Country" );

// Build the Country Coulumn
CountryString = Report( rpt )["Responses( VALUE ) By COUNTRY"][GridCellBox( 10 )] << get text;
// Buildthe list of Countries
CountryStringList = {};
WordCNT = 3;
While( Trim( Word( WordCNT, CountryString, "\!n" ) ) != "",
 Insert Into( CountryStringLIst, Trim( Word( WordCNT, CountryString, "\!n" ) ) );
 WordCNT++;, 

);
dtCountry << New Column( "Country", character, values( CountryStringList ) );

// Build the Percent Columns
dtCountry << New Column( "Çok iyi", Format( "Percent", 7, 2 ) );
dtCountry << New Column( "İyi", Format( "Percent", 7, 2 ) );
dtCountry << New Column( "Ortalama", Format( "Percent", 7, 2 ) );
dtCountry << New Column( "Zayıf", Format( "Percent", 7, 2 ) );
dtCountry << New Column( "Çok Zayıf", Format( "Percent", 7, 2 ) );
PercentString = Report( rpt )["Responses( VALUE ) By COUNTRY"][GridMultiCellBox( 2 )] << get text;
WordCNT = 1;
While( Trim( Word( WordCNT, PercentString, "\!n" ) ) == "", WordCNT++ );
RowCNT = WordCNT - 1;
While( Trim( Word( WordCNT, PercentString, "\!n" ) ) != "",
 TheLine = Trim( Word( WordCNT, PercentString, "\!n" ) );
 For( i = 1, i <= 5, i++,
  Column( dtCountry, i + 1 )[WordCNT - RowCNT] = Num( Trim( Word( i, Theline, "%" ) ) ) / 100
 );
 WordCNT++;
);

// Add the Total Responses Column
TotalString = Report( rpt )["Responses( VALUE ) By COUNTRY"][GridCellBox( 2 )] << get text;
TotalStringList = {};
WordCNT = 3;
While( Trim( Word( WordCNT, TotalString, "\!n" ) ) != "",
 Insert Into( TotalStringLIst, Num( Trim( Word( WordCNT, TotalString, "\!n" ) ) ) );
 WordCNT++;,

);
dtCountry << New Column( "Total Responses", values( TotalStringList ) );

// Add the Mean Column
MeanString = Report( rpt )["Responses( VALUE ) By COUNTRY"][GridCellBox( 4 )] << get text;
MeanStringList = {};
WordCNT = 3;
While( Trim( Word( WordCNT, MeanString, "\!n" ) ) != "",
 Insert Into( MeanStringLIst, Num( Trim( Word( WordCNT, MeanString, "\!n" ) ) ) );
 WordCNT++;,

);
dtCountry << New Column( "Mean", values( MeanStringList ) );

// Sort the table
dtCountry << Sort( By( :Mean ), Order( Ascending ), Replace Table( 1 ) );

Re: Consumer Research: Kategorisch: Reihenfolge absteigend nach Durchschnittswert oder nach Gesamtantworten

Das Problem ist, dass es sich bei den Ergebnissen um einen Kreuztabellenbericht handelt (keine Standarddatentabelle).  Eine Teillösung wäre, Ihre Ergebnisse in Excel zu speichern und sie dort zu bearbeiten.  Zum Beispiel:

NamesDefaultToHere(1);
dt = CurrentDataTable();
rpt = dt << Categorical(
 GroupingOption( EachIndividually ),
 X( :SECTION, :MARKET, :COUNTRY ), Responses( :VALUE ),
 Frequencies(0), ShareChart(0), Legend(0),
 MeanScore(1), OrderByMeanScore(1)
);
rpt << SaveExcelFile( "C:\Categorical.jmp",
 SeparateRowsForEachCellStatistic(1)
);

 

Nächste Schritte sind:

• Öffnen Sie die gespeicherte Excel-Datei
• Löschen Sie nicht benötigte Excel-Spalten und -Zeilen manuell
• Speichern Sie die Daten in einer oder mehreren JMP-Datentabellen
• Verwenden Sie die JMP-Tabellensortierung

 

Re: Consumer Research: Kategorisch: Reihenfolge absteigend nach Durchschnittswert oder nach Gesamtantworten

Vielen Dank für Ihre Antwort.

Ich habe eine vereinfachte Datentabelle mit dem Skript "kategorisch" angehängt. Die gleiche Frage für diese spezifische Analyse ist, ob es eine Option für die Tabellenanordnung gibt, die nach Gesamtantworten und Mittelwert auf- oder absteigend ist

Ich habe versucht, die Spalte "COUNTRY" mit "Wert" zu versehen, aber wenn die Daten aktualisiert werden, wird auch die Wertereihenfolge ...

Danke im Voraus

Re: Consumer Research: Kategorisch: Reihenfolge absteigend nach Durchschnittswert oder nach Gesamtantworten

Können Sie eine Beispieldatentabelle für dieses Skript bereitstellen?