45490_es-ES

liliconcom

Fórmula de extracción para préstamo

Hola,

 

Quiero extraer de un cronograma de préstamos la fórmula que representa la suma de los intereses en efectivo durante el período del préstamo y la fórmula que corresponde al pago del capital sabiendo que también hay intereses compuestos. Quiero definir una variable para cambiar mientras otras están predefinidas (por ejemplo, se define la tasa de interés pero la variable es el pago mensual del préstamo que puedo definir como x1, x2, etc.)

 

Mi pregunta es:

 

1- cómo ingresar un calendario de préstamos en JMP Pro

2- cómo instruir a JMP Pro para que muestre la fórmula de la suma mencionada anteriormente

 

Muchas gracias por su ayuda

Re: Fórmula de extracción para préstamo.

Hola,

La siguiente secuencia de comandos crea una tabla que tiene información de pago de Principal e Intereses para un préstamo a 30 años con pagos mensuales. Puede ajustar el Principal inicial y la Tasa de interés en las variables de la tabla. También incluí columnas para los pagos acumulados de capital e intereses, así como el saldo restante. No estoy seguro de si esto es lo que buscabas, pero espero que te ayude a llegar allí.

Miguel

 

New Table( "Loan Payments",
 Add Rows( 360 ),
 New Table Variable( "Principal", 100000 ),
 New Table Variable( "Interest Rate", 0.04 ),
 New Column( "Month", Numeric, "Continuous", Format( "Best", 12 ), Set Values( 1 :: 360 ) ),
 New Column( "Principal Payment",
  Numeric,
  "Continuous",
  Format( "Currency", "USD", 17, 2 ),
  Formula( Principal Payment( :Interest Rate / 12, :Month, 360, -:Principal ) )
 ),
 New Column( "Interest Payment",
  Numeric,
  "Continuous",
  Format( "Currency", "USD", 17, 2 ),
  Formula( Interest Payment( :Interest Rate / 12, :Month, 360, -:Principal ) )
 ),
 New Column( "Total Payment",
  Numeric,
  "Continuous",
  Format( "Currency", "USD", 17, 2 ),
  Formula( Payment( :Interest Rate / 12, 360, -:Principal ) )
 ),
 New Column( "Cumulative Principal",
  Numeric,
  "Continuous",
  Format( "Currency", "USD", 17, 2 ),
  Formula( Col Cumulative Sum( :Principal Payment ) )
 ),
 New Column( "Cumulative Interest",
  Numeric,
  "Continuous",
  Format( "Currency", "USD", 17, 2 ),
  Formula( Col Cumulative Sum( :Interest Payment ) )
 ),
 New Column( "Remaining Balance",
  Numeric,
  "Continuous",
  Format( "Currency", "USD", 17, 2 ),
  Formula( :Principal - :Cumulative Principal )
 )
)

Re: Fórmula de extracción para préstamo.

Desafortunadamente, no sé lo suficiente sobre lo que estás tratando de hacer para ayudar. Sospecho que eso también puede ser cierto para otros (pero es posible que tenga suerte). ¿Tienes un ejemplo en, por ejemplo, Excel? 

Re: Fórmula de extracción para préstamo.

Gracias, pero ¿cómo puedo crear un calendario de préstamos y cómo puedo extraer la fórmula que mencioné? Por favor, aclare ya que necesito resolverlo con urgencia hoy. Gracias

Re: Fórmula de extracción para préstamo.

Para empezar, me gustaría revisar JMP's funciones financieras (mostrado abajo en el editor de fórmulas):