44711_ja-JP

liliconcom

JMPで特定の範囲のトランスクリプトの長さをビニングするのに役立つ

私はビニング（<250、250 - 500、500 - 1000、1000 - 1500、1500 - 2000、2000 - 2500、2500 - ）を使用してそれらの長さ分布をグラフ化したいと考えています。3000、> 3000）、最後のビンにはすべての長さ> 3000が含まれます。これまで私はこれを理解することができませんでした（JMPに新しい）。1行に1つの値、1つの列にすべてのトランスクリプトを持っています。

 

ありがとうございました、

 

ジョニー

再：JMPの特定の範囲でトランスクリプトの長さをビニングするのに役立つ

このスクリプトをありがとう、それは大いに役立ちます。私はあなたがJMPでスクリプトを書くことができるとは思わなかった。

 

ジョニー

再：JMPの特定の範囲でトランスクリプトの長さをビニングするのに役立つ

これを行う方法は、単純に新しい列を作成し、ビンを作成するためにかなり単純な式を使用することです。 ここにあなたが望むことをするスクリプトがあります、しかしあなたは新しい列を作成しそしてそれから式のためのコードを作成するために式エディタを使用することによってこれを対話的に簡単に作成することができます

Names Default To Here( 1 );
// Create an example data table
dt = New Table( "Bin",
 add rows( 60000 ),
 New Column( "value", numeric, formula( Random Normal( 1500, 600 ) ) )
);
// Make sure all 60,000 get processed before proceeding
wait(2);
// Remove the formula to make the values "real" not virtual values
dt:value << delete property( "formula" );

// Create a new column with a binning formula you want
dt << New Column( "Bin",
 character,
 formula(
  If(
   :value < 250, "<250",
   :value < 500, "250-499",
   :value > 3000, ">3000",
   Char( 500 * Floor( :value / 500 ) ) || "-" || Char(
    500 * Ceiling( :value / 500 ) - 1
   )
  )
 )
);

// Since the bin values will not display alphabetically, set the Value Ordering
// column property to make sure the ordering will display properly
dt:bin << set property(
 "value ordering",
 {"<250", "250-499", "500-999", "1000-1499", "1500-1999", "2000-2499", "2500-2999", ">3000"}
);

PS

私はあなたがあなたのコメントを見つけるだろうと信じています」 可能であればこれをどうやってやるのかという考えは非質問になるでしょう、あるいは少なくともそれは質問の最初の部分だけに修正されるでしょう。 JMPとJSLを使用すると、必要なものはほとんどすべて見つけることも、作成することもできます。