83017_es-ES

liliconcom

Para línea de referencia de gráfico de variable de bucle

Estoy generando una serie de gráficos (10 o más gráficos en total) con un bucle for; sin embargo, después del sexto gráfico, las líneas de referencia no aparecen en el gráfico. Después del gráfico 10 u 11, las líneas de referencia aparecen de nuevo en los gráficos. He intentado agregar esperar (0); en varios lugares, pero eso no ha ayudado. Intenté usar diferentes tipos de gráficos, bivariados estándar frente a generadores de gráficos, intenté reducir el tamaño de mi conjunto de datos original para ver si se trata de un problema de memoria. Ninguno de estos intentos ha funcionado y estoy buscando sugerencias. El segundo problema que me gustaría abordar, que es menos problemático que el primero, es cómo cerrar la tabla temporal creada sin cerrar los gráficos que he creado y guardado en mi ventana de resultados. Intenté usar el enlace a la tabla (0), intenté cerrar las tablas después de generar la ventana de salida y aún no funciona. Cualquier sugerencia es muy apreciada.

　

For( w = 1, w <= row_count, w++,
 Stmt = CofA_dt10:Parameter[w];
 CofA_dt9 << clear column selection;
 CofA_dt9 << select where( :Parameter == Eval( Parse( Eval Insert( "Stmt" ) ) ) );
 CofA_dt9a = CofA_dt9 << Subset( Output Table( "TempTable" || Char( w ) ), );
 
　
 Mean_4sigmaUCL = CofA_dt9a:UCL_Line[w];
 Mean_4sigmaLCL = CofA_dt9a:LCL_Line[w];
 
 
 output2 << append(
  V List Box(
   CofA_dt9a << 
 
   Bivariate(
    Y( :test_value ),
    X( :shelf_life_start_date ), 
 
    SendToReport(
     Dispatch(
      {},
      "Bivariate Fit of test_value By shelf_life_start_date",
      OutlineBox,
      {Set Title(
       "Parameter Value by shelf_life_start_date -" || Eval(
        Parse( Eval Insert( "Stmt" ) )
       )
      )}
     ), 
 
     Dispatch(
      {},
      "2",
      ScaleBox,
      {Add Ref Line( Mean_4sigmaUCL, "Solid", "Red", "Mean_4s_UCL", 1 ),
      Add Ref Line( Mean_4sigmaLCL, "Solid", "Red", "Mean_4s_LCL" )}
     ),
     Dispatch( {}, "1", ScaleBox, {Label Row( Label Orientation( "Angled" ) )} ),
     Dispatch( {}, "test_value", TextEditBox, {Set Text( "Parameter Value" )} ), 
 
     Dispatch(
      {},
      "Bivar Plot",
      FrameBox,
      {Frame Size( 1018, 423 ), Row Legend(
       Flagging,
       Color( 1 ),
       Color Theme( "JMP Default" ),
       Marker( 1 ),
       Marker Theme( "Standard" ),
       Continuous Scale( 0 ),
       Reverse Scale( 1 ),
       Excluded Rows( 0 )
 
      )}
     )
    )
   )
  )
 )
 
 ;
); //end row loop

 

Re: Línea de referencia de gráfico de variable de bucle For

El HTML interactivo intenta mantener algo de interactividad cuando se envuelve en un clonebox, pero como lo señala Craige...

<SPAN class="token comment">"disconnects the clone from the data table"</SPAN>

Cuando se utiliza una Leyenda de fila, los colores y las formas de los marcadores se almacenan en la tabla. Cuando la conexión a la tabla se interrumpe con clonebox, creo que se crean nuevas estructuras de datos de atributos de marcador que permiten que las ventanas del escritorio conserven los atributos de marcador, pero estas estructuras de datos no se exportan a HTML interactivo.

 

Acepto que SaveHTML debería proporcionar una visualización correcta en HTML, porque las imágenes de los gráficos (como se ven en el escritorio) aparecerán en el HTML.  

 

Con el Generador de gráficos, los colores y las formas de los marcadores no se almacenan en la tabla, por lo que si pudo crear los mismos gráficos bivariados con el Generador de gráficos, debería poder conservar los colores y las formas de los marcadores, independientemente de si envuelve o no los gráficos en un cuadro de clonación. Usando Graph Builder, puede que no sea necesario usar un clonebox en absoluto.

 

~Juan

      

Re: Línea de referencia de gráfico de variable de bucle For

@John_Powell_JMP para la pregunta HTML.

 

La operación de cuadro de clonación convierte un informe en vivo en un conjunto estático de cuadros de visualización. No estoy seguro de cuánta interactividad puede esperar (creo que ninguna). Es posible que pueda usar <<Re: Línea de referencia de gráfico de variable de bucle For

Hola Craig, encontré una consecuencia no intencionada de usar << clonebox. en
mi guion Estoy guardando la salida como un html interactivo y para algunos
motivo cuando se guarda el html, los marcadores solo aparecen como puntos negros
versus el formato estándar que estoy usando en la leyenda. De alguna manera, el
la leyenda está siendo desactivada. Lo interesante está en la ventana abierta,
los gráficos se muestran correctamente, es justo cuando abro el archivo html que
Observo que los marcadores no coinciden con la leyenda. Si guardo la salida como
diario, la leyenda también funciona. Lo he reducido a usar el
clonebox (cuando lo comento, el html se guarda correctamente) pero no lo he hecho
he podido encontrar mucha documentación sobre cómo formatear el cuadro de clonación.

La secuencia de comandos con sus sugerencias se incorpora a continuación se encuentra a continuación.

For( w = 1, w <= row_count, w++,
 Stmt = CofA_dt10:Parameter[w];
 Stmt2 = CofA_dt10:Material Parameter[w];
 CofA_dt9 << Clear Row States;
 CofA_dt9 << select where( :Parameter == Eval( Parse( Eval Insert( "Stmt" ) ) ) );
 CofA_dt9a = CofA_dt9 << Subset( Output Table( "TempTable" || Char( w ) ), );

 Mean_4sigmaUCL = CofA_dt9a:UCL_Line[1];
 Mean_4sigmaLCL = CofA_dt9a:LCL_Line[1];
 Mean_data = CofA_dt9a:Name( "Mean(real_value)" )[1];
 output2 << append(
  V List Box(
   (CofA_dt9a << Bivariate(
    Y( :test_value ),
    X( :received_date ),
    SendToReport(
     Dispatch(
      {},
      "Bivariate Fit of test_value By received_date",
      OutlineBox,
      {Set Title( Eval( Parse( Eval Insert( "Stmt" ) ) ) )}
     ),
     Dispatch(
      {},
      "2",
      ScaleBox,
      {Add Ref Line( Mean_4sigmaUCL, "Solid", "Red", "Mean_4s_UCL", 1 ),
      Add Ref Line( Mean_4sigmaLCL, "Solid", "Red", "Mean_4s_LCL" ),
      Add Ref Line( Mean_data, "Solid", "Green", "Mean" )}
     ),
     Dispatch( {}, "1", ScaleBox, {Label Row( Label Orientation( "Angled" ) )} ),
     Dispatch(
      {},
      "test_value",
      TextEditBox,
      {Set Text( Eval( Parse( Eval Insert( "Stmt2" ) ) ) )}
     ),
     Dispatch(
      {},
      "Bivar Plot",
      FrameBox,
      {Frame Size( 1018, 423 ), Row Legend(
       Flagging,
       Color( 1 ),
       Color Theme( "JMP Default" ),
       Marker( 1 ),
       Marker Theme( "Standard" ),
       Continuous Scale( 0 ),
       Reverse Scale( 1 ),
       Excluded Rows( 0 )
      )}
     )
    )
   ))
  ) << cloneBox
 );
 Close( CofA_dt9a, nosave );
); //end row loop

Este es el script para guardar el archivo html, viene justo después de crear el
ventana de salida, por lo que no sé por qué el clonebox afectaría el
formateo?

output = Tab Box( "EASY Summary", output1, "Trend Graphs", output2 );
output_window = New Window( "F68 CofA Flagging Summary", output );
output_window << Save Interactive html(
 path || "FlagSummaryAll" || "
Sigma=" || Char( sigma ) || " Days=" || Char( Days ) || ".html"
);

Re: Línea de referencia de gráfico de variable de bucle For¡Gracias! Esto me ayudó a resolver ambos problemas.Re: Línea de referencia de gráfico de variable de bucle For

Prueba algo como esto

dt = Open( "$sample_data/big class.jmp" );

output2 = V List Box(); // vlist box of all the results

For( w = 1, w <= N Rows( dt ), w++, // for every row in *some* table (the original question uses a different table for this)
    Stmt = dt:height[w]; // get some interesting value to subset with and make a subset...
    // (This simplied answer  is a little bit  non-sensical without another table involved--it will make duplicate graphs)
    dt << Clear Row States; // I think this is what you wanted, rather than clearing the column selection
    dt << select where( dt:height == Stmt );
    CofA_dt9a = dt << Subset( Output Table( "TempTable" || Char( w ) ) ); // make a subset

    row1weight = CofA_dt9a:weight[1]; // use row 1 of the subset to get values that will
    row1age = CofA_dt9a:age[1]; // be visible on the X and Y axes

    output2 << append( // collect all the results here
        V List Box( // a list of 1 box; bivariate attaches to this vlist rather than making a window
            (CofA_dt9a << Bivariate( Y( :weight ), X( :age ),
                SendToReport( // the next line has a hyphen that appears to make stmt negative...
                    Dispatch({},"Bivariate Fit of weight By age",OutlineBox,{Set Title( "Parameter Value by shelf_life_start_date -" || Char( stmt ) )}),
                    Dispatch( {}, "2", ScaleBox, {Add Ref Line( row1weight, "Solid", "Red", "row 1 weight", 1 )} ),
                    Dispatch( {}, "1", ScaleBox, {Label Row( Label Orientation( "Angled" ) ), Add Ref Line( row1age, "Solid", "Red", "row 1 age" )} ), 
                    Dispatch({},"Bivar Plot",FrameBox,{Frame Size( 200, 100 )}
                    )
                )
            ))
        ) << cloneBox // cloning the V List Box and the bivariate platform disconnects the clone from the data table
    );
    Close( CofA_dt9a, nosave ); // the subset is not needed after the clone
); //end row loop

Close( dt, nosave );

New Window( "output2", output2 );