83017_ja-JP

liliconcom

ループ変数グラフ基準線の場合

for ループを使用して一連のグラフ (合計で 10 以上のグラフ) を生成しています。ただし、6 番目のグラフ以降、基準線はグラフに表示されません。 10～11回目あたりから、再び基準線がグラフに現れます。 wait(0); を追加してみました。複数の場所にありますが、それは役に立ちませんでした。 さまざまなタイプのグラフ、標準の二変量対グラフビルダーを使用してみました。元のデータセットのサイズを縮小して、メモリの問題かどうかを確認しました。 これらの試みはどれもうまくいきませんでした。私は提案を探しています。 最初の問題よりも問題が少ない2番目の問題は、作成して出力ウィンドウに保存したグラフを閉じずに、作成した一時テーブルを閉じる方法です。 テーブル (0) へのリンクを使用しようとしましたが、出力ウィンドウを生成した後にテーブルを閉じようとしましたが、まだ機能しません。 どんな提案でも大歓迎です。

　

For( w = 1, w <= row_count, w++,
 Stmt = CofA_dt10:Parameter[w];
 CofA_dt9 << clear column selection;
 CofA_dt9 << select where( :Parameter == Eval( Parse( Eval Insert( "Stmt" ) ) ) );
 CofA_dt9a = CofA_dt9 << Subset( Output Table( "TempTable" || Char( w ) ), );
 
　
 Mean_4sigmaUCL = CofA_dt9a:UCL_Line[w];
 Mean_4sigmaLCL = CofA_dt9a:LCL_Line[w];
 
 
 output2 << append(
  V List Box(
   CofA_dt9a << 
 
   Bivariate(
    Y( :test_value ),
    X( :shelf_life_start_date ), 
 
    SendToReport(
     Dispatch(
      {},
      "Bivariate Fit of test_value By shelf_life_start_date",
      OutlineBox,
      {Set Title(
       "Parameter Value by shelf_life_start_date -" || Eval(
        Parse( Eval Insert( "Stmt" ) )
       )
      )}
     ), 
 
     Dispatch(
      {},
      "2",
      ScaleBox,
      {Add Ref Line( Mean_4sigmaUCL, "Solid", "Red", "Mean_4s_UCL", 1 ),
      Add Ref Line( Mean_4sigmaLCL, "Solid", "Red", "Mean_4s_LCL" )}
     ),
     Dispatch( {}, "1", ScaleBox, {Label Row( Label Orientation( "Angled" ) )} ),
     Dispatch( {}, "test_value", TextEditBox, {Set Text( "Parameter Value" )} ), 
 
     Dispatch(
      {},
      "Bivar Plot",
      FrameBox,
      {Frame Size( 1018, 423 ), Row Legend(
       Flagging,
       Color( 1 ),
       Color Theme( "JMP Default" ),
       Marker( 1 ),
       Marker Theme( "Standard" ),
       Continuous Scale( 0 ),
       Reverse Scale( 1 ),
       Excluded Rows( 0 )
 
      )}
     )
    )
   )
  )
 )
 
 ;
); //end row loop

 

Re: For ループ変数グラフ基準線

インタラクティブな HTML は、クローンボックスにラップされたときにある程度のインタラクティブ性を維持しようとしますが、Craige が指摘するように...

<SPAN class="token comment">"disconnects the clone from the data table"</SPAN>

行の凡例を使用すると、色とマーカーの形状がテーブルに格納されます。 clonebox を使用してテーブルへの接続が切断されると、新しいマーカー属性データ構造が作成され、デスクトップ ウィンドウがマーカー属性を保持できるようになると思いますが、これらのデータ構造は Interactive HTML にエクスポートされません。

 

グラフの画像 (デスクトップで表示されるもの) が HTML に表示されるため、SaveHTML が HTML で正しく表示されることに同意します。  

 

グラフ ビルダーでは、マーカーの色と形状はテーブルに保存されないため、グラフ ビルダーを使用して同じ二変量プロットを作成できた場合は、グラフをクローンボックスにラップするかどうかに関係なく、マーカーの色と形状を保持できるはずです。 Graph Builder を使用すると、clonebox を使用する必要がまったくない場合があります。

 

〜ジョン

      

Re: For ループ変数グラフ基準線

@ジョン_パウエル_JMP HTMLの質問について。

 

クローン ボックス操作は、ライブ レポートを表示ボックスの静的なセットに変換します。 どれだけの対話性が期待できるかはわかりません (私は何もないと思います)。

Re: For ループ変数グラフ基準線

こんにちはクレイグ、 << クローンボックスを使用することの意図しない結果が1つ見つかりました。の
私のスクリプト。 出力をインタラクティブなhtmlとして保存しています。
HTMLが保存される理由は、マーカーが黒い点として表示されるだけです
凡例で使用している標準の書式設定とは対照的です。 どういうわけか、
凡例は非アクティブ化されています。 面白いのは開いた窓の中にある、
グラフが正しく表示されているのは、html ファイルを開いたときだけです。
マーカーが凡例と一致しないことがわかりました。 出力を次のように保存すると
ジャーナル、伝説も機能します。 私はそれを使用して絞り込みました
clonebox (コメントアウトすると、html は正しく保存されます)
クローンボックスのフォーマット方法に関する多くのドキュメントを見つけることができました.

あなたの提案を含むスクリプトは以下に組み込まれています。

For( w = 1, w <= row_count, w++,
 Stmt = CofA_dt10:Parameter[w];
 Stmt2 = CofA_dt10:Material Parameter[w];
 CofA_dt9 << Clear Row States;
 CofA_dt9 << select where( :Parameter == Eval( Parse( Eval Insert( "Stmt" ) ) ) );
 CofA_dt9a = CofA_dt9 << Subset( Output Table( "TempTable" || Char( w ) ), );

 Mean_4sigmaUCL = CofA_dt9a:UCL_Line[1];
 Mean_4sigmaLCL = CofA_dt9a:LCL_Line[1];
 Mean_data = CofA_dt9a:Name( "Mean(real_value)" )[1];
 output2 << append(
  V List Box(
   (CofA_dt9a << Bivariate(
    Y( :test_value ),
    X( :received_date ),
    SendToReport(
     Dispatch(
      {},
      "Bivariate Fit of test_value By received_date",
      OutlineBox,
      {Set Title( Eval( Parse( Eval Insert( "Stmt" ) ) ) )}
     ),
     Dispatch(
      {},
      "2",
      ScaleBox,
      {Add Ref Line( Mean_4sigmaUCL, "Solid", "Red", "Mean_4s_UCL", 1 ),
      Add Ref Line( Mean_4sigmaLCL, "Solid", "Red", "Mean_4s_LCL" ),
      Add Ref Line( Mean_data, "Solid", "Green", "Mean" )}
     ),
     Dispatch( {}, "1", ScaleBox, {Label Row( Label Orientation( "Angled" ) )} ),
     Dispatch(
      {},
      "test_value",
      TextEditBox,
      {Set Text( Eval( Parse( Eval Insert( "Stmt2" ) ) ) )}
     ),
     Dispatch(
      {},
      "Bivar Plot",
      FrameBox,
      {Frame Size( 1018, 423 ), Row Legend(
       Flagging,
       Color( 1 ),
       Color Theme( "JMP Default" ),
       Marker( 1 ),
       Marker Theme( "Standard" ),
       Continuous Scale( 0 ),
       Reverse Scale( 1 ),
       Excluded Rows( 0 )
      )}
     )
    )
   ))
  ) << cloneBox
 );
 Close( CofA_dt9a, nosave );
); //end row loop

これは、html ファイルを保存するためのスクリプトです。
出力ウィンドウなので、なぜクローンボックスが影響するのか途方に暮れています
整形？

output = Tab Box( "EASY Summary", output1, "Trend Graphs", output2 );
output_window = New Window( "F68 CofA Flagging Summary", output );
output_window << Save Interactive html(
 path || "FlagSummaryAll" || "
Sigma=" || Char( sigma ) || " Days=" || Char( Days ) || ".html"
);

Re: For ループ変数グラフ基準線ありがとう！ これは、両方の問題を解決するのに役立ちました。Re: For ループ変数グラフ基準線

このようなことを試してください

dt = Open( "$sample_data/big class.jmp" );

output2 = V List Box(); // vlist box of all the results

For( w = 1, w <= N Rows( dt ), w++, // for every row in *some* table (the original question uses a different table for this)
    Stmt = dt:height[w]; // get some interesting value to subset with and make a subset...
    // (This simplied answer  is a little bit  non-sensical without another table involved--it will make duplicate graphs)
    dt << Clear Row States; // I think this is what you wanted, rather than clearing the column selection
    dt << select where( dt:height == Stmt );
    CofA_dt9a = dt << Subset( Output Table( "TempTable" || Char( w ) ) ); // make a subset

    row1weight = CofA_dt9a:weight[1]; // use row 1 of the subset to get values that will
    row1age = CofA_dt9a:age[1]; // be visible on the X and Y axes

    output2 << append( // collect all the results here
        V List Box( // a list of 1 box; bivariate attaches to this vlist rather than making a window
            (CofA_dt9a << Bivariate( Y( :weight ), X( :age ),
                SendToReport( // the next line has a hyphen that appears to make stmt negative...
                    Dispatch({},"Bivariate Fit of weight By age",OutlineBox,{Set Title( "Parameter Value by shelf_life_start_date -" || Char( stmt ) )}),
                    Dispatch( {}, "2", ScaleBox, {Add Ref Line( row1weight, "Solid", "Red", "row 1 weight", 1 )} ),
                    Dispatch( {}, "1", ScaleBox, {Label Row( Label Orientation( "Angled" ) ), Add Ref Line( row1age, "Solid", "Red", "row 1 age" )} ), 
                    Dispatch({},"Bivar Plot",FrameBox,{Frame Size( 200, 100 )}
                    )
                )
            ))
        ) << cloneBox // cloning the V List Box and the bivariate platform disconnects the clone from the data table
    );
    Close( CofA_dt9a, nosave ); // the subset is not needed after the clone
); //end row loop

Close( dt, nosave );

New Window( "output2", output2 );