Ligne de référence du graphique variable de la boucle ForJe génère une série de graphiques (10 graphiques ou plus au total) avec une boucle for ; cependant, après le sixième graphique, les lignes de référence n'apparaissent pas dans le graphique. Après environ le 10ème ou le 11ème graphique, les lignes de référence réapparaissent dans les graphiques. J'ai essayé d'ajouter wait(0); à plusieurs endroits, mais cela n'a pas aidé. J'ai essayé d'utiliser différents types de graphiques, bivariés standard ou générateur de graphiques, j'ai essayé de réduire la taille de mon ensemble de données d'origine pour voir s'il s'agissait d'un problème de mémoire. Aucune de ces tentatives n'a fonctionné et je recherche des suggestions. Le deuxième problème que je voudrais aborder et qui pose moins problème que le premier est de savoir comment fermer la table temporaire créée sans fermer les graphiques que j'ai créés et enregistrés dans ma fenêtre de sortie. J'ai essayé d'utiliser le lien vers la table (0), j'ai essayé de fermer les tables après avoir généré la fenêtre de sortie et cela ne fonctionne toujours pas. Toutes les suggestions sont grandement appréciées.
For( w = 1, w <= row_count, w++,
Stmt = CofA_dt10:Parameter[w];
CofA_dt9 << clear column selection;
CofA_dt9 << select where( :Parameter == Eval( Parse( Eval Insert( "Stmt" ) ) ) );
CofA_dt9a = CofA_dt9 << Subset( Output Table( "TempTable" || Char( w ) ), );
Mean_4sigmaUCL = CofA_dt9a:UCL_Line[w];
Mean_4sigmaLCL = CofA_dt9a:LCL_Line[w];
output2 << append(
V List Box(
CofA_dt9a <<
Bivariate(
Y( :test_value ),
X( :shelf_life_start_date ),
SendToReport(
Dispatch(
{},
"Bivariate Fit of test_value By shelf_life_start_date",
OutlineBox,
{Set Title(
"Parameter Value by shelf_life_start_date -" || Eval(
Parse( Eval Insert( "Stmt" ) )
)
)}
),
Dispatch(
{},
"2",
ScaleBox,
{Add Ref Line( Mean_4sigmaUCL, "Solid", "Red", "Mean_4s_UCL", 1 ),
Add Ref Line( Mean_4sigmaLCL, "Solid", "Red", "Mean_4s_LCL" )}
),
Dispatch( {}, "1", ScaleBox, {Label Row( Label Orientation( "Angled" ) )} ),
Dispatch( {}, "test_value", TextEditBox, {Set Text( "Parameter Value" )} ),
Dispatch(
{},
"Bivar Plot",
FrameBox,
{Frame Size( 1018, 423 ), Row Legend(
Flagging,
Color( 1 ),
Color Theme( "JMP Default" ),
Marker( 1 ),
Marker Theme( "Standard" ),
Continuous Scale( 0 ),
Reverse Scale( 1 ),
Excluded Rows( 0 )
)}
)
)
)
)
)
;
); //end row loop
Re : Ligne de référence du graphique variable de la boucle ForLe HTML interactif essaie de maintenir une certaine interactivité lorsqu'il est enveloppé dans une clonebox, mais comme le note Craige...
<SPAN class="token comment">"disconnects the clone from the data table"</SPAN>
Lorsqu'une légende de ligne est utilisée, les couleurs et les formes des marqueurs sont stockées dans le tableau. Lorsque la connexion à la table est interrompue à l'aide de clonebox, je pense que de nouvelles structures de données d'attributs de marqueur sont créées, permettant aux fenêtres du bureau de conserver les attributs de marqueur, mais ces structures de données ne sont pas exportées vers HTML interactif.
Je suis d'accord que SaveHTML devrait fournir un affichage correct en HTML, car les images des graphiques (tels qu'ils apparaissent sur le bureau) apparaîtront dans le HTML.
Avec Graph Builder, les couleurs et les formes des marqueurs ne sont pas stockées dans le tableau. Par conséquent, si vous avez pu créer les mêmes tracés bivariés à l'aide de Graph Builder, vous devriez pouvoir conserver les couleurs et les formes des marqueurs, que vous enveloppiez ou non les graphiques dans une clonebox. En utilisant Graph Builder, il n'est peut-être pas du tout nécessaire d'utiliser une clonebox.
~Jean
Re : Ligne de référence du graphique variable de la boucle For@John_Powell_JMP pour la question HTML.
L'opération de clonage de boîte transforme un rapport en direct en un ensemble statique de boîtes d'affichage. Je ne suis pas sûr du niveau d'interactivité auquel vous pouvez vous attendre (je pense qu'il n'y en a pas.) Vous pourrez peut-être utiliser <<Re : Ligne de référence du graphique variable de la boucle For
Salut Craig, j'ai trouvé une conséquence involontaire de l'utilisation de la << clonebox. dans
mon scénario. J'enregistre la sortie au format HTML interactif et pour certains
raison pour laquelle lorsque le code HTML est enregistré, les marqueurs apparaissent simplement sous forme de points noirs
par rapport au formatage standard que j'utilise dans la légende. D'une manière ou d'une autre, le
la légende est en cours de désactivation. Ce qui est intéressant c'est dans la fenêtre ouverte,
les graphiques s'affichent correctement, c'est justement lorsque j'ouvre le fichier html que
J'observe que les marqueurs ne correspondent pas à la légende. Si j'enregistre la sortie sous
journal, la légende fonctionne aussi. Je l'ai réduit à l'utilisation du
clonebox (quand je le commente, le code HTML est enregistré correctement) mais je ne l'ai pas fait
J'ai pu trouver beaucoup de documentation sur la façon de formater la boîte de clonage.
Le script avec vos suggestions est ci-dessous incorporé ci-dessous.
For( w = 1, w <= row_count, w++,
Stmt = CofA_dt10:Parameter[w];
Stmt2 = CofA_dt10:Material Parameter[w];
CofA_dt9 << Clear Row States;
CofA_dt9 << select where( :Parameter == Eval( Parse( Eval Insert( "Stmt" ) ) ) );
CofA_dt9a = CofA_dt9 << Subset( Output Table( "TempTable" || Char( w ) ), );
Mean_4sigmaUCL = CofA_dt9a:UCL_Line[1];
Mean_4sigmaLCL = CofA_dt9a:LCL_Line[1];
Mean_data = CofA_dt9a:Name( "Mean(real_value)" )[1];
output2 << append(
V List Box(
(CofA_dt9a << Bivariate(
Y( :test_value ),
X( :received_date ),
SendToReport(
Dispatch(
{},
"Bivariate Fit of test_value By received_date",
OutlineBox,
{Set Title( Eval( Parse( Eval Insert( "Stmt" ) ) ) )}
),
Dispatch(
{},
"2",
ScaleBox,
{Add Ref Line( Mean_4sigmaUCL, "Solid", "Red", "Mean_4s_UCL", 1 ),
Add Ref Line( Mean_4sigmaLCL, "Solid", "Red", "Mean_4s_LCL" ),
Add Ref Line( Mean_data, "Solid", "Green", "Mean" )}
),
Dispatch( {}, "1", ScaleBox, {Label Row( Label Orientation( "Angled" ) )} ),
Dispatch(
{},
"test_value",
TextEditBox,
{Set Text( Eval( Parse( Eval Insert( "Stmt2" ) ) ) )}
),
Dispatch(
{},
"Bivar Plot",
FrameBox,
{Frame Size( 1018, 423 ), Row Legend(
Flagging,
Color( 1 ),
Color Theme( "JMP Default" ),
Marker( 1 ),
Marker Theme( "Standard" ),
Continuous Scale( 0 ),
Reverse Scale( 1 ),
Excluded Rows( 0 )
)}
)
)
))
) << cloneBox
);
Close( CofA_dt9a, nosave );
); //end row loop
C'est le script pour sauvegarder le fichier html, il vient juste après la création du
fenêtre de sortie, je ne comprends donc pas pourquoi la clonebox affecterait le
mise en page?
output = Tab Box( "EASY Summary", output1, "Trend Graphs", output2 );
output_window = New Window( "F68 CofA Flagging Summary", output );
output_window << Save Interactive html(
path || "FlagSummaryAll" || "
Sigma=" || Char( sigma ) || " Days=" || Char( Days ) || ".html"
);
Re : Ligne de référence du graphique variable de la boucle ForMerci! Cela m'a aidé à résoudre les deux problèmes.Re : Ligne de référence du graphique variable de la boucle ForEssayez quelque chose comme ça
dt = Open( "$sample_data/big class.jmp" );
output2 = V List Box(); // vlist box of all the results
For( w = 1, w <= N Rows( dt ), w++, // for every row in *some* table (the original question uses a different table for this)
Stmt = dt:height[w]; // get some interesting value to subset with and make a subset...
// (This simplied answer is a little bit non-sensical without another table involved--it will make duplicate graphs)
dt << Clear Row States; // I think this is what you wanted, rather than clearing the column selection
dt << select where( dt:height == Stmt );
CofA_dt9a = dt << Subset( Output Table( "TempTable" || Char( w ) ) ); // make a subset
row1weight = CofA_dt9a:weight[1]; // use row 1 of the subset to get values that will
row1age = CofA_dt9a:age[1]; // be visible on the X and Y axes
output2 << append( // collect all the results here
V List Box( // a list of 1 box; bivariate attaches to this vlist rather than making a window
(CofA_dt9a << Bivariate( Y( :weight ), X( :age ),
SendToReport( // the next line has a hyphen that appears to make stmt negative...
Dispatch({},"Bivariate Fit of weight By age",OutlineBox,{Set Title( "Parameter Value by shelf_life_start_date -" || Char( stmt ) )}),
Dispatch( {}, "2", ScaleBox, {Add Ref Line( row1weight, "Solid", "Red", "row 1 weight", 1 )} ),
Dispatch( {}, "1", ScaleBox, {Label Row( Label Orientation( "Angled" ) ), Add Ref Line( row1age, "Solid", "Red", "row 1 age" )} ),
Dispatch({},"Bivar Plot",FrameBox,{Frame Size( 200, 100 )}
)
)
))
) << cloneBox // cloning the V List Box and the bivariate platform disconnects the clone from the data table
);
Close( CofA_dt9a, nosave ); // the subset is not needed after the clone
); //end row loop
Close( dt, nosave );
New Window( "output2", output2 );
